Vorgänger/Nachfolger aus Zahlenliste bestimmen

Bild

Betrifft: Vorgänger/Nachfolger aus Zahlenliste bestimmen
von: Joerschi
Geschrieben am: 24.10.2015 11:57:04

Hallo liebes Forum,
folgende Aufgabe soll gelöst werden.
Aus einer Zahlenliste soll der Vorgänger (VG) und Nachfolger (NF) jener Zahl bestimmt werden, die man manuell vorgibt (und die es in der Liste natürlich dann auch geben muss).
Am Beispiel:
Userbild
https://www.herber.de/bbs/user/101010.xlsx
Gesucht sind die Formellösungen in G2:H3 - die richtigen Lösungen je Zeile jeweils in Klammern.
In B4 ist manuell die Zahl vorgegeben, welche als Ausgangspunkt der Bestimmung des VG/NF verwendet werden soll.
Besonderheit in der zweiten Zahlenliste von A3:E3 ist, dass es zweimal die Vorgabezahl gibt. In dem Falle wäre die Lösung mit der Vorgabezahl identisch.
Mein erste Vermutung wäre eine Lösung mit VERGLEICH, aber dann weiter...?
Viele Grüße und besten Dank vorab
Joerschi

Bild

Betrifft: Korrektur des Screenshot
von: Joerschi
Geschrieben am: 24.10.2015 11:59:44
da in G3 und H3 in Klammern das falsche Ergebnis (im Text oben ist schon alles richtig benannt)
Userbild

Bild

Betrifft: AW: Vorgänger/Nachfolger aus Zahlenliste bestimmen
von: Hajo_Zi
Geschrieben am: 24.10.2015 12:02:17
Hallo Joerschi,

Tabelle1

 GHIJ
1VG?NF?VGNF
2? (2,5)? (4,0)2,504,00
3? (2,0)? (4,0)2,004,00

verwendete Formeln
Zelle Formel Bereich N/A
I2:I3{=MAX(WENN(A2:E2<$B$4;A2:E2))}$I$2 
J2:J3{=MIN(WENN(B2:F2>$B$4;B2:F2))}$J$2 
{} Matrixformel mit Strg+Umschalt+Enter abschließen
Matrixformeln sind durch geschweifte Klammern {} eingeschlossen
Diese Klammern nicht eingeben!!

Excel-Inn.de
Hajo-Excel.de
XHTML-Tabelle zur Darstellung in Foren, einschl. der neuen Funktionen ab Version 2007
Add-In-Version 19.08 einschl. 64 Bit




Bild

Betrifft: AW: Vorgänger/Nachfolger aus Zahlenliste bestimmen
von: ransi
Geschrieben am: 24.10.2015 13:32:29
Hallo Joerschi,
Alternativ noch was ohne {}:
Tabelle1

 ABCDEFGH
1      VG?NF?
22,002,503,004,005,00 2,504
32,003,003,004,005,00 2,004
4Vorgabe:3,00      

Formeln der Tabelle
ZelleFormel
G2=KKLEINSTE(A2:E2;ZÄHLENWENN(A2:E2;"<" &$B$4))
H2=KGRÖSSTE(A2:E2;ZÄHLENWENN(A2:E2;">" &$B$4))


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
ransi

Bild

Betrifft: AW: Vorgänger/Nachfolger aus Zahlenliste bestimmen
von: Daniel
Geschrieben am: 24.10.2015 14:06:08
Hi
Vorgänger: =Index(A2:F2;1;Vergleich(B4;A2:F2;0)-1)
Nachfolger: =Index(A2:F2;1;Vergleich(B4;A2:F2;0)+1)
um das Problem mit den doppelten Zahlen oder falscheingaben abzufangen so:
=Wahl(Max(ZählenWenn(A2:E2;B4)+1;3);"Zahl nicht vorhanden";Index(...);B4)
für Index(...) setzt du jeweils die Vorgänger- oder Nachfolgerformel ein.
Damit die Formel auch bei Eingabe von Randwerten (2; 5) richtig funktioniert, solltest du in der Index-Funktion die linke und rechte Nachbarzelle in den Zellbereich mit aufnehmen und in diese Zellen die Formel ="" schreiben.
für die rechte Nachbarzelle habe ich das mit F2 bereits berücksichtigt, für die linke solltest du das ebenfalls tun, hierzu musst du aber vor den Daten noch eine Leerspalte A einfügen.
diese Zellen sollten auch einen Text enthalten, denn echte Leerzellen werden als 0 angezeigt, wenn sie von anderen Formeln ausgelesen werden (und das könnte ja insbesondere bei der Vorgängerzelle zu falschen Interpretationen führen)
Gruss Daniel

Bild

Betrifft: Herzlichen Dank an alle Lösungsfinder
von: Joerschi
Geschrieben am: 24.10.2015 15:32:23
Sehr interessante Ansätze dabei.
Auch vielen Dank @ Daniel für die ausführlichen zusätzlichen Tipps in Sachen Fehlerbehandlung.
ich bin zwar grad unterwegs und noch nicht getestet, aber:
Für die Behandlung bezüglich des doppelten Vorgabewertes werde ich wohl sowas probieren:
Wenn Anzahl B4 größer als 1; dann B4; sonst eine Formellösung von Euch.
Nochmals Danke und beste Grüße ins WE
Joerschi

Bild

Betrifft: AW: hier muss jedoch beachtet werden ...
von: ... neopa C
Geschrieben am: 25.10.2015 13:15:35
Hallo Joerschi,
... Deine Aufgabenstellung war diesmal nicht ganz eindeutig, wie man auch aus den unterschiedlichen Lösungsansätzen entnehmen kann.
Daniel hat sich bezüglich Deiner nicht vorgegebenen Begriffsdefinition "Vorgänger" und "Nachfolger" an der Lage der Datenwerte im Zellbereich orientiert, während Hallo und ransi sich ausschließlich von der Größe der Zahlenwerte leiten lassen haben.
Zwar führen die bisherigen verschiedenen Lösungsansätze für Deine Beispieldaten (wenn der Suchwert kein Randdatenwerte ist) alle zum gleichen Ergebnis, aber sobald die Daten nicht mehr wie in Deinem Beispiel aufwärts sortiert gelistet sind, können sich verschiedene Ergebnisse ergeben. Das wäre dann Deinerseits sicherlich ungewollt und lässt auch vermeiden.
Nachfolgend zeige ich das am Beispiel mit einer zusätzlichen Datenzeile 5 auf.
Gleichzeitig zeige ich eine weitere Alternative für die Ermittlung des kleineren bzw. größeren Zahlenwertes auf und wie mit Hilfe von WENNFEHLER() und entsprechenden Formelkonstrukten man auch zusätzliche Hilfszellen vermeiden könnte (anstelle: ;"" kannst Du natürlich auch jeden beliebigen Text einsetzen):.Die Formeln einfach nach oben kopieren

 ABCDEFGHIJK
1      KLGR VGNF
22,002,503,004,005,00 2,504,00 2,504,00
33,003,003,004,005,00  4,00  4,00
4Vorgabe:3,00       Vorgabe: 
53,002,503,003,053,00 2,503,05   
6      Zahlenwerte beliebige Daten

Formeln der Tabelle
ZelleFormel
G5=WENNFEHLER(AGGREGAT(14;6;A5:E5/(A5:D5<B$4); 1); "")
H5=WENNFEHLER(AGGREGAT(15;6;A5:E5/(A5:E5>B$4); 1); "")
J5=WENNFEHLER(INDEX(A5:E5;VERGLEICH(B$4;A5:E5;)-1); "")
K5=WENNFEHLER(--(INDEX(5:5;VERWEIS(9;1/(A5:E5=B$4); SPALTE(5:5))+1)&""); "")


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Werner
.. , - ...

Bild

Betrifft: AW: hier muss jedoch beachtet werden ...
von: Joerschi
Geschrieben am: 25.10.2015 21:08:21
Hallo Werner,
auch Dir Danke für die tollen Lösungsvorschläge.
Schon interessant: Die Aufgabenstellung ist denkbar einfach, die Lösung aber - je nach angenommener Datensituation - durchaus sehr unterschiedlich. :-)
Viele Grüße
Joerschi

 Bild

Beiträge aus den Excel-Beispielen zum Thema "Vorgänger/Nachfolger aus Zahlenliste bestimmen"