Suche Hilfe: Iterative Suchfunktion Spalte + Summe + Ausgabe

Hallo Zusammen,

bin leider zu eingerostet zum Programmieren und mit VBA kann ich nur Kleinkram, aber nichts komplexeres erschaffen.

Ich habe eine Excel mit diversen Spalten ca. 150.000 Zeilen und muss diese auswerten.
Ich versuch mein Problem mal zu umreißen und ggf. in Psydeu-Code erklären was ich vor habe.
Hintergrund
Ich hab in Spalte A: Zahlen (von 1 bis 2000) und in Spalte B einen Betrag mit bis zu 4 Stellen hinter dem Komma.
Die Zahlen von 1 bis 2000 kommen in den 150.000 Zeilen mehrfach vor, oder garnicht.
Nun brauche ich eine Gesamtsumme wie oft die Zahl vorkommt und die Addition der Werte aus Spalte B. (Aus Anzahl und gesamt Wert bilde ich später noch einen Durchschnitt)

Wenn zum Bsp.
in Spalte A die Zahl 199 - 7 mal enthalten ist dann sollen die entsprechenden Werte aus Spalte B addiert werden
Nun möchte ich die Zahl 199 in Spalte A eines 2. Sheets kopieren, dann Anzahl wie oft enthalten in Spalte B und die Addierte Summe in Spalte C
Und das von den Zahlen 1 bis 2000

Hier mein Versuch als "Pysdo-Code"
DIM Zahl As Integer (langt da nur ganze Zahlen)
DIM Summe As Long
DIM Anzahl As Integer (langt da die Zahlen nicht mehr als 32.767 mal vorkommen werden)
Zahl = 1

Suche in Spalte A nach Zahl
Wenn Zahl gefunden wird
summiere den entsprechende Wert aus Spalte B und merke dir die Anzahl der Summierungen
Suche Weiter in Spalte A bis Zahl nicht mehr gefunden wird
Anschliessend Schreibe in 2.Sheet Zahl in Spalte A, Anzahl in in Spalte B und Summe in Zeile C
Wenn Zahl nicht gefunden wird
Zahl = Zahl +1 und suche erneut in Spalte A

Hoffe das ist so verständlich! xD
Verzweifle da so langsam dran, weil es meine Kompetenz in VBA und Excel überschreitet...

Wenn hier jemand weiterhelfen kann, auch nur in Teilbereichen gibt neben einem Dankeschön auch eine virtuelle Umarmung von mir.

Gruß

Nasrag

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo Nasrag,

eigentlich hätte man schon nach dem 3ten Zeile aufhören zu lesen: Auswertung heisst Pivottable:
idealerweise hat deine Liste Überschriften. Wenn füge eine: "Artikel" in A1, "Wert" in B1
auf die erste Zelle deine Liste gehen,
Menü "Einfügen", "Pivottable",
der Bereich wird erkannt, ob auf diese Arbeitsmappe oder auf eine neue, spielt keine Rolle.
Verschiebt den Feld "Artikel" vom Feldliste in der weissen Quadrat "Zeile",
verschiebt den Feld "Wert" zweimal vom Feldliste in der weissen Quadrat "Wert"
der Zweite bekommt den Name "Summe von Wert2", klick auf dem Dropdown-Eck davon und wähle "Wertfeldeinstellungen...",
Andere die "zusammenfasungs"-funktion in "Anzahl", ok.

Fertig. Ändern sich Werte in der Quelle: Rechtsklick auf die Pivottable und "aktualisieren".

Da es in der Frage um VBA ging (und weil es mir langweilig ist), hier die VBA-Lösung (ungetestet, weil keine Material dafür):

Sub Sammeln_Summieren()

Dim E ' E wie Element

Dim Sum As Object

Dim Anz As Object



    Set Sum = CreateObject("Scripting.Dictionary")

    Set Anz = CreateObject("Scripting.Dictionary")

'Sammeln, zählen, summieren

    With Worksheets("Tabelle1")

        For Each E In Range(.Range("A1"), .Cells(Rows.Count, 1).End(xlUp))

            Sum(E.Value) = Sum(E.Value) + E.Offset(, 1).Value

            Anz(E.Value) = Anz(E.Value) + 1

        Next

    End With

'Ausgeben (inn einem neuen Blatt)

    With Worksheets.Add(After:=Worksheets(Worksheets.Count))

        .Range("A1") = "Schlüssel": .Range("B1") = "Anzahl": .Range("C1") = "Summe"

        For Each E In Anz.Keys

            With .Cells(Rows.Count, 1).End(xlUp)

                .Offset(1, 0).Value = E

                .Offset(1, 1).Value = Anz(E)

                .Offset(1, 2).Value = Sum(E)

            End With

        Next

    End With

End Sub

Ändern sich Werte in der Quelle: lösche die Ausgaben blatt und starte das Makro wieder. Nach spätestens 4mal wirst Du selber sagen: wie war's nochmal mit der Pivottable? ;-)

VG
Yal

Beliebteste Forumthreads (12 Monate)

Suche Hilfe: Iterative Suchfunktion Spalte + Summe + Ausgabe

6 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread