Formel kürzen

Bild

Betrifft: Formel kürzen
von: Giuseppe
Geschrieben am: 14.11.2003 14:00:53

Hallo Freunde, noch 'ne Frage:
Wie kann man die Formel kürzen?

=ZÄHLENWENN(D8:AH8;"F")*Arbeitzeit!$F$7+ZÄHLENWENN(D8:AH8;"F1")*Arbeitzeit!$F$8+ZÄHLENWENN(D8:AH8;"F2")*Arbeitzeit!$F$9+ZÄHLENWENN(D8:AH8;"F3")*Arbeitzeit!$F$10+ZÄHLENWENN(D8:AH8;"S")*Arbeitzeit!$F$11+ZÄHLENWENN(D8:AH8;"S1")*Arbeitzeit!$F$12+ZÄHLENWENN(D8:AH8;"S2")*Arbeitzeit!$F$13+ZÄHLENWENN(D8:AH8;"S3")*Arbeitzeit!$F$14+ZÄHLENWENN(D8:AH8;"Z")*Arbeitzeit!$F$15+ZÄHLENWENN(D8:AH8;"N")*Arbeitzeit!$F$16+ZÄHLENWENN(D8:AH8;"k")*Arbeitzeit!$F$17+ZÄHLENWENN(D8:AH8;"u")*Arbeitzeit!$F$18+ZÄHLENWENN(D8:AH8;"Bg")*Arbeitzeit!$F$19+SUMME(D9:AH9)

Danke
Giuseppe

Bild


Betrifft: AW: Formel kürzen
von: Karl-Otto Reimann
Geschrieben am: 14.11.2003 14:14:21

Hallo Giuseppe
Für Freitagnachmittag genau das Richtige.
Vielleicht schilderst Du uns 'mal Dein Problem,
vermutlich kann man was über =HÄUFIGKEIT() machen.
Gruß KO


Bild


Betrifft: AW: Formel kürzen
von: Giuseppe
Geschrieben am: 14.11.2003 14:25:48

Hallo Karl-Otto,
wg. Freitag hast du allerdings recht!!!
Mit kürzen meinte ich statt immerr zu schreiben Zählenwenn.... + Zählenwenn, z.B. Zählenwenn(und ... in diese Form!
Ciao
Giuseppe


Bild


Betrifft: Mehrere ZÄHLENWENN vereinen
von: Boris
Geschrieben am: 14.11.2003 14:21:56

Hi Guiseppe,

=SUMME(ZÄHLENWENN(D8:H8;{"F"."F1"."F2"."F3"."S"."S1"."S2"."S3"."Z"."N"."K"."U"."BG"})*{1.2.3.4.5.6.7.8.9.10.11.12.13};D9:H9)

wobei 1.2.3.4.5.6.7 etc... für Arbeitszeit!F7, Arbeitszeit!F8 etc. steht.
Also zu "F" gehört die 1, zu "F1" die 2 etc. etc..

Das ist der einzige Nachteil:
Statt 1.2.3.4.5.6.7. etc.. kann man leider NICHT auf Zellen referenzieren.

Grüße Boris


Bild


Betrifft: AW: Mehrere ZÄHLENWENN vereinen
von: Giuseppe
Geschrieben am: 14.11.2003 14:28:31

Hallo Boris,
Schade!!!
Kann man vielleicht mit ein Verweis, oder mit Zählenwenn(UND ?
Ciao
Giuseppe


Bild


Betrifft: Mehrere ZÄHLENWENN vereinen - viel einfacher
von: Boris
Geschrieben am: 14.11.2003 14:43:01

Hi Guiseppe,

es geht viel einfacher:

{=SUMME(ZÄHLENWENN(D8:H8;B12:B24)*A12:A24;D9:H9)}

In B12:B24 steht untereinander "F", "F1", "F2" etc..
In A12:A24 stehen die zu multiplizierenden Werte (also z.B. A12: 1, B12: "F")

Den Rest erledigt obige Formel. Es ist eine Array-Formel; die {geschweiften Klammerne nicht eingeben, sondern Formeleingabe mit Strg-Shift-Enter abschließen. Das erzeugt sie.

Grüße Boris


Bild


Betrifft: AW: Mehrere ZÄHLENWENN vereinen - viel einfacher
von: Giuseppe
Geschrieben am: 14.11.2003 14:49:19

Hallo Boris,
sehr interessante Lösung! Ich werde gleich probieren.
Danke
Giuseppe


Bild

Beiträge aus den Excel-Beispielen zum Thema " Formel kürzen"