Microsoft Excel

Herbers Excel/VBA-Archiv

Summenprodukt und Teilergebnis?

Betrifft: Summenprodukt und Teilergebnis? von: Daniel
Geschrieben am: 20.11.2012 14:04:03

Hallo zusammen,

ich scheitere gerade an folgender Aufgabenstellung:

Ich habe eine Tabelle mit zwei Spalten, in denen jeweils Prozentwerte stehen (alternativ sind die Zellen leer oder enthalten einen Strich). Ich möchte nun einfach wissen, wie viele Datensätze es gibt, bei denen in beiden Spalten ein Wert steht. Die besondere Herausforderung: ich möchte ein Teilergebnis haben, da ich die Tabelle filtern möchte um so eine dynamische Auswertung zu haben. Und ich möchte keine Hilfsspalten verwenden. ;-)

Noch ohne die Integration von Teilergebnis habe ich aktuell folgende Ideen:

Entweder:
ZÄHLENWENNS(Tabelle1[2M_ZE_inh];">=0";Tabelle1[2M_ZE_wirt];">=0")

Oder:
SUMMENPRODUKT((Tabelle1[2M_ZE_inh]<>"-")*(Tabelle1[2M_ZE_wirt]<>"-")*(Tabelle1[2M_ZE_inh]<>"")*(Tabelle1[2M_ZE_wirt]<>""))

Nun brauche ich eure Hilfe: wie integriere ich das Teilergebnis?

VG Daniel

  

Betrifft: AW: Summenprodukt und Teilergebnis? von: silex1
Geschrieben am: 20.11.2012 21:07:09

Hallo,

versuche mal dies:
http://www.excelformeln.de/formeln.html?welcher=259

VG René


  

Betrifft: AW: Summenprodukt und Teilergebnis? von: Daniel
Geschrieben am: 21.11.2012 16:10:51

Hallo René,

danke für den Link. Leider fehlt mir hier aber die Aussage, wie ich eine zweite Bedingung in die Teilergebnisfunktion einbaue. Mir geht es ja darum zu prüfen, ob in Spalte A ein Wert steht UND ob in Spalte B ein Wert steht. Wenn ja, soll gezählt werden. Mit meiner oben genannten Zählewenns-Funktion könnte ich ggf. schon auf dem richtigen Wert sein. Da weiß ich nur nicht, wie ich die Teilergebnisfunktion integriere.

Noch Ideen?

VG Daniel


  

Betrifft: AW: Summenprodukt und Teilergebnis? von: silex1
Geschrieben am: 21.11.2012 20:33:40

Hallo Daniel,

ich weiss nicht, ob die Teilergebnisformel mit ganzen Listenbereichen klar kommt. Da fehlt mit die Erfahrung. Allerdings kannst Du die Bereiche ja ermitteln.

Poste doch mal ne anonymisierte kleine Bps.-Datei! Dann schaun wir mal!;-)

vg René


  

Betrifft: AW: Summenprodukt und Teilergebnis? von: Daniel
Geschrieben am: 22.11.2012 12:14:24

Hallo René,

danke für dein Hilfsangebot! :) Anbei eine kleine Datei, die das Prinzip verdeutlicht.

https://www.herber.de/bbs/user/82724.xlsx

In Zelle F1 soll eine dynamische Formel, die auch bei gesetzten Filtern die richtigen Ergebnisse liefert. Die Originaldatei soll von den Filtern her über alle Spalten variabel bleiben - die Beipielkriterien A, B, C und D sollten daher nicht in der Formel auftauchen.

Danke und viele Grüße

Daniel


  

Betrifft: AW: Summenprodukt und Teilergebnis? von: silex1
Geschrieben am: 22.11.2012 13:31:48

Hallo,

vielleicht ein bischen umständlich, aber scheint zu funktionieren:

=SUMMENPRODUKT(((Tabelle1[Wert 1]>0)*(Tabelle1[Wert 1]<>"-"))*((Tabelle1[Wert 2]>0) *(Tabelle1[Wert 2]<>"-"))*(TEILERGEBNIS(3;INDIREKT("A"&ZEILE(Tabelle1[Wert 1])))))

VG René


  

Betrifft: AW: Summenprodukt und Teilergebnis? von: Daniel
Geschrieben am: 22.11.2012 14:05:53

WOW! Die Lösung ist genial - klasse Arbeit!

Nur ein Problem noch: wenn in der Tabelle Nullwerte enthalten sind (0 %) werden die Datensätze nicht gezählt, auch wenn in beiden Spalten Daten vorhanden sind. Ich habe versucht, den Term ">0" einfach durch ">=0" zu ersetzen, dann kommt allerdinge eine falsche Anzhal heraus. Hast du hier eventuell noch eine Idee?


  

Betrifft: AW: Summenprodukt und Teilergebnis? von: Daniel
Geschrieben am: 22.11.2012 14:54:15

Ich glaub ich habs - ich kann mit >=0 arbeiten, wenn ich gleichzeitig noch auf leere Zellen prüfe. Das sollte die Lösung sein:

=SUMMENPRODUKT(((Tabelle1[Wert 1]>=0)*(Tabelle1[Wert 1]<>"-")*(Tabelle1[Wert 1]<>"")) *((Tabelle1[Wert 2]>=0)*(Tabelle1[Wert 2]<>"-")*(Tabelle1[Wert 2]<>"")) *(TEILERGEBNIS(3;INDIREKT("A"&ZEILE(Tabelle1[Wert 1])))))

Vielen Dank nochmal. Das ist genau das, was ich benötigt habe! :-)

Viele Grüße

Daniel


  

Betrifft: AW: Summenprodukt und Teilergebnis? von: silex1
Geschrieben am: 22.11.2012 15:05:45

Hallo,

würde dies dann ggf. so machen. Allerdings ungetestet, XL03 kann mit den Listennamen nix anfangen!

=SUMMENPRODUKT(((Tabelle1[Wert 1]>=0)*(Tabelle1[Wert 1]<>"-")*(Tabelle1[Wert 1]<>"")) *((Tabelle1[Wert 2]>=0)*(Tabelle1[Wert 2]<>"-")*((Tabelle1[Wert 2]<>"")) *(TEILERGEBNIS(3;INDIREKT("A"&ZEILE(Tabelle1[Wert 1])))))

VG René


  

Betrifft: AW: Summenprodukt und Teilergebnis? von: Daniel
Geschrieben am: 22.11.2012 15:15:12

Da haben sich unsere Posts hier mit den Lösungen zeitlich wohl überschnitten. ;-)

Danke nochmal!


 

Beiträge aus den Excel-Beispielen zum Thema "Summenprodukt und Teilergebnis?"