Microsoft Excel

Herbers Excel/VBA-Archiv

Informationen und Beispiele zum Thema TextBox
BildScreenshot zu TextBox TextBox-Seite mit Beispielarbeitsmappe aufrufen

Hyperlink auf verschobene Datei ändern


Betrifft: Hyperlink auf verschobene Datei ändern von: MaBlu
Geschrieben am: 22.01.2019 08:37:52

Hallo

wir mussten die Daten verschieben, jetzt haben wir Hyperlinks auf Excel Dokumente die nicht mehr gehen!
Kann mir jemand helfen wie ich das mit einem Makro erledigen kann so dass ich nicht jedes Dokument neu verlinken muss?

Alter Link:
"G:\08_OP\01_FA\03_Projekte\Frei\Kunden\Kunde\2032-Langbandschiene 133-Transferfertigung\20 Projektabwicklung\23 Projektpflichtenheft\2032-Projektpflichtenheft.xls"

Neuer Link:
"G:\08_OP\80_Kunden\Frei\Kunden\Kunde\2032-Langbandschiene 133-Transferfertigung\20 Projektabwicklung\23 Projektpflichtenheft\2032-Projektpflichtenheft.xls"

Ich hatte mal sowas gefunden aber weiss nicht wie aanpassen?

Sub hl()
Dim altsv As String, neusv As String
altsv = "\\Kunde\dfs-2\" 'Groß / klei beachten !!
neusv = "\\Kunde.ch\dfs-2\from\"
Dim hlk As Hyperlink
For Each hlk In Sheets("Zugelassene Lieferanten").Hyperlinks 'Tabelle anpassen !
hlk.Address = Replace(hlk.Address, altsv, neusv)
Next
End Sub

Wäre sehr nett wenn mir da geholfen werden könnte.

Gruss MaBlu

  

Betrifft: AW: Hyperlink auf verschobene Datei ändern von: MaBlu
Geschrieben am: 22.01.2019 08:42:41

Hallo

fast vergessen, es ändert nur der erste Teil siehe Links

alt ****\01_FA\03_Projekte\**** wird durch neu ersetzt
Neu *****\80_Kunden\

besten Dank MaBlu


  

Betrifft: AW: Hyperlink auf verschobene Datei ändern von: Daniel M.
Geschrieben am: 22.01.2019 08:43:03

Hallo,

versuch mal in dem Code die abweichenden Teile in deinen Links einzusetzen:

altsv = "01_FA\03_Projekte"
neusv = "80_Kunden"

Dann noch den Part "Zugelassene Lieferanten" mit dem Namen deines Tabellenblatts ersetzen.

Grüße
Daniel


  

Betrifft: AW: Hyperlink auf verschobene Datei ändern von: MaBlu
Geschrieben am: 22.01.2019 09:21:52

Hallo Daniel

ich habe mich falsch ausgedrückt, es sind Desktopverknüpfungen die in einem Ordner sind diese sind jetzt falsch und dort möchte ich den Pfad richtig stellen, das Makro das ich eingestellt habe ist ja im Dokumen den Pfad zu ändern darum weiss ich nicht wie anpassen?

Gruss MaBlu


  

Betrifft: AW: Hyperlink auf verschobene Datei ändern von: Daniel M.
Geschrieben am: 22.01.2019 09:26:21

Mal abgesehen davon, dass ich mir überlegen würde, ob das Arbeiten mit massenhaft Desktopverknüpfungen die effizienteste Arbeitsweise ist, klingt es so als wäre es einfacher, die Verknüpfungen zu löschen und neu aus dem Ordner auf den Desktop zu ziehen.
Aber wie gesagt, grundsätzlich könnte man das bestimmt etwas eleganter gestalten?


  

Betrifft: AW: Hyperlink auf verschobene Datei ändern von: Sepp
Geschrieben am: 22.01.2019 08:48:03

Hallo MaBlu,

probier es mal so.

Sub replaceHL_Address()
  Dim objHL As Hyperlink, strOld As String, strNew As String
  
  strOld = "G:\08_OP\01_FA\03_Projekte\Frei\Kunden\Kunde\2032-Langbandschiene 133-Transferfertigung\20 Projektabwicklung\23 Projektpflichtenheft\"
  strNew = "G:\08_OP\80_Kunden\Frei\Kunden\Kunde\2032-Langbandschiene 133-Transferfertigung\20 Projektabwicklung\23 Projektpflichtenheft\"

  For Each objHL In Sheets("Zugelassene Lieferanten").Hyperlinks 'Tabelle anpassen ! 
    objHL.Address = Replace(objHL.Address, strOld, strNew)
  Next
End Sub


VBA/HTML-CodeConverter, AddIn für Office 2002-2016 - in VBA geschrieben von Lukas Mosimann. Projektbetreuung:RMH Software & Media

Code erstellt und getestet in Office 16 - mit VBAHTML 12.6.0


 ABCDEF
1Gruß Sepp
2
3



  

Betrifft: AW: Hyperlink auf verschobene Datei ändern von: MaBlu
Geschrieben am: 22.01.2019 09:05:00

Hallo Sepp

ich habs probiert geht nicht ich denke ich habe mich falsch ausgedrückt, der Link ist nicht im Sheet sondern es ist eine Desktopverknüpfung auf das Dokument das jetzt auf ein falschen Speicherort verweist, das Makro das ich eingestellt habe war damals um den Link zu ändern in einem Dokument sorry.


Zur Präzisierung das sind sehr viele Desktopverknüpfungen die alle auf den falsche Speicherort verweisen!

Gruss Mablu


  

Betrifft: AW: Hyperlink auf verschobene Datei ändern von: Sepp
Geschrieben am: 22.01.2019 09:52:11

Hallo Mablu,

probier mal, aber auf eigene Gefahr!

Sub CreateFileShortcut()
  Dim objShell As Object, objSC As Object, objFSO As Object, objFile As Object
  Dim strPath As String, strOld As String, strNew As String

  strOld = "\01_FA\03_Projekte\"
  strNew = "\80_Kunden\"

  Set objShell = CreateObject("WScript.Shell")
  Set objFSO = CreateObject("Scripting.FilesystemObject")

  strPath = objShell.SpecialFolders("desktop")

  For Each objFile In objFSO.GetFolder(strPath).Files
    If LCase(objFile.Name) Like "*.lnk" Then
      Set objSC = objShell.CreateShortcut(objFile.Path)
      With objSC
        .TargetPath = Replace(.TargetPath, strOld, strNew)
        .Save
      End With
    End If
  Next

  Set objSC = Nothing
  Set objShell = Nothing
  Set objFSO = Nothing
End Sub


VBA/HTML-CodeConverter, AddIn für Office 2002-2016 - in VBA geschrieben von Lukas Mosimann. Projektbetreuung:RMH Software & Media

Code erstellt und getestet in Office 16 - mit VBAHTML 12.6.0


 ABCDEF
1Gruß Sepp
2
3



  

Betrifft: AW: Hyperlink auf verschobene Datei ändern von: MaBlu
Geschrieben am: 22.01.2019 10:16:00

Hallo Sepp danke für deine Mühe leider klappt es nicht
es passiert offensichtlich nichts, auch keine Fehlermeldung
ich denke es ist der Start pfad die Desktop-Verknüpfungen sind nicht auf dem Desktop sondern in einem Ordner auf dem Server, wie müsste ich den Start Pfad denn abändern?

Pfad: T:\05_OP\70_Fertigung\Produktion\Einrichtpläne\Ausgefüllte Einrichtpläne

Gruss MaBlu


  

Betrifft: AW: Hyperlink auf verschobene Datei ändern von: Sepp
Geschrieben am: 22.01.2019 10:19:21

Hallo Mablu,

na ja, wenn du mit jeder info auch immer erst hinterher kommst!

Probiere es mit:

strPath = "T:\05_OP\70_Fertigung\Produktion\Einrichtpläne\Ausgefüllte Einrichtpläne"

 ABCDEF
1Gruß Sepp
2
3



  

Betrifft: AW: hat geklappt von: MaBlu
Geschrieben am: 22.01.2019 10:30:06

Hallo Sepp

vielen Dank das hat geklappt besten Dank.

Gruss und schönen Tag
MaBlu


  

Betrifft: AW: Hyperlink auf verschobene Datei ändern von: PeterK
Geschrieben am: 22.01.2019 10:26:12

Hallo

Oder "strPath = objShell.SpecialFolders("AllUsersDesktop")


Beiträge aus dem Excel-Forum zum Thema "Hyperlink auf verschobene Datei ändern"