Microsoft Excel

Herbers Excel/VBA-Archiv

Informationen und Beispiele zum Thema MsgBox
BildScreenshot zu MsgBox MsgBox-Seite mit Beispielarbeitsmappe aufrufen

Ordner per Excel-Liste erstelln

Betrifft: Ordner per Excel-Liste erstelln von: Jaschke
Geschrieben am: 11.09.2020 22:09:46

Hallo,


ich möchte gerne via Marko folgendes lösen:

In Spalte A stehen Projektnamen, z.B. A1 "Äpfel"; A2 "Brinen" usw.

Per Marko soll unter C:\Projektordner\ ein leerer Ordner pro Projekt erstellt werden, der nach dem Projektnamen benannt ist, also

C\Projektordner\Äpfel\; C:\Projektordner\Birnen\


Wie ist das lösbar?

Vielen Dank!!

Gruß Jaschke

Betrifft: AW: Ordner per Excel-Liste erstelln
von: fcs
Geschrieben am: 12.09.2020 00:34:04

Hallo Jaschke,

hier ein entsprechendes Makro.

LG
Franz
Sub Projektordner_erstellen()
  Dim rng As Range
  Dim sBasis As String
  Dim sOrdner As String, sVerzeichnis As String
  
  If MsgBox("Jetzt Projektordner anlegen?", vbQuestion + vbOKCancel) = vbCancel Then Exit Sub
  
  sBasis = "C:\Projektordner"
  
  If Dir(sBasis, vbDirectory) = "" Then
    MsgBox "Verzeichnis """ & sBasis & """ existiert nicht!", vbOKOnly, _
        "Projekt-Ordner erstellen"
  Else
    sBasis = sBasis & Application.PathSeparator
    With ActiveSheet
      For Each rng In .Range(.Cells(1, 1), .Cells(.Rows.Count, 1).End(xlUp)).Cells
        sOrdner = Trim(rng.Text)
        If sOrdner <> "" Then
          sVerzeichnis = sBasis & sOrdner
          If Dir(sVerzeichnis, vbDirectory) = "" Then
            VBA.MkDir sVerzeichnis
          End If
        End If
        
      Next
    End With
  End If
End Sub


Betrifft: AW: Ordner per Excel-Liste erstelln
von: Marc
Geschrieben am: 12.09.2020 00:36:27

Hallo Jaschke,

bitteschön:
Private Sub ordner_erstellen()
Dim letzteZeile As Range
Dim leerRange As Range
Dim ordnerName As String

With ThisWorkbook.Worksheets(1)
Set letzteZeile = .Range(.Cells(1, 1), .Cells(Rows.Count, 1).End(xlUp).Rows)

For Each leerRange In letzteZeile
If Not leerRange Is Nothing Then
ordnerName = leerRange.Value
If Dir("C:\Projektordner\" & ordnerName, vbDirectory) = "" Then
  MkDir ("C:\Projektordner\" & ordnerName)
Else
End If
Else
End If
Next
End With
End Sub
Gruß Marc

Beiträge aus dem Excel-Forum zum Thema "Ordner per Excel-Liste erstelln"