AW: datenimport die zweite
26.09.2003 00:11:27
Thomas Scher
Hallo Jörg ,
ich habe dir hier mal was raus kopiert aus dem Forum !!
Vielleicht hilft das !!!
Datensätze aus einer Access-Datenbank einlesen
Prozedur: dbReadData
Art:
Sub
Modul: Standard
Zweck: Datensätze aus einer Access-Datenbank einlesen
Ablaufbeschreibung:
Variablendeklaration
Objektvariable mit dem Zieldatenblatt belegen
String-Variable mit Dateipfad und Dateiname belegen
String-Variable mit dem Tabellennamen belegen
Prüfung, ob die Quelldatenbank vorhanden ist
Wenn nein, Warnmeldung und Ausstieg
Zielblatt leeren
Zellen als Text formatieren
Datenbank öffnen
In einer Schleife die Spaltenköpfe einlesen
Datentabelle öffnen
Erste Zielzeile festlegen
Schleife über alle Datensätze bilden
Zeilenzähler eins hochzählen
Schleife über alle Spalten bilden
Datensatz einlesen
Datenbank schließen
Spaltenbreite optimieren
Erste Zeile mit dem Schriftattribut Bold belegen
Excel-Datenmaske aufrufen
Code:
Sub dbReadData()
Dim dbFile As Database
Dim dbSet As Recordset
Dim wks As Worksheet
Dim sFile As String, sTable As String
Dim iCount As Integer, iCounter As Integer
Dim iRow As Integer, iCol As Integer
Set wks = ThisWorkbook.Worksheets("Data")
With ThisWorkbook.Worksheets("Initialize")
sFile = .Range("Pfad").Value & "\" & .Range("Datei").Value
sTable = .Range("Tabelle").Value
End With
If Dir(sFile) = "" Then
MsgBox "Sie müssen die Daten zuerst exportieren!"
Exit Sub
End If
wks.Range("A1").CurrentRegion.Clear
wks.Cells.NumberFormat = "@"
Set dbFile = OpenDatabase(sFile)
For iCounter = 0 To dbFile.TableDefs(sTable).Fields.Count - 1
wks.Cells(1, iCounter + 1).Value = _
dbFile.TableDefs(sTable).Fields(iCounter).Name
Next iCounter
Set dbSet = dbFile.OpenRecordset(sTable, dbOpenDynaset)
iRow = 1
Do Until dbSet.EOF
iRow = iRow + 1
For iCol = 0 To WorksheetFunction.CountA(wks.Rows(1)) - 1
If IsNull(dbSet.Fields(iCol).Value) = False Then
wks.Cells(iRow, iCol + 1) = _
CStr(dbSet.Fields(iCol).Value)
End If
Next iCol
dbSet.MoveNext
Loop
dbFile.Close
wks.Columns.AutoFit
wks.Rows(1).Font.Bold = True
Call dbDataMask
End Sub
Gruss
der Thomas