Microsoft Excel

Herbers Excel/VBA-Archiv

Bild vergrößern


Betrifft: Bild vergrößern von: Uli
Geschrieben am: 18.07.2017 15:40:02

Hallo,

ich habe viele Bilder, die ich vergrößern möchte. Dazu habe ich ein Makro hier aus dem Forum kopiert. Dieses Makro funktioniert bei allen Formen, die ich direkt mit Excel einfüge, egal ob Diagramme oder was auch immer.
Aber mit Bildern aus dem Internet funktioniert dieses Makro nicht, z.B. wenn ich ein Logo einer Firma habe.
Wie bekomme ich es trotzdem größer?

Mein Makro lautet:

Sub GrossKlein()
Dim objShp As Shape
Dim f As Single, a As Variant

f = 2 'Vergößerungsfaktor

Set objShp = ActiveSheet.Shapes(Application.Caller)

If objShp.AlternativeText = "" Then
    With objShp
        .AlternativeText = .Width & ";" & .Height
        .ScaleWidth f, msoFalse
        .ScaleHeight f, msoFalse
    End With
Else
    With objShp
        a = Split(.AlternativeText, ";")
        .Width = a(0)
        .Height = a(1)
        .AlternativeText = ""
    End With
End If

Set objShp = Nothing
End Sub

  

Betrifft: AW: Bild vergrößern von: Mullit
Geschrieben am: 18.07.2017 15:56:15

Hallo,

ändere den Code mal so ab und klick beim ersten Neueinfügen der Grafik zweimal drauf, dann normal...

Option Explicit

Sub GrossKlein()
Dim objShp As Shape
Dim f As Single, a As Variant

f = 2 'Vergößerungsfaktor

Set objShp = ActiveSheet.Shapes(Application.Caller)

If objShp.AlternativeText = "" Then
    With objShp
        .AlternativeText = .Width & ";" & .Height
        .ScaleWidth f, msoFalse
        .ScaleHeight f, msoFalse
    End With
Else
    With objShp
        a = Split(.AlternativeText, ";")
        If UBound(a) = 1 Then
          If IsNumeric(a(0)) And IsNumeric(a(1)) Then
            .Width = a(0)
            .Height = a(1)
          End If
        End If
        .AlternativeText = ""
    End With
End If

Set objShp = Nothing
End Sub

Gruß, Mullit


  

Betrifft: AW: Bild vergrößern von: Uli
Geschrieben am: 18.07.2017 16:14:35

Super, danke. Das klappt.

lg
Uli


  

Betrifft: prima....owT von: Mullit
Geschrieben am: 18.07.2017 16:49:15




  

Betrifft: AW: Bild vergrößern von: Mullit
Geschrieben am: 18.07.2017 16:00:58

Hallo nochmal,

bzw. Du könntest auch nach Neueinfügen der Grafik einfach den AlternativeText händisch löschen, nix anderes macht die Anpasssung im Code, da steht meistens noch die Webadresse drin...

Gruß, Mullit


Beiträge aus den Excel-Beispielen zum Thema "Bild vergrößern"