Code mit With-Anweisung

Bild

Betrifft: Code mit With-Anweisung
von: Peter Weber
Geschrieben am: 22.09.2015 22:10:06

Hallo Zusammen,
ich habe eine Bitte an Euch.
Wie müsste der Rangebefehl für die Range Zeile heißen?
Ich erhalte andauernd die Fehlermeldung 1004. Die Methode 'Range' für das Objekt '_Worksheet' ist fehlgeschlagen.
with wksTest
.Range(Cells(lngZ, 3), Cells(lngZ, LetzteSP)).Select
'------------------------------------------------------
'Grau einfärben
'------------------------------------------------------
With Selection.Interior
.Pattern = xlSolid
.PatternColorIndex = xlAutomatic
.ThemeColor = xlThemeColorDark1
.TintAndShade = -4.99893185216834E-02
.PatternTintAndShade = 0
End With
end with
Ich danke jetzt schon für Eure Unterstützung,
LG, Peter

Bild

Betrifft: AW: Code mit With-Anweisung
von: Sepp
Geschrieben am: 22.09.2015 22:22:14
Hallo Peter,
ohne .Select und mit den . bei Cells.


With wksTest
  With .Range(.Cells(lngZ, 3), .Cells(lngZ, LetzteSP)).Interior
    .Pattern = xlSolid
    .PatternColorIndex = xlAutomatic
    .ThemeColor = xlThemeColorDark1
    .TintAndShade = -4.99893185216834E-02
    .PatternTintAndShade = 0
  End With
End With

Gruß Sepp

Bild

Betrifft: AW: Code mit With-Anweisung
von: Peter Weber
Geschrieben am: 22.09.2015 22:31:10
Hallo Sepp,
danke für deine helfende Antwort. Muss ich das jetzt für jede With-Anweisung durchführen?
Mein Code-Teil sieht so aus:
'****************************************************************************
'Ramen erstellen
'****************************************************************************
.Range(.Cells(lngZ, 3), .Cells(lngZ, LetzteSP)).Select

Selection.Borders(xlDiagonalDown).LineStyle = xlNone
Selection.Borders(xlDiagonalUp).LineStyle = xlNone

With Selection.Borders(xlEdgeLeft)
.LineStyle = xlContinuous
.Weight = xlThin
.ColorIndex = xlAutomatic
End With

With Selection.Borders(xlEdgeTop)
.LineStyle = xlContinuous
.Weight = xlThin
.ColorIndex = xlAutomatic
End With

With Selection.Borders(xlEdgeBottom)
.LineStyle = xlContinuous
.Weight = xlThin
.ColorIndex = xlAutomatic
End With

With Selection.Borders(xlEdgeRight)
.LineStyle = xlContinuous
.Weight = xlThin
.ColorIndex = xlAutomatic
End With

With Selection.Borders(xlInsideVertical)
.LineStyle = xlContinuous
.Weight = xlThin
.ColorIndex = xlAutomatic
End With

'------------------------------------------------------
'Grau einfärben
'------------------------------------------------------
With .Range(.Cells(lngZ, 3), .Cells(lngZ, LetzteSP)).Interior
With Selection.Interior
.Pattern = xlSolid
.PatternColorIndex = xlAutomatic
.ThemeColor = xlThemeColorDark1
.TintAndShade = -4.99893185216834E-02
.PatternTintAndShade = 0
End With
'------------------------------------------------------
'Schrift Zentrieren und Umbruch einfügen
'------------------------------------------------------
With Selection
.HorizontalAlignment = xlGeneral
.VerticalAlignment = xlCenter
.WrapText = True
.Orientation = 0
.AddIndent = False
.IndentLevel = 0
.ShrinkToFit = False
.ReadingOrder = xlContext
.MergeCells = False
End With

Range("A8").Select
End With
LG, Peter


Bild

Betrifft: AW: Code mit With-Anweisung
von: Sepp
Geschrieben am: 23.09.2015 00:01:19
Hallo Peter,
mit Teil-Codes ist das so eine Sache.
Stell doch den kompletten Code ein, dann ist es viel einfacher, um diese Uhrzeit hab ich keine Lust auf Ratespiele.

Gruß Sepp


Bild

Betrifft: AW: Code mit With-Anweisung
von: Sepp
Geschrieben am: 23.09.2015 00:24:05
Hallo Peter,
mal so aufs Geratewohl.

With wksTest
  
  '****************************************************************************
  'Ramen erstellen
  '****************************************************************************
  
  With .Range(.Cells(lngZ, 3), .Cells(lngZ, LetzteSP))
    
    .Borders(xlDiagonalDown).LineStyle = xlNone
    .Borders(xlDiagonalUp).LineStyle = xlNone
    
    With .Borders(xlEdgeLeft)
      .LineStyle = xlContinuous
      .Weight = xlThin
      .ColorIndex = xlAutomatic
    End With
    
    With .Borders(xlEdgeTop)
      .LineStyle = xlContinuous
      .Weight = xlThin
      .ColorIndex = xlAutomatic
    End With
    
    With .Borders(xlEdgeBottom)
      .LineStyle = xlContinuous
      .Weight = xlThin
      .ColorIndex = xlAutomatic
    End With
    
    With .Borders(xlEdgeRight)
      .LineStyle = xlContinuous
      .Weight = xlThin
      .ColorIndex = xlAutomatic
    End With
    
    With .Borders(xlInsideVertical)
      .LineStyle = xlContinuous
      .Weight = xlThin
      .ColorIndex = xlAutomatic
    End With
    
    '------------------------------------------------------
    'Grau einfärben
    '------------------------------------------------------
    
    With .Interior
      .Pattern = xlSolid
      .PatternColorIndex = xlAutomatic
      .ThemeColor = xlThemeColorDark1
      .TintAndShade = -4.99893185216834E-02
      .PatternTintAndShade = 0
    End With
    
    '------------------------------------------------------
    'Schrift Zentrieren und Umbruch einfügen
    '------------------------------------------------------
    
    .HorizontalAlignment = xlGeneral
    .VerticalAlignment = xlCenter
    .WrapText = True
    .Orientation = 0
    .AddIndent = False
    .IndentLevel = 0
    .ShrinkToFit = False
    .ReadingOrder = xlContext
    .MergeCells = False
    
  End With
  
End With

Gruß Sepp


Bild

Betrifft: AW: Code mit With-Anweisung
von: Rudi Maintaire
Geschrieben am: 23.09.2015 09:58:20
Hallo,
...wenn wie hier die Rahmenlinien alle gleich sind.

  With wksTest
    
    '****************************************************************************
    'Ramen erstellen
    '****************************************************************************
    
    With .Range(.Cells(lngZ, 3), .Cells(lngZ, letzteSp))
      
      With .Borders
        .LineStyle = xlContinuous
        .Weight = xlThin
        .ColorIndex = xlAutomatic
      End With
    End With
  End With
Gruß
Rudi

Bild

Betrifft: AW: Code mit With-Anweisung
von: Peter Weber
Geschrieben am: 22.09.2015 23:12:53
Hallo Sepp,
hast du noch einen Tipp?
LG, Peter

Bild

Betrifft: AW: Code mit With-Anweisung
von: Peter Weber
Geschrieben am: 23.09.2015 12:02:03
Hallo Zusammen,
vielen Dank für Eure Antworten. So funktioniert das Makro sehr gut und es wurde durch Eure Hilfe viel kürzer und übersichtlicher.
Dadurch habe ich wieder viel gelernt und werde einige meiner Codes anpassen.
LG,
Peter

 Bild

Beiträge aus den Excel-Beispielen zum Thema "Datum kleiner gleich - gleicher Tag fällt raus"