Live-Forum - Die aktuellen Beiträge
Datum
Titel
15.10.2025 16:22:17
Datum ist nicht Datum :(
15.10.2025 15:02:20
Blockpfeile mit Makro gehen nicht mehr nach freigabe
15.10.2025 13:51:13
VBA - Fortschrittsbalken unabhängig von Zellen
15.10.2025 13:31:47
WENN Formel mit zwei Bedingungen über 4 Spalten...
Keine passende Antwort im Forumarchiv gefunden?
Stelle deine Frage im Live-Forum
Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Vorheriger Thread
Vorheriger Thread
Rückwärts Blättern
1164to1168
1164to1168
Aktuelles Verzeichnis
Verzeichnis Übersicht
Verzeichnis Übersicht
Übersicht Verzeichnisse
Nächster Thread
Nächster Thread
Vorwärts blättern
Inhaltsverzeichnis

Ersetzen durch nichts "funst" nicht

Forumthread: Ersetzen durch nichts "funst" nicht

Ersetzen durch nichts "funst" nicht
Keule30
Hi Leute,
....vielleicht hat von euch einer Plan, warum diese relativ simple Geschichte nicht funktionieren will:
In Spalte B stehen Minutenangaben: 12:00, 05:00; 13:00
aber auch stehen in B "fehlerhafte " Angaben wie: 12min, 20min etc.
Will man diese über eine Formel auswerten, stößt man natürlich darauf, diese unterschiedlichen Formate manuell korrigiren zu müssen...was auch nicht das Problem darstellt.
Es soll hier also über eine Formel automatisch funktionieren, so dass es in Spalte C alles im richtigen Format ausspuckt.
Meine Formel in Spalte C hierfür sieht so aus:
=WENN(ISTZAHL(SUCHEN("min";B9));UND(ERSETZEN(B9;LÄNGE(B9);3;"");(B9/1440));B9)
(Durch die UND-Verknüpfung soll der entstehende Datumswert auf Minuten berechnet werden)
Soweit ich das analysieren konnte, liegt der Fehler hier:
ERSETZEN(B9;LÄNGE(B9);3;"")
Obwohl ich angegeben habe, dass stets die letzten 3 Stellen, also "min" gelöscht werden soll, löscht diese Funktion immer nur die letzte Stelle also nur das "n", so dass dann "12 mi" da steht...und diesen Wert kann Excel natürlich nicht durch 1440 teilen.
Vielleicht hab ich auch nur Tomaten auf den Augen und Ihr habt eine Idee?
Liebe Grüße!
Anzeige
Parameter falsch interpretiert
02.07.2010 16:03:44
NoNet
Hallo Keule,
da hast Du wohl den Parameter der ERSETZEN()-Funktion falsch interpretiert :
Ab der letzten Stelle (Länge(B9)) werden 3 Stelle ersetzt - also nur die letzte Stelle !
Was Du möchtest ist wohl folgendes :
=WENN(ISTZAHL(SUCHEN("min";B9));ERSETZEN(B9;LÄNGE(B9)-2;3;"")/1440;B9)
Gruß, NoNet
gegen    2:1

Anzeige
Das wäre mein Tipp
02.07.2010 21:24:32
FP
Hallo NoNet,
=TEXT(WECHSELN(A1;"min";"")/1440;"[hh]:mm")
DE : ARG 2 : 1 --> genau mein Tipp ! ! ! ( und ich hatte schon damit Recht, dass NL gegen BRA gewinnt - okay ich hatte 1:0 getippt, aber 2:1 ist ja auch nicht wesentlich anders :D )
Falls Du Dir einmal eine Turniermappe von mir anschauen willst ( für EM, WM, Quali und Meisterschaften geeignet ), schau doch mal hier http://www.office-loesung.de/fpost1633127.php#1633127 vorbei.
Kommentare ( positiv wie negativ ), Verbesserungsvorschläge usw jederzeit willkommen ;-)
Servus aus dem Salzkammergut und ( ich drücke die Daumen )
Anzeige
AW: Parameter falsch interpretiert
02.07.2010 21:27:11
FP
Hallo NoNet,
noch etwas hier geposteten Problem:
=TEXT(WECHSELN(A1;"min";"")/WAHL(TYP(A1);1;1440);"[hh]:mm")
funktioniert dann auch, wenn schon Zeitangaben in A1 stehen
Servus aus dem Salzkammergut
Franz
AW: Ersetzen durch nichts "funst" nicht
02.07.2010 16:04:23
Beverly
Hi,
meinst du das so:
=WENN(ISTZAHL(WECHSELN(B9;"min";"")*1);WECHSELN(B9;"min";"")*1/1440;B9)

Anzeige
dafür genügt letztendlich
02.07.2010 21:31:16
FP
Hallo,
=WECHSELN(A1;"min";"")/WAHL(TYP(A1);1;1440)
und die Ergebniszelle als Zeit formatieren ( z.B. [hh]:mm
Servus aus dem Salzkammergut
Franz
AW: dafür genügt letztendlich
05.07.2010 10:36:19
Keule30
Aloha,
vielen Dank an alle für die vielen Antworten und Vorschläge.
Ehrlich gesagt weis ich grad gar nicht, welche der vorgeschlagenen Formeln nun die effizienteste ist?
Genauer gesagt, gibt es auch zwei Möglichkeiten, einmal der Typ, dass "min" gelöscht und durch 1440
geteilt werden muss, es kann aber auch sein, dass "min:" mit Doppelpunkt da steht, was dann auch
ersetzt werden müsste.
(Bitte nicht fragen warum auch "min" mit Doppelpunkt möglich ist, klingt komisch ..ist aber so)
Liebe Grüße
Anzeige
AW: dafür genügt letztendlich
05.07.2010 11:07:21
Beverly
Hi,
=WENN(ISTZAHL(WECHSELN(WECHSELN(B9;"min";"");":";"")*1);WECHSELN(WECHSELN(B9;"min";"");":";"") *1/1440;B9)

Formel die "alles" nach MIN umrechnet
05.07.2010 12:25:17
FP
Hallo,
=WECHSELN(A1;LINKS("min:";3+ANZAHL(1/SUCHEN(":";A1)));"")/WAHL(TYP(A1);(A1>1)*1439+1;1440)
in A1 darf dabei stehen: z.B. 23 Minuten
min23
min:23
23:00 ( als Zeitwert mit Format mm:ss )
23 ( als dezimaler Zahlwert )
Servus aus dem Salzkammergut
Franz
Anzeige
AW: Formel die "alles" nach MIN umrechnet
05.07.2010 13:00:31
Keule30
Ihr seid echt genial!
Ich muss mir das jetzt erst mal in Ruhe "reinziehen".
AW: Formel die "alles" nach MIN umrechnet
05.07.2010 14:33:18
Keule30
Hallo Franz,
Deine Formel funktioniert super! Eine Verständnisfrage habe ich dazu:
Durch "LINKS" werden die ersten 3 Zeichen der Zeichenfolge "min" genommen. Danach:
"+ANZAHL(1/SUCHEN..". Die Suchen - Funktion nach dem Doppelpunkt leuchtet auch ein, aber warum
ANZAHL und eins geteilt durch Suchen? Was bedeutet das?
Liebe Grüße
Anzeige
ANZAHL ...
05.07.2010 15:03:58
FP
Hallo,
... ermittelt normalerweise wieviele Zahlen in einem bestimmten Bereich stehen.
Hier wird es "zweckentfremdet" so verwendet: ermittle wieviele Zahlen durch die Rechnung 1/x entstehen.
Ist x ein Fehlerwert weil die Suche nach ":" fehlschlägt, so ist ANZAHL 0.
Dabei merke ich gerade, dass man 1/ in diesem Fall ruhig weglassen kann, da SUCHEN ja entweder eine Zahl oder einen Fehlerwert zurückgibt ( habe wieder mal zu umständlich gedacht ).
verkürzte und funktionierende Formel daher:
=WECHSELN(A1;LINKS("min:";3+ANZAHL(SUCHEN(":";A1)));"")/WAHL(TYP(A1);(A1>1)*1439+1;1440)
Servus aus dem Salzkammergut
Franz
Anzeige
AW: ANZAHL ...
06.07.2010 08:51:37
Keule30
Hallo Beverly & Franz,
Entschuldigt bitte erstmal, dass ich das gleiche hier schon einmal geschrieben bzw. gepostet habe, war mir aber nicht sicher ob Ihr es lest, da ich mir zuletzt selbst geantwortet habe (es sind die ersten Male, dass ich etwas in einem Forum schreibe).
wie gesagt, danke und es funktionieren natürlich beide Formeln super.
Eine kleine abgewandelte aber fast identische Problematik noch, hier ein Beispiel:
Sartzeit Spalte A : bis Endzeit in Spalte B: in Spalte C ist Arbeitszeit in Min gesucht
23:30 bis 1:00
06:30 bis 7:00
12 min:
bei "12min:"wurde Arbeitszeit ohne Startzeit/Endzeit eingetragen (insgesamt, kann in Spalte A oder B stehen)
15 min (insgesamt)
12:00 bis 12:15
Wie vorhin, gilt es die Arbeitszeit in Minuten zu ermitteln, die Uhrzeitdifferenz daher über diese Grundformel:
=WENN(B1<A1;1+B1-A1; B1-A1)~f~
Weil ab und zu auch Leerzeilen auftreten und ich bei diesen keine Uhrzeitdifferenz als Null-Minuten angezeigt bekommen möchte, diese Ergänzung durch ISTZAHL (Zellen die leer sind werden nicht als 0:00 angezeigt):
~f~=WENN(UND(ISTZAHL(A1);ISTZAHL(B1);(B1<A1));1+B1-A1;WENN(UND(ISTZAHL(A1);ISTZAHL(B1);(B1>A1));B1-A1;……
…….jetzt geht die Formel mit dem Part von Franz weiter, um das mit dem „min“ und „min:“ heraus zu rechnen:
WENN(ISTZAHL(WECHSELN(B1;LINKS("min:";3+ANZAHL(1/SUCHEN(":";B1)));"")*1);WECHSELN(B1;LINKS("min:";3+ANZAHL(SUCHEN(":";B1)));"")/1440; WENN(ISTZAHL(WECHSELN(A1;LINKS("min:";3+ANZAHL(SUCHEN(":";A1)));"")*1);WECHSELN(A1;LINKS("min:";3+ANZAHL(SUCHEN(":";A1)));"")/1440;""))))
Obwohl die Formel von Franz funktioniert, bleibt diese in der Kombination an der Stelle „Suchen“ hängen und ich hab leider keinen Schimmer warum?
Ich wäre euch für eure Hilfe sehr dankbar!
Anzeige
probier's mal damit
06.07.2010 13:14:49
FP
Hallo,
{=WAHL(ANZAHL(A2:B2;1/TYP(A2:B2));WECHSELN(WENN(A2="";B2;A2);LINKS(WENN(A2="";B2;A2); 3+ANZAHL(SUCHEN(":";WENN(A2="";B2;A2))));"")/1440;MAX(A2:B2)/1440;B2+(A2>B2)-A2) }
Servus aus dem Salzkammergut
Franz
AW: probier's mal damit
06.07.2010 13:21:26
FP
Hallo,
funktioniert auch ohne {}
=WAHL(ANZAHL(A2:B2;1/TYP(A2:B2));WECHSELN(WENN(A2="";B2;A2);LINKS(WENN(A2="";B2;A2); 3+ANZAHL(SUCHEN(":";WENN(A2="";B2;A2))));"")/1440;MAX(A2:B2)/1440;B2+(A2>B2)-A2)
Servus aus dem Salzkammergut
Franz
Anzeige
oder mit {} aber kürzer
06.07.2010 13:27:05
FP
Hallo,
{=WAHL(ANZAHL2(A2:B2);MAX(--WECHSELN(A2:B2&0;LINKS("min:";3+ANZAHL(SUCHEN(":";A2:B2)));""))/14400; B2+(A2>B2)-A2) }
Servus aus dem Salzkammergut
Franz
Feedback und 3 kleine Fragen
07.07.2010 14:47:41
Keule30
Hallo Beverly & Franz,
ich hätte nicht gedacht, dass ich das noch hin bekomme: aber Dank eurer Beiden Hilfe konnte ich mir nun sowohl aus Beverly’s als auch aus den Formeln von Franz meine „perfekte Formel“ zusammenbauen: )))
=WENN(UND(ISTLEER(A7);ISTLEER(B7));"";WAHL(ANZAHL2(A7:B7);(WECHSELN(WECHSELN(A7&B7;"min";"");":";"")*1/1440);B7+(A7>B7)-A7))
Um Euch ein Feedback geben zu können: hier die jeweiligen Vorteile/Nachteile zu euren Formeln: 1) Beverly’s:
=WENN(ISTZAHL(WECHSELN(WECHSELN(B9;"min";"");":";"")*1);WECHSELN(WECHSELN(B9;"min";"");":";"") *1/1440;B9)
  • Vorteil: Diese Formel ersetzt „min:“ und „min“ unabhängig davon ob zwischen der Zahl und dem min noch Freizeichen sind; SUPER!
  • Nachteil: Diese Formel kann nur auf eine Bezugsspalte angewendet werden; was aber damals von mir auch gar nicht anders „gefordert“ war (vgl. Nachricht von Keule vom 06.07.2010 !
    2) Franz:
    {=WAHL(ANZAHL2(A2:B2);MAX(--WECHSELN(A2:B2&0;LINKS("min:";3+ANZAHL(SUCHEN(":";A2:B2)));""))/14400; B2+(A2>B2)-A2) }
  • Vorteil 1: Diese Formel berechnet die Uhrzeitdifferenz (Arbeitszeit in Minuten), zwischen zwei Spalten, auch wenn in der einen oder anderen Zelle von Spalte A oder B bereits die Gesamtzeit schon eingetragen ist (z.B. 12 min).
  • Vorteil 2: Diese Formel ist genial kurz gehalten
  • Nachteil 1: Diese Formel funktioniert nicht wenn ein Freizeichen zwischen der Zahl und „min“ vorkommt.
  • Nachteil 2: Diese Formel kann man nicht mit der Formelauswertung in Excel auswerten, um sie besser zu verstehen (Excel bleibt ab einem best. Punkt dann immer hängen und muss beendet werden).
    Hier nur noch 3 kurze Fragen:
…Wie gesagt: ich hatte nun die Vorteile eurer Formeln erkannt und mir versucht die für mich „ _
perfekte“ zu entwickeln.
Am Anfang wollte es nur nicht klappen weil ich ähnlich wie auch Franz:
…WECHSELN(A2:B2;"min";"");":";"")*1/1440);B7+(A7>B7)-A7))…
geschrieben habe.
Die Betonung liegt auf dem Bereich A2:B2.
So hatte es einfach nicht funktionieren wollen. Durch Zufall hatte ich dann anstelle des  _
Doppelpunktes   ein &-Zeichen gemacht und plötzlich funktionierte es.
Frage 1) 	Warum kann ich anstelle des &-Zeichens nicht auch wie Franz einen Doppelpunkt  _
schreiben?
Frage 2)	Und warum funktioniert dieses &-Zeichen nicht auch bei der vorangestellten „ISTLEER- _
Funktion“?
Frage 3)	Weshalb muss ich nach der „WECHSELN-Funktion“ alles mit *1 multiplizieren?
Vielen Dank für eure Antwort im Voraus.

    • Anzeige
    neue noch kürzere Formel
    07.07.2010 22:09:11
    FP
    Hallo,
    ... noch dazu ohne {}
    =WAHL(ANZAHL2(A2:B2);VERWEIS(999;RECHTS(A2&B2;SPALTE(2:2))/1440); B2+(A2>B2)-A2)
    @1. / 2. Frage - keine Ahnung, bei mir würde es funktionieren
    @3. WECHSELN gibt immer "Text" zurück, durch Multiplilkation mit 1 ( oder Addition von 0 ) wird aus einer "Textzahl" wieder eine Zahl
    Servus aus dem Salzkammergut
    Franz
    Anzeige
    AW: dafür genügt letztendlich
    05.07.2010 19:47:50
    Keule30
    Hallo Beverly & Franz,
    wie gesagt, danke und es funktionieren natürlich beide Formeln super.
    Eine kleine abgewandelte aber fast identische Problematik noch, hier ein Beispiel:
    Sartzeit Spalte A : bis Endzeit in Spalte B: in Spalte C ist Arbeitszeit in Min gesucht
    23:30 bis 1:00
    06:30 bis 7:00
    12 min:
    bei "12min:"wurde Arbeitszeit ohne Startzeit/Endzeit eingetragen (insgesamt, kann in Spalte A oder B stehen)
    15 min (insgesamt)
    12:00 bis 12:15
    Wie vorhin, gilt es die Arbeitszeit in Minuten zu ermitteln, die Uhrzeitdifferenz daher über diese Grundformel:
    =WENN(B1<A1;1+B1-A1; B1-A1)~f~
    Weil ab und zu auch Leerzeilen auftreten und ich bei diesen keine Uhrzeitdifferenz als Null-Minuten angezeigt bekommen möchte, diese Ergänzung durch ISTZAHL (Zellen die leer sind werden nicht als 0:00 angezeigt):
    ~f~=WENN(UND(ISTZAHL(A1);ISTZAHL(B1);(B1<A1));1+B1-A1;WENN(UND(ISTZAHL(A1);ISTZAHL(B1);(B1>A1));B1-A1;……
    …….jetzt geht die Formel mit dem Part von Franz weiter, um das mit dem „min“ und „min:“ heraus zu rechnen:
    WENN(ISTZAHL(WECHSELN(B1;LINKS("min:";3+ANZAHL(1/SUCHEN(":";B1)));"")*1);WECHSELN(B1;LINKS("min:";3+ANZAHL(SUCHEN(":";B1)));"")/1440; WENN(ISTZAHL(WECHSELN(A1;LINKS("min:";3+ANZAHL(SUCHEN(":";A1)));"")*1);WECHSELN(A1;LINKS("min:";3+ANZAHL(SUCHEN(":";A1)));"")/1440;""))))
    Obwohl die Formel von Franz funktioniert, bleibt diese in der Kombination an der Stelle „Suchen“ hängen und ich hab leider keinen Schimmer warum?
    Ich wäre euch für eure Hilfe sehr dankbar!
    Anzeige
    ;

    Forumthreads zu verwandten Themen

    Suchen und Ersetzen durch
    pitt_111@gmx.de

    Hallo Excel Gemeinde,
    brauche wieder Eure EErfahrung und Hilfe.
    In angehängter Tabelle soll nach Werten gesucht werden und diese
    sollen entsprechend durch 1 ersetzt werden.
    https://www.herber.de/bbs/user/59198.xls
    Das suchen und ersetzen soll sich aber nur auf das betreffen...
    07.02.2009 09:50:37
    Thread-ID: 1047999
    2 Beiträge
    Suchen und Ersetzen durch VBA
    Sascha

    Hallo zusammen,
    ich habe ein Problem.
    Ich habe eine Userform für die verwaltung von Kundendaten. Jetzt soll es möglich sein einen Kunden anzulegen (funktioniert), zu suchen (funktioniert) und einen gesuchten Kunden zu ändern (funktioniert nicht richtig).
    Leider fügt mir mein VBA Cod...
    15.11.2010 16:51:04
    Thread-ID: 1186859
    6 Beiträge
    Zeichen ersetzen durch Positionszahl
    Matthias

    Hallo und Guten Morgen
    In meiner Zeile A1 steht beispielsweise:
    X XX X
    Nun möchte ich diese X durch eine Zahl ersetzen und zwar deren Position angeben. Das sähe dann wie folgt aus:
    1 45 7
    Die leerschläge könnten weggelassen werden, Hauptsache ich sehe irgendwie diese Zahle...
    21.06.2013 10:02:11
    Thread-ID: 1318861
    3 Beiträge
    ersetzen durch "nichts"
    Jörn

    hallo allerseits,
    gibt es die möglichkeit beim suchen und ersetzen, zellen mit bestimmtem inhalt durch leerzellen zu ersetzen?

    05.07.2002 12:52:59
    Thread-ID: 134180
    2 Beiträge
    Suchen und ersetzen mit Platzhaltern
    Christian
    Hallo,
    bin gerade dabei eine etwas größere Excel Datei zu erstellen. Dazu müsste ich Viele Zellen kopieren. Da Excel mir dabei immer die Felder in den Formeln anpasst, wollte ich diese mit dem $ versehen.
    Habe daher versucht mit Suchen und ersetzen so etwas hinzubekommen: Suche nach $?4 un...
    28.08.2015 13:44:56
    Thread-ID: 1444876
    3 Beiträge
    Anzeige
    Ersetzen-Makro funktioniert nicht
    Christian

    Hallo!
    Ich habe folgendes Problem:
    In einem Tabellenblatt habe ich eine Vielzalh von Sverweis-Formeln mit folgendem Aufbau:
    =WENN($A28"";SVERWEIS(D$22;Daten!$D$30:$HI$1004;17;FALSCH);"").
    Es wird also jeweils ein Wert aus Spalte 17 (oder auch je nach Formel aus Spalte 12, 20 ode...
    30.08.2017 11:51:32
    Thread-ID: 1577487
    3 Beiträge
    Anzeige
    Suchen und Ersetzen durch VBA
    Schnider

    Guten Tag
    Wollte aus diesem Forum, etwas längere Zeit her, einen Code ausprobieren, welcher das Problem von mir in genau trifft, nun finde ich den Beitrag nicht mehr, respektive kann keine Antwort mehr darauf schreiben.
    Private Sub CommandButton3_Click() ' Daten ändern Dim lZeile As L...
    24.05.2018 16:15:48
    Thread-ID: 1625627
    17 Beiträge
    Suchen/Ersetzen-Makro funktioniert nicht...
    Russi
    Hallo Leute!

    Ich verstehe etwas nicht und hoffe, dass Ihr mir mal wieder auf die Sprünge helft. Per Makrorecorder habe ich ein Suchen/Ersetzen-Makro aufgezeichnet:

    Columns("K:M").Select
    Selection.Replace What:="20.10.2003", Replacement:="", LookAt:=xlPart, _
    Sea...
    24.10.2003 14:39:22
    Thread-ID: 328278
    4 Beiträge
    Ordner suchen und neuste Datei nicht löschen
    Michael

    Hallo!
    Da ich in Access nicht so fit bin, habe ich mit XL eine DB erstellt.
    Es kommen jede Woche neue Dateien dazu, die ich manuell in die DB übertrage.
    Es sind .xls dateien, allerdings löschen meine Kollegen nicht die alten dateien, so daß ich immer erst schauen muß welche Datei ne...
    01.01.1970 00:00:00
    Thread-ID: 400688
    4 Beiträge
    Anzeige
    Suchen und Sortieren von nicht konstanten Werten
    Stefan
    Hallo allerseits,
    ich bin neu hier und, um´s vorneweg zu sagen, nur sehr unerfahren in Bezug auf Excel. Hier mein Problem:
    Im Bereich B1 bis L4 werden zufällige Werte mit drei Nachkommastellen ungeordnet ausgegeben (normalerweise zwischen 0.100 und 10.000). Diese Werte sind genau genommen Rohd...
    22.03.2004 21:04:33
    Thread-ID: 402480
    2 Beiträge
    Zeichenfolge ersetzen durch andere Zeichenfolge?
    Logan

    Hallo,
    Kann ich in einer Arbeitsmappe mit drei Tabellen, eine Zeichenfolge (in Zellen vornedran und hintendran steht noch etwas in der selben Zelle) durch eine andere ersetzen lassen, z.B. -XX- durch -*- ersetzen? Wenn ja wie?
    MfG
    Logan
    01.01.1970 00:00:00
    Thread-ID: 421026
    3 Beiträge
    Suchen und ersetzen funktioniert nicht!!!
    Martin

    Hallo Leute,
    ich wollte per Makro alle Zellen durchsuchen lassen und in den Formeln die Formel Teilergebnis durch Summe ersetzen.
    Ich habe den Vorgang mit dem Recorder aufgezeichnet und mir wurde folgender Code ausgegeben:
    Cells.Replace What:="=TEILERGEBNIS(9;", Replacement:="=SUMME(...
    10.08.2004 11:37:37
    Thread-ID: 467202
    3 Beiträge
    Entdecke relevante Threads

    Schau dir verwandte Threads basierend auf dem aktuellen Thema an

    Alle relevanten Threads mit Inhaltsvorschau entdecken
    Anzeige
    Anzeige

    Infobox / Tutorial

    Ersetzen von Zeichen in Excel: Tipps und Tricks

    Schritt-für-Schritt-Anleitung

    Um in Excel Zeichen durch nichts zu ersetzen, kannst du die Funktion WECHSELN() oder ERSETZEN() verwenden. Hier ist eine Schritt-für-Schritt-Anleitung:

    1. Öffne Excel und wähle die Zelle oder den Bereich aus, in dem du Änderungen vornehmen möchtest.
    2. Gib die Formel ein:
      • Wenn du beispielsweise "min" durch nichts ersetzen möchtest, nutze: 
        =WECHSELN(B1; "min"; "")
      • Um dies für die gesamte Spalte B anzuwenden, ziehe das Ausfüllkästchen nach unten.
    3. Überprüfe das Ergebnis: Stelle sicher, dass die unerwünschten Zeichen entfernt wurden.

    Wenn du die Funktion ERSETZEN() benutzt und feststellst, dass sie nicht wie gewünscht funktioniert, beachte, dass sie die Zeichen an einer bestimmten Position ersetzt. Beispielsweise wird ERSETZEN(B1; LÄNGE(B1)-2; 3; "") nur die letzten drei Zeichen ersetzen.

    Häufige Fehler und Lösungen

    1. Funktioniert nicht wie erwartet: Wenn ERSETZEN() nicht die gewünschten Zeichen entfernt, könnte das daran liegen, dass du die Parameter falsch gesetzt hast. Stelle sicher, dass die Zeichenposition korrekt angegeben ist.

    2. Suchen und Ersetzen funktioniert nicht: Wenn der Befehl Suchen und Ersetzen in Excel nicht funktioniert, prüfe, ob du die richtige Auswahl getroffen hast. Oft hilft es, nur den markierten Bereich zu nutzen.

    3. Leere Zellen werden angezeigt: Wenn du leere Zellen hast und diese als "0:00" angezeigt werden, kannst du die Funktion ISTZAHL() verwenden, um dies zu vermeiden.

    Alternative Methoden

    Falls die Standardmethoden nicht ausreichen, kannst du auch folgende Alternativen ausprobieren:

    • Array-Formeln: Diese können verwendet werden, um komplexere Ersetzungen vorzunehmen.

      =WAHL(ANZAHL2(A2:B2); WECHSELN(A2:B2; "min"; "")/1440; B2 + (A2 > B2) - A2)

    • Textverarbeitung mit Makros: Wenn du regelmäßig viele Ersetzungen vornehmen musst, könnte ein einfaches VBA-Makro helfen.

    Praktische Beispiele

    Hier sind einige praktische Beispiele, die zeigen, wie man Zeichen in Excel ersetzen kann:

    1. Minutenangaben:

      • Wenn in Spalte B Zeitangaben stehen, die "min" enthalten: 
        =WECHSELN(B1; "min"; "")/1440

    2. Formatierung:

      • Um sicherzustellen, dass die Zellen im richtigen Zeitformat angezeigt werden, kannst du das Format auf [hh]:mm setzen.

    3. Umgang mit Doppelpunkten:

      • Um auch "min:" zu ersetzen, kannst du eine verschachtelte Formel verwenden: 
        =WECHSELN(WECHSELN(B1; "min"; ""); ":"; "")

    Tipps für Profis

    • Verwende Platzhalter: Bei der Suchen und Ersetzen-Funktion kannst du Wildcards wie ? oder * verwenden, um flexibler zu sein.
    • Markiere den Bereich: Wenn du nur in einem bestimmten Bereich ersetzen möchtest, kannst du dies in den Optionen für Suchen und Ersetzen einstellen.
    • Ersetze durch nichts: Wenn du etwas so ersetzen möchtest, als hätte es keinen Wert, verwende "" in der Ersetzungsformel.

    FAQ: Häufige Fragen

    1. Wie kann ich mehrere Zeichen gleichzeitig ersetzen? Du kannst verschachtelte WECHSELN()-Funktionen verwenden, um mehrere Änderungen in einer Formel vorzunehmen.

    2. Warum funktioniert die Suchen und Ersetzen-Funktion manchmal nicht? Mögliche Ursachen sind falsche Auswahl, geschützte Blätter oder nicht sichtbare Zeichen wie Leerzeichen.

    3. Was ist der Unterschied zwischen WECHSELN() und ERSETZEN()? WECHSELN() ersetzt alle Vorkommen eines Textes, während ERSETZEN() Zeichen an einer spezifischen Position austauscht.

    Beliebteste Forumthreads (12 Monate)

    Jetzt das Excel-Portal bewerten: Deine Stimme zählt!
    Anzeige
    Anzeige
    Entdecke mehr
    Finde genau, was du suchst

    Die erweiterte Suchfunktion hilft dir, gezielt die besten Antworten zu finden

    Suche nach den besten Antworten
    Unsere beliebtesten Threads

    Entdecke unsere meistgeklickten Beiträge in der Google Suche

    Top 100 Threads jetzt ansehen
    Anzeige