Microsoft Excel

Herbers Excel/VBA-Archiv

Zahlenreihe


Betrifft: Zahlenreihe von: Stephan
Geschrieben am: 09.01.2018 10:54:45

Hallo zusammen

ich hatte hier vor x Jahren schon einmal sehr gute Hilfe bekommen. Daher versuche ich es nun wieder. Leider habe ich im Forum bisher nichts dergleichen gefunden:

Folgendes:
ich habe einen Wert in Zelle A1 (Rundungswert und somit auch der Minimale Wert - Bsp.100)
in A2 steht der Maximal mögliche Wert (ein x-faches des Rundungswertes Bsp. 1000).

nun möchte ich ein Code, welcher mir automatisch in B1 den Maximalen Wert einträgt. In B2 sollte dann der Maximale Wert - Rundungswert eingetragen werden. Das ganze solange runterziehen, bis der Rundungswert und somit der Minimale Wert erreicht ist.

Das Ganze sollte dann so aussehen:
B1: 1000
B2: 900
B3: 800
..
B10 100

  

Betrifft: AW: Zahlenreihe von: SF
Geschrieben am: 09.01.2018 10:59:24

Hola,

=WENNFEHLER(WENN(B1-$A$1<$A$1;"";B1-$A$1);"")

Gruß,
steve1da


  

Betrifft: AW: Zahlenreihe von: Sepp
Geschrieben am: 09.01.2018 11:01:53

Hallo Stephan,

Formel in B2 wit genug nach unten ausfüllen.

Tabelle1

 ABCD
11001000  
21000900  
3 800  
4 700  
5 600  
6 500  
7 400  
8 300  
9 200  
10 100  
11    
12    
13    
14    
15    
16    
17    

Formeln der Tabelle
ZelleFormel
B1=A2
B2=WENN($B$1-($A$1*(ZEILE(A2)-1))<$A$1;"";B1-$A$1)


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8



Gruß Sepp



  

Betrifft: AW: Zahlenreihe von: Stephan
Geschrieben am: 09.01.2018 11:19:03

Danke für die die sehr schnelle Antwort. In Excel funktioniert dies einwandfrei, ähnlich weit war ich auch schon. Ich möchte das Ganze aber in VBA haben da die Abfrage Teil einer Berechnung ist die regelmässig durchgeführt werden soll - mit veränderten Parameter. Gibt es hier eine Möglichkeit genau diese Formel abzubilden? Sorry für die etwas ungenaue Formulierung.


  

Betrifft: AW: Zahlenreihe von: Sepp
Geschrieben am: 09.01.2018 11:31:24

Hallo Stephan,

in das Modul der Tabelle.

' **********************************************************************
' Modul: Tabelle1 Typ: Element der Mappe(Sheet, Workbook, ...)
' **********************************************************************

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
Dim lngIndex As Long, varOut() As Variant

On Error GoTo ErrorHandler

If Not Intersect(Target, Range("A1:A2")) Is Nothing Then
  Application.EnableEvents = False
  If IsNumeric(Range("A1")) And IsNumeric(Range("A2")) Then
    Range("B:B") = ""
    Redim varOut(1 To Int(Range("A2") / Range("A1")), 1 To 1)
    For lngIndex = 1 To UBound(varOut, 1)
      varOut(lngIndex, 1) = Range("A2") - (Range("A1") * (lngIndex - 1))
    Next
    Range("B1").Resize(UBound(varOut, 1), 1) = varOut
  End If
End If

ErrorHandler:
Application.EnableEvents = True
End Sub


Gruß Sepp



  

Betrifft: AW: Zahlenreihe von: Stephan
Geschrieben am: 09.01.2018 13:24:33

Danke Sepp, genau so etwas habe ich gesucht. Toller Support!
Gruss,Stephan


  

Betrifft: AW: Zahlenreihe von: UweD
Geschrieben am: 09.01.2018 11:36:16

Hier noch eine Lösung


Sub hdhd()
    Dim Anz As Integer
    Anz = Int(Range("A2") / Range("A1")) 'Anzahl Werte 
    
    With Range("B1").Resize(Anz)
        'Reset 
        .EntireColumn.ClearContents
        
        'Formel setzen 
        .FormulaR1C1 = "=R2C1-(ROW()-1)*R1C1"
        
        'in Werte verwandeln 
        .Value = .Value
    End With
End Sub

LG UweD


  

Betrifft: AW: Zahlenreihe von: Stephan
Geschrieben am: 09.01.2018 13:25:31

Danke Uwe, genau so etwas habe ich gesucht. Auch diese variante funktioniert. Toller Support!
Gruss,Stephan


  

Betrifft: gern geschehen owT von: UweD
Geschrieben am: 10.01.2018 08:39:33




  

Betrifft: AW: Zahlenreihe von: Daniel
Geschrieben am: 09.01.2018 11:31:16

Hi

solche Aufgaben kannst du mit der Menüfunktion Start - Bearbeiten - Füllbereich - Reihe erledigen.

der Code dazu sieht dann so aus:

Range("B1").Value = Range("A2").Value
Range("B1").DataSeries Rowcol:=xlColumns, Type:=xlLinear, Step:=-Range("A1").Value, Stop:=Range("A1").Value
Gruß Daniel


  

Betrifft: AW: Zahlenreihe von: Stephan
Geschrieben am: 09.01.2018 13:25:53

Danke Daniel, wieder was gelernet!


Beiträge aus dem Excel-Forum zum Thema "Zahlenreihe"