ZÄHLENWENN-Problem

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

hallo gerda
versuchs mal so:

	A	B	C	D	E	F	G	H	I	J	K	L	M	N
1	96			6	6	6	6		Tabellen-Auswertung:			6	2
2	95			6	6	6	6					7	0
3	94			7	6	6	7					8	1
4	92			8	8	7	7
5	90			8	8	7	8		Wenn in A1:A5 und A 11:A15 und A21:A25 die Zahlen 91 oder 92 stehen,
6	96	5	3	3					wievielmal stehen dann in D1:D5 und D11:D15 und D21:D25 die Zahlen 6 und 7 und 8
7	95	5	3	3
8	93	6	3	3
9	91	7	3	3
10	91	7	3	3					Wenn in A6:A10 und A 16:A20 und A26:A30 die Zahl 95 steht,
11	95			6	6	6	6		wievielmal steht dann in B6:B10 und B16:B20 und B26:B30 die Zahl 5
12	93			7	7	7	7					5	2
13	92			6	7	8	7
14	90			6	7	8	8
15	94			6	6	7	7		Wievielmal steht in C6 bis C10 und C16:C20 und C26:C30 die Zahl 3
16	96	5	2	2					Mit ZÄHLENWENN kriege ich das nur hin, wenn ich die ganze Spalte C als Bezug nehme.
17	93	6	3	3								3	10
18	91	7	2	2					Alle weiteren Versuche mit UND/ODER habe ich leider nicht hinbekommen.
19	92	7	2	3
20	89	8	3	3
21	95			6	6	6	6
22	93			7	7	7	7
23	91			6	8	7	7
24	90			6	7	8	7
25	87			8	8	8	8
26	95	5	2	2
27	93	6	3	3
28	92	7	3	3
29	90	8	3	3
30	87	9	5	5

Formeln der Tabelle

M1 : {=SUMME(WENN(REST((GANZZAHL((ZEILE($A$1:$A$100)-1)/5));2)=0;($A$1:$A$100={91.92})*($D$1:$D$100=L1)))}
M2 : {=SUMME(WENN(REST((GANZZAHL((ZEILE($A$1:$A$100)-1)/5));2)=0;($A$1:$A$100={91.92})*($D$1:$D$100=L2)))}
M3 : {=SUMME(WENN(REST((GANZZAHL((ZEILE($A$1:$A$100)-1)/5));2)=0;($A$1:$A$100={91.92})*($D$1:$D$100=L3)))}
M12 : {=SUMME(WENN(REST((GANZZAHL((ZEILE($A$1:$A$100)-1)/5));2)>0;($A$1:$A$100=95)*($B$1:$B$100=L12)))}
M17 : {=SUMME(WENN(REST((GANZZAHL((ZEILE($A$1:$A$100)-1)/5));2)>0;($C$1:$C$100=3)*1))}

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
Die formeln sind Matrixformeln.
also eingabe mit strg+shift+enter abschliessen.
ransi

hallo gerda
wenn du dich entschließen könntest die prüfung nicht auf die zeilennummer zu beziehen
sondern darauf ob Spalte B ="" dann wirds erheblich einfacher nachzuvollziehen.
dann entfällt das ganze "(WENN(REST((GANZZAHL((ZEILE($A$1:$A$100)-1)/5));2)=0;(" -Konstrukt um die spaltennummer zu überprüfen.
dann tut es auch ne einfache summenprodukt()Formel.

	I	J	K	L	M
1	Tabellen-Auswertung:			6	2
2				7	0
3				8	1
4
5	Wenn in A1:A5 und A 11:A15 und A21:A25 die Zahlen 91 oder 92 stehen,
6	wievielmal stehen dann in D1:D5 und D11:D15 und D21:D25 die Zahlen 6 und 7 und 8
7
8
9
10	Wenn in A6:A10 und A 16:A20 und A26:A30 die Zahl 95 steht,
11	wievielmal steht dann in B6:B10 und B16:B20 und B26:B30 die Zahl 5
12				5	2
13
14
15	Wievielmal steht in C6 bis C10 und C16:C20 und C26:C30 die Zahl 3
16	Mit ZÄHLENWENN kriege ich das nur hin, wenn ich die ganze Spalte C als Bezug nehme.
17				3	10
18	Alle weiteren Versuche mit UND/ODER habe ich leider nicht hinbekommen.

Formeln der Tabelle

M1 : =SUMMENPRODUKT(($A$1:$A$100={91.92})*($B$1:$B$100="")*($D$1:$D$100=L1)*1)
M2 : =SUMMENPRODUKT(($A$1:$A$100={91.92})*($B$1:$B$100="")*($D$1:$D$100=L2)*1)
M3 : =SUMMENPRODUKT(($A$1:$A$100={91.92})*($B$1:$B$100="")*($D$1:$D$100=L3)*1)
M12 : =SUMMENPRODUKT(($A$1:$A$100=95)*($B$1:$B$100=5)*1)
M17 : =SUMMENPRODUKT(($B$1:$B$100<>"")*($C$1:$C$100=3)*1)

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
ransi

Beliebteste Forumthreads (12 Monate)

3 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread