Leere Seite zwischen zwei Umbrüchen wird trotzdem gedruckt

Hallo Zusammen,

ich bin jetzt schon mehrere Tage damit beschäftigt, wie ich meine Angebotsvorlage, welche die Daten direkt aus den Kalkulationsblättern zieht, so anpasse, dass immer ein definierter Bereich auf einer Seite gedruckt wird. Ich habe es erstmal ohne Makros gemacht, weil ich es einfach haben wollte und ich bin selbst Anfänger Level 0 was Makros angeht.
Die Seite ist so formatiert, dass die im Druckbereich ausgewählten Spalten in die Breite der A4 Seite reinpassen.
Horizontale Abgrenzung an A4 habe ich mit festen Seitenumbrüchen gemacht. Da ich im Angebotsformular je nach dem, welches Produkt das ist, einige Zeilen gruppiere, verrutscht mir das ganze nicht zusammen und alle Informationen bleiben an einer A4 je Produkt.
Das Druckdialog in Excel oder auch für PDF speichern erlaubt keine Auswahl an separaten Seiten, nur von-bis.

Versuche:
1. Ich habe versucht eine komplete Seite zu gruppieren, indem der +- Button in der obersten Zeile war, direkt unter dem Seitenumbruch. Die oberste Zeile nach dem Seitenumbruch habe ich aus dem Druckbereich rausgenommen. Das Problem ist, dass die leere Seite zwischen den zwei Seitenumbrüchen gedruckt wird. Zusätzlich dazu stellt sich die Reihenfolge der gedruckten Seiten umgekehrt.
2. Druckbereich von Zeile 1 bis zur letzten Zeile gewählt, ohne Unterbrechungen. Manuelle Seitenumbrüche hinzugefügt. Ich habe die Zellen manuell ausgeblendet. Trotzdem wird die leere Seite zwischen den zwei Umbrüchen gedruckt.
3. Ähnlich wie Versuch zwei, aber das Ausblenden der Seite über Filter an der rechten Seite gemacht.

Ich bin echt ratlos, wie ich die Struktur in Griff bekomme. Hier die Datei: https://www.herber.de/bbs/user/166424.xlsx
Danke für die Hilfe und Ratschläge im Voraus!

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Guten Morgen Zusammen,
ich habe eine Lösung für mein Problem hier gefunden:
https://www.mrexcel.com/board/threads/auto-filter-causing-blank-hidden-pages-to-print-out.1065844/#post-5118621

Das Makro entfernt leere Seiten, welche durch Seitenumbruch und ausgeblendeten Zellen entstanden sind und druckt direkt ins PDF. ...ins Modul speichern.

Sub PrintVisible()

  Dim rng As Range, s As String

  Set rng = ActiveSheet.UsedRange.Cells.SpecialCells(xlCellTypeVisible)

  s = ActiveSheet.PageSetup.PrintArea

  If Len(s) > 0 Then

    Set rng = Intersect(rng, Range(s))

  End If

  If rng Is Nothing Then

    MsgBox "Nothing to print", , "Exit"

    Exit Sub

  End If

  Application.EnableEvents = False

  rng.PrintOut

  Application.EnableEvents = True

End Sub

 

Sub SaveAsPdf()

  Dim FileName As String, Path As String, rng As Range, s As String

  Set rng = ActiveSheet.UsedRange.Cells.SpecialCells(xlCellTypeVisible)

  s = ActiveSheet.PageSetup.PrintArea

  If Len(s) > 0 Then

    Set rng = Intersect(rng, Range(s))

  End If

  If rng Is Nothing Then

    MsgBox "Nothing to print", , "Exit"

    Exit Sub

  End If

  With ThisWorkbook

    Path = .Path & "\"

    FileName = Left(.Name, InStrRev(.Name, ".")) & "pdf"

  End With

  FileName = Application.InputBox("Name of the PDF file", Path, FileName, Type:=2)

  If Trim(FileName) = "" Then

    MsgBox "Exit without saving"

    Exit Sub

  End If

  FileName = Path & FileName

  If Dir(FileName) > "" Then

    If MsgBox("File exists. Do you want to overwrite it?", vbYesNo, FileName) = vbNo Then

      MsgBox "Exit without saving"

      Exit Sub

    End If

  End If

  Application.EnableEvents = False

  On Error GoTo exit_

  rng.ExportAsFixedFormat Type:=xlTypePDF, _

                            FileName:=Path & FileName, _

                            Quality:=xlQualityStandard, _

                            IncludeDocProperties:=True, _

                            IgnorePrintAreas:=False, _

                            OpenAfterPublish:=False

exit_:

  Application.EnableEvents = True

  If Err Then MsgBox Err.Description, vbExclamation, "Error - file is in usage"

End Sub

Oder man kann diesen u.g. Code in Objekt DieseArbeitsmappe einfügen. Dann werden die leeren Seiten in Druckvorschau gezeigt, beim Drucken (Papier, PDF) werden die Leeren Seiten aber entfernt.

Option Explicit

 

Dim IsSaving As Boolean

 

Private Sub Workbook_BeforePrint(Cancel As Boolean)

  Dim rng As Range, s As String

  Set rng = ActiveSheet.UsedRange.Cells.SpecialCells(xlCellTypeVisible)

  s = ActiveSheet.PageSetup.PrintArea

  If Len(s) > 0 Then

    Set rng = Intersect(rng, Range(s))

  End If

  If rng Is Nothing Then

    MsgBox "Nothing to print", , "Exit"

    Exit Sub

  End If

  Application.EnableEvents = False

  If IsSaving Then

    IsSaving = False

    'Application.OnTime Now, "SaveAsPdf"

  Else

    rng.PrintOut

    Cancel = True

  End If

  Application.EnableEvents = True

End Sub

 

Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)

  IsSaving = True

End Sub

 

Private Sub Workbook_AfterSave(ByVal Success As Boolean)

  IsSaving = False

End Sub

Beliebteste Forumthreads (12 Monate)

Leere Seite zwischen zwei Umbrüchen wird trotzdem gedruckt

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Leere Seite zwischen zwei Umbrüchen wird trotzdem gedruckt

5 Beiträge zum Forumthread Beiträge zu diesem Forumthread

VBA Beispiele zu verwandten Themen

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread