Thema: Summenprodukt mit variabler Spaltenangabe | Herbers Excel-Forum

Hallo liebe Experten,
ich habe folgendes Problem bei welchem ich etwas Hilfe bräuchte.
Ausgangsituation:
In Tabelle1 stehen in Zellen A1, A2 und A3 jeweils die Kriterien Krit1, Krit2 und Krit3.
In Tabelle2 stehen in den Zeilen der Spalte A die Werte die das Krit1 erfüllen können,
in den Zeilen der Spalte B die Werte die das Krit2 erfüllen können.
Das Krit3 ist ein Monatsname mit Jahresangabe (z.B. Jan09). Dieser steht als Spaltenüberschrift in einer der Spalten C1 bis BY1 (variabel, keine Doppelnennungen)
Nun zur Frage:
Über die Funktion SUMMENPRODUKT() kann ich Zahlen in einer fest vorgegeben Spalte addieren die dem Krit1 und Krit2 entsprechen.
Lässt sich diese Funktion so umbauen, dass anstatt der fest vorgegeben Spalte, die Spalte gesucht wird welche als Spaltenüberschrift das Krit3 hat und dann die Werte aus dieser Spalte addiert werden (wenn sie dem Krit1 und Krit2 entsprechen)?
Vielen Dank schon mal.
Gruß
Jonathan

hallo jonathan,
wo stehen deine suchkriterien nach denen in den spalten aufsummiert werden soll?
gruß selli

Hallo selli,
die Suchkriterien stehen in Tabelle1 in den Zellen A1, A2 und A3
Gruß
Jonathan

hallo jonathan,
ja, habe ich überlesen.
versuche mal das hier:
=SUMMENPRODUKT((Tabelle2!A2:A20=A1)*(Tabelle2!B2:B20=A2)*(INDIREKT("Z2S"&VERGLEICH(A3; Tabelle2!C1:BY1;0)+2&":Z20S"&VERGLEICH(A3;Tabelle2!C1:BY1;0)+2;FALSCH)))
gruß selli

Hallo selli,
vielen Dank für deine schnelle Antwort.
Leider kommt als Ergebnis bei mir immer 0 raus...
Ich habe mal ein Bsp-File hier angehängt:
https://www.herber.de/bbs/user/66636.xls
Gruß
Jonathan

habe in der formel noch einmal den bezug auf die tabelle2 vergessen.
dann also so:
=SUMMENPRODUKT((Tabelle2!A2:A20=A1)*(Tabelle2!B2:B20=A2)*(INDIREKT("Tabelle2!Z2S"&VERGLEICH(A3; Tabelle2!C1:BY1;0)+2&":Z20S"&VERGLEICH(A3;Tabelle2!C1:BY1;0)+2;FALSCH)))
gruß selli

Hallo selli,
herzlichen Dank. Die Formel funktioniert einwandfrei!
Das angehängte File von eben ist somit auch überflüssig... =)
Gruß
Jonathan

Hallo Jonathan,
so gehts einfacher und schneller:
=SUMMENPRODUKT((Tabelle2!A2:A20=A1)*(Tabelle2!B2:B20=A2)*(A3=Tabelle2!C1:J1)*Tabelle2!C2:J20)
Gruß Ingo
PS eine Rückmeldung wäre nett...

Hallo Ingo,
vielen Dank auch für deine Rückmeldung.
Deine Lösung funktioniert auch einwandfrei.
Gruß
Jonathan

.