Alphanummerische Eingabe geht nicht

Hallo,
mit Hilfe von Euch Profis habe ich eine Userform erstellt, in der ich nach Artikeln suche und mir die Ergebnisse in einer Listbox angezeigt werden. Das funktioniert in soweit, wenn es sich ausschliesslich um Zahlen im Textfeld handelt.
Bei Alphanummerischen Artikelnummern wird mir gar nichts angezeigt, ob wohl es den Artikel im Sheet gibt.
Wie müsste der Code geändert werden, damit ich sowohl nur Zahlen wie auch Buchstaben abfragen kann?
Derzeitiger Code ist:

Private Sub TextBox_Artikel_AfterUpdate()
Dim boVorhanden As Boolean
Dim Zeile As Long
If IsNumeric(TextBox_Artikel.Text) Then
With ThisWorkbook.Worksheets("BESTAND")
For Zeile = 2 To .Cells(.Rows.Count, 6).End(xlUp).Row
If CLng(.Cells(Zeile, 2).Value) = CLng(TextBox_Artikel.Text) Then
boVorhanden = True
ListBox1.AddItem
ListBox1.List(ListBox1.ListCount - 1, 0) = .Cells(Zeile, 1).Value
ListBox1.List(ListBox1.ListCount - 1, 1) = .Cells(Zeile, 3).Value
ListBox1.List(ListBox1.ListCount - 1, 2) = .Cells(Zeile, 2).Value
ListBox1.List(ListBox1.ListCount - 1, 3) = .Cells(Zeile, 4).Value
ListBox1.List(ListBox1.ListCount - 1, 4) = .Cells(Zeile, 7).Value
ListBox1.List(ListBox1.ListCount - 1, 5) = .Cells(Zeile, 8).Value
ListBox1.List(ListBox1.ListCount - 1, 6) = .Cells(Zeile, 9).Value
End If
Next
End With
If Not boVorhanden Then
ListBox1.Clear
MsgBox "Die Artikel-Nummer ist nicht vorhanden!"
End If
End If
End Sub

Danke
Andre

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Andre,
teste mal:

Private Sub TextBox_Artikel_AfterUpdate()

    Dim objCell As Range
    Dim strFirstAddress As String

    TextBox_Artikel.Text = Trim$(TextBox_Artikel.Text)

    If TextBox_Artikel.TextLength > 0 Then

        Call ListBox1.Clear

        With ThisWorkbook.Worksheets("BESTAND")

            Set objCell = .Columns(2).Find(What:=TextBox_Artikel.Text, After:=.Cells(.Rows.Count, 2), _
                LookIn:=xlValues, LookAt:=xlWhole, MatchCase:=False)

            If Not objCell Is Nothing Then

                strFirstAddress = objCell.Address

                Do

                    ListBox1.AddItem
                    ListBox1.List(ListBox1.ListCount - 1, 0) = objCell.Offset(0, -1).Value
                    ListBox1.List(ListBox1.ListCount - 1, 1) = objCell.Offset(0, 1).Value
                    ListBox1.List(ListBox1.ListCount - 1, 2) = objCell.Value
                    ListBox1.List(ListBox1.ListCount - 1, 3) = objCell.Offset(0, 2).Value
                    ListBox1.List(ListBox1.ListCount - 1, 4) = objCell.Offset(0, 5).Value
                    ListBox1.List(ListBox1.ListCount - 1, 5) = objCell.Offset(0, 6).Value
                    ListBox1.List(ListBox1.ListCount - 1, 6) = objCell.Offset(0, 7).Value

                    Set objCell = .Columns(2).FindNext(After:=objCell)

                Loop Until objCell.Address = strFirstAddress
            Else
                MsgBox "Die Artikel-Nummer ist nicht vorhanden!", vbExclamation, "Hinweis"
            End If
        End With
    End If
End Sub

Gruß
Nepumuk

Beliebteste Forumthreads (12 Monate)

Alphanummerische Eingabe geht nicht

7
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Alphanummerische Eingabe geht nicht

7 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu verwandten Themen

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

7
Beiträge zum Forumthread

Beiträge zu diesem Forumthread