Wenn Wert aus Blatt1 nicht in Blatt 2 dann Zellfarbe = Gelb

Dim MeinBereich As Range, AndererBereich As Range 'Dim LetzteZeile 'Dim i Sheets("Data").Select LetzteZeile = LastRow(Sheets("Data")) i = 0 Set MeinBereich = Range("C2:C" & LetzteZeile) Set AndererBereich = Worksheets("data zum import").Range("$C:$C") With Worksheets("Data") For i = 1 To LetzteZeile If WorksheetFunction.CountIf(AndererBereich, Range("C" & i)) = 0 Then .Interior.ColorIndex = 15 Else End If Next End With

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Dim MeinBereich As Range, AndererBereich As Range 'Dim LetzteZeile - habe ich bereits vorher anderweitig festglegt 'Dim i - habe ich bereits vorher anderweitig festglegt LetzteZeile = LastRow(Sheets("Data")) i = 0 Set MeinBereich = Range("C2:C" & LetzteZeile) Set AndererBereich = Worksheets("data zum import").Range("$C:$C") For i = 2 To LetzteZeile With Worksheets("Data") If WorksheetFunction.CountIf(AndererBereich, Range("C" & i)) = 0 Then .Range("C" & i).Interior.Color = RGB(255, 255, 0) Else End If End With Next

Dim MeinBereich As Range, AndererBereich As Range 'Dim LetzteZeile - habe ich bereits vorher anderweitig festglegt 'Dim i - habe ich bereits vorher anderweitig festglegt i = 0 LetzteZeile = LastRow(Sheets("Data")) Set MeinBereich = Range("C2:C" & LetzteZeile) Set AndererBereich = Worksheets("data zum import").Range("$C:$C") For i = 2 To LetzteZeile With Worksheets("Data") If WorksheetFunction.CountIf(AndererBereich, Range("C" & i)) > 0 Then .Range("C" & i).Interior.Color = RGB(255, 255, 0) Else End If End With Next

Hallo Mi (man spricht sich im forum per Vorname an ;-)

der stabile Klassiker: die Variante mit doppelter For-Schleife:

Sub VergleichenUndFärben()

Dim D As Long

Dim I As Long

Dim wD As Worksheet

Dim wI As Worksheet



    Set wI = Worksheets("data zum import")

    Set wD = Worksheets("Data")

    For I = 2 To wI.Cells(Rows.Count, "C").End(xlUp).Row

        For D = 1 To wD.Cells(Rows.Count, "C").End(xlUp).Row

            If wI.Cells(I, "C").Value = wD.Cells(D, "C").Value Then wD.Cells(D, "C").Interior.ColorIndex = 15

        Next

    Next

End Sub

die Objekt-Variante davon:

Sub VergleichenUndFärben()

Dim D As Range

Dim I As Range



    With Worksheets("data zum import")

        For Each I In Range(.Range("C2"), .Cells(Rows.Count, "C").End(xlUp))

            With Worksheets("Data")

                For Each D In Range(.Range("C2"), .Cells(Rows.Count, "C").End(xlUp))

                    If I.Value = D.Value Then D.Interior.ColorIndex = 15

                Next

            End With

        Next

    End With

End Sub

eine Version mit CountIf:

Sub VergleichenUndFärben()

Dim cellD As Range

Dim rgI As Range



    With Worksheets("data zum import")

        Set rgI = Intersect(.Columns(3), .UsedRange)

    End With

    With Worksheets("Data")

        For Each cellD In Range(.[C2], .Cells(Rows.Count, "C").End(xlUp))

            If WorksheetFunction.CountIf(rgI, cellD) Then cellD.Interior.ColorIndex = 15

        Next

    End With

End Sub

und eine Version mit Dictionary (schon, aber irgendwie zu heavy):

Sub VergleichenUndFärben()

Dim Dic As Object

Dim Z As Range 'Z wie Zelle



    Set Dic = CreateObject("Scripting.Dictionary")

    With Worksheets("data zum import")

        For Each Z In Intersect(.Columns(3), .UsedRange)

            Dic(Z.Value) = 1

        Next

    End With

    With Worksheets("Data")

        For Each Z In Range(.[C2], .Cells(Rows.Count, "C").End(xlUp))

            If Dic.Exists(Z.Value) Then Z.Interior.ColorIndex = 15

        Next

    End With

    Set Dic = Nothing

End Sub

VG
Yal

Beliebteste Forumthreads (12 Monate)

Wenn Wert aus Blatt1 nicht in Blatt 2 dann Zellfarbe = Gelb

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

Wenn Wert aus Blatt1 nicht in Blatt 2 dann Zellfarbe = Gelb

8 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread