Eingabefeld auf Homepage

Sub Webcrawler() Dim IEApp As Object Set IEApp = CreateObject("InternetExplorer.Application") IEApp.Visible = True IEApp.navigate "www.price-robot.de" Application.Wait (Time + TimeValue("00:00:10")) Do: Loop Until IEApp.busy = False Do: Loop Until IEApp.busy = False Do: Loop Until IEApp.document.ReadyState = "complete" IEApp.document.getElementByID("comp-k4rlxxdpinput").Select IEApp.document.getElementByID("comp-k4rlxxdpinput").Value = "Test" IEApp.document.getElementByID("comp-k4rlysbklink").Click MsgBox ("Ende") End Sub

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Rolf Jan,
das Input-Tag hat mehrere Events. Damit der Name übernommen wird musst Du das onKeydown-Event triggern. Die manuelle Wartezeit für den kompetten Seitenaufbau kann auf 5 Sekunden abgesenkt werden, 3 waren zu kurz bei mir. Das der Button erfolgreich geklickt wurde habe ich am erscheinenden Datum festgemacht:


Sub PriceRobotLogIn()
Dim logInName As String
Dim browser As Object
Dim url As String
Dim knotenEingabe As Object
Dim knotenButton As Object
logInName = "Testname"
url = "https://www.price-robot.de/"
'Internet Explorer initialisieren, Sichtbarkeit festlegen,
'URL aufrufen und warten bis Seite vollständig geladen wurde
Set browser = CreateObject("internetexplorer.application")
browser.Visible = True
browser.navigate url
Do Until browser.ReadyState = 4: DoEvents: Loop
'Manuelle Pause, damit die Seite komplett zur Verfügung steht
Application.Wait (Now + TimeSerial(0, 0, 5))
'Das input-Tag sondieren
'[Fehlerprüfung temporär ausschalten, weil getElementByID() einen
'Laufzeitfehler wirft, wenn es die gesuchte ID nicht gibt]
On Error Resume Next
Set knotenEingabe = browser.document.getElementByID("comp-k4rlxxdpinput")
On Error GoTo 0
'Prüfen ob knotenEingabe erzeugt werden konnte
If Not knotenEingabe Is Nothing Then
'Das onKeyDown Event auslösen
Call TriggerEvent(browser.document, knotenEingabe, "onKeyDown")
'LogIn Namen eintragen
knotenEingabe.Value = logInName
Else
MsgBox "Eingabefeld für den LogIn Namen wurde nicht gefunden"
'Button klicken bringt nix, also Makro kontrolliert beenden
Exit Sub
End If
'Button sondieren
On Error Resume Next
Set knotenButton = browser.document.getElementByID("comp-k4rlysbklink")
On Error GoTo 0
'Prüfen ob knotenEingabe erzeugt werden konnte
If Not knotenButton Is Nothing Then
knotenButton.Click
Else
MsgBox "LogIn-Button wurde nicht gefunden"
End If
End Sub

Mit folgender Prozedur wird ein HTML-Event getriggert:


Sub TriggerEvent(htmlDocument As Object, htmlElementWithEvent As Object, eventType As String)
'Basierend auf einer Prozedur von Anton aus dem Herber Forum
'Für allgemeine Events angepasst nach Vorschlag von QHaar auf StackOverflow
Dim theEvent As Object
htmlElementWithEvent.Focus
Set theEvent = htmlDocument.createEvent("HTMLEvents")
theEvent.initEvent eventType, True, False
htmlElementWithEvent.dispatchEvent theEvent
End Sub

Viele Grüße,
Zwenn

Beliebteste Forumthreads (12 Monate)

4 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread