Wenn-Funktion

Bild

Betrifft: Wenn-Funktion
von: Knut
Geschrieben am: 29.03.2005 15:55:05
Hallo,
habe in der einer Spalt bzw. Zelle mit folgender Formel gearbeitet:
=WENN(G3=0;0;WENN(G3=1;0,5;WENN(G3=2;1;WENN(G3=3;1,5;WENN(G3=4;2;WENN(G3=5;2,5;WENN(G3=6;3;WENN(G3=7;3,5;))))))))+WENN(G3=8;4;)/24/60
Wurde in der ZELLE G3 keine Eingabe gemacht erscheint immer nach meinem benutzerdefinierten Format 00:00:00 Std.!
Wie kann ich die Formel erweitern, damit erst nach einer Eingabe in G3 eine dementsprechende Zeit erscheint?
Gruß Knut

Bild

Betrifft: AW: Wenn-Funktion
von: heikoS
Geschrieben am: 29.03.2005 16:03:42
Hallo Knut,
entweder Du erweiterst Deine Formel um ein weiteres WENN(): =wenn(DeineFormel=0;"";DeineFormel), dabei mußt Du dann aber G3=7;3 in den zweiten Wenn-Teil bringen,
oder
Du löst das über die bedingte Formatierung: Zellwert gleich 0, Schriftfarbe weiß.

Gruß Heiko
Bild

Betrifft: AW: Wenn-Funktion
von: c0bRa
Geschrieben am: 29.03.2005 16:05:02
hallo...
um deine formel mal schöner zu verschachteln:
=wenn(g3="";"";wenn(und(g3>=0;g3<=8;g3=ganzzahl(g3));g3/2/24/60;"falsch"))
alternativ kannst auch mti sverweis eine tabelle erstellen, wo du jeweis die hälfte deiner ursprungszahl reinschreibst...
aber mir excel gut und vba gut, wirste den sverweis sicherlich im schlaf können...

Rückmeldung nicht vergessen...
c0bRa
Bild

Betrifft: AW: Wenn-Funktion
von: Andi
Geschrieben am: 29.03.2005 16:05:05
Hi,
=WENN(G3="";"";[Deine Formel])
Schönen Gruß,
Andi
Bild

Betrifft: AW: Wenn-Funktion
von: Knut
Geschrieben am: 29.03.2005 16:19:36
Dank an Alle,
wieder was dazu gelernt!
P.S. Hab versehentlich auf gute Kenntnisse gedrückt-bin noch Anfänger!!!
Bild

Betrifft: AW: Funktion WAHL verwenden!
von: Luc :-?
Geschrieben am: 29.03.2005 16:24:26
Hallo Knut,
so geht's:
=WAHL(G3+1;WENN(G3="";"";0);0,5;1;1,5;2;2,5;3;3,5;4)
Gruß Luc :-?
Bild

Betrifft: AW: Funktion WAHL verwenden!
von: Knut
Geschrieben am: 29.03.2005 17:39:47
Hallo Luc,
die Formel ist Klasse!
Wie kann bei Deiner, aber auch bei meiner Möglichkeit der Formel, bei keiner Eingabe in Zelle G3 die Anzeige #WERT! weg bekommen?
Gruß Knut
Bild

Betrifft: =WENN(ANZAHL(G3);G3/2/24/60;"")
von: Boris
Geschrieben am: 29.03.2005 17:47:13
Hi Knut,
...sollte doch in deinem Fall reichen.
Grüße Boris
Bild

Betrifft: AW: =WENN(ANZAHL(G3);G3/2/24/60;"")
von: Knut
Geschrieben am: 29.03.2005 18:05:48
Hallo Boris,
hast schon recht, aber ich versuche halt ein bischen weiter zu denken!
Zur Vorlage beim Chef sieht`s halt ein bischen blöd aus , wenn der #WERT da steht!
Gruß Knut
Bild

Betrifft: Hä?
von: Boris
Geschrieben am: 29.03.2005 18:11:34
Hi Knut,
...ich versteh kein Wort.
Meine Aussage bezog sich auf die WAHL-Funktion, die mir hier recht überflüssig schien. Und mit der von mir geposteten Formel gibt es doch kein #WERT! - oder ...?
Grüße Boris
Bild

Betrifft: AW: Hä?
von: Knut
Geschrieben am: 29.03.2005 18:28:54
Sorry Boris,
ich hab´s erst nicht gerafft!
Danke für die Hilfe......
Gruß Knut
Bild

Betrifft: Noch ne´ Frage Boris
von: Knut
Geschrieben am: 29.03.2005 18:53:04
Noch ne´ Frage Boris,
gibt es bezüglich dieser Formel eine Umkehrung?
Wenn: 0= 04:00:00 Std.
1= 03:30:00 Std.
..........
8= 00:00:00 Std.
sein soll?
Mir fehlt da die Grundlage!
Gruß Knut
Bild

Betrifft: Noch ne´ Frage Boris
von: Knut
Geschrieben am: 29.03.2005 18:53:10
Noch ne´ Frage Boris,
gibt es bezüglich dieser Formel eine Umkehrung?
Wenn: 0= 04:00:00 Std.
1= 03:30:00 Std.
..........
8= 00:00:00 Std.
sein soll?
Mir fehlt da die Grundlage!
Gruß Knut
Bild

Betrifft: AW: Funktion WAHL verwenden!
von: Luc :-?
Geschrieben am: 29.03.2005 20:28:05
Hallo Knut,
wenn ein Ergebnis durch einfache Berechnung erreicht wdn kann, ist diese Form natürlich vorzuziehen. Die Funktion WAHL lässt sich bei gleicherart günstigen Voraussetzungen wie hier auch anderweitig gut anstelle von WENN einsetzen. Übrigens ergibt die Formel bei mir auch keinen #WERT!-Fehler (G3 mit Standard-, Formelzelle mit Uhrzeit-Formatierung unter Office2000 und Win98SE).
Gruß Luc :-?
Bild

Betrifft: AW: =G3/2880
von: FP
Geschrieben am: 29.03.2005 19:08:07
Hallo Knut,
genügt eigentlich vollkommen
wenn Du die Zelle, in der diese Formel steht so formatierst: [>0]hh:mm:ss
wird nicht einmal der Wert Null angezeigt, falls G3 leer ist
möchtest Du sogar "ungestraft" Text in G3 schreiben wird's natürlich hoch kompliziert ;-)
=N(G3)/2880
Servus aus dem Salzkammergut
Franz
Bild

Betrifft: =G3/48
von: FP
Geschrieben am: 29.03.2005 19:17:58
Hallo Knut,
da Du offenbar doch Stunden und nicht Minuten ermitteln willst ;-)
Kleiner Tipp:
1 steht in Excel für 1 Tag = 24 Stunden
Will man so wie Du den Dezimalwert 1 in halbe Stunden umwandeln, muss man eben durch 48 teilen statt durch 24.
Alles klar?
Das was Du gerechnet hast ( g3/2/24/60 ) liefert dagegen MINUTEN!!!
Servus aus dem Salzkammergut
Franz
 Bild

Beiträge aus den Excel-Beispielen zum Thema "Wenn-Funktion"