Zahlen Drehen/Spiegeln

Bild

Betrifft: Zahlen Drehen/Spiegeln
von: Thorsten
Geschrieben am: 01.04.2005 15:04:04
Hallo.
Ich suche eine Lösung für das Drehen bzw. Spiegeln von Zahlen und zusammenfügen von Zahlenreihen. Bspl. Spalte 1 enthält den eintrag 1,23 die die Spalte 2 den Eintrag 4,56, dann möchte ich diese zwei Werte in eine neue Spalte übernehmen und mit Nullen in der Mitte auf insgesammt 12 Stellen ergänzen, damit diese wie folgt aussieht, 321000000456. In Access habe ich das schon hinbekommen, da kann man auber auch mit anderen Befehlen arbeiten als in Excel. Oder habe ich da was verpasst!? Das gleiche sollte dann aber auch mit Zahlen wie 12,34 und 56,78 funktionieren und wie folgt aussehen, 432100005678. Vielen Dank im Vorraus für die Hilfe. Gruß

Bild

Betrifft: AW: Zahlen Drehen/Spiegeln
von: u_
Geschrieben am: 01.04.2005 15:18:45
Hallo,
mal als Ansatz:
http://www.excelformeln.de/formeln.html?welcher=244
Gruß
Bild

Betrifft: AW: Zahlen Drehen/Spiegeln
von: Fred
Geschrieben am: 01.04.2005 15:18:58
Hi,
brauchst du das als Formel- oder VBA-Lösung?
Verständnisfrage, wozu braucht man sowas?
Gruß Fred
Bild

Betrifft: AW: Zahlen Drehen/Spiegeln
von: Boris
Geschrieben am: 01.04.2005 16:08:43
Hi,
um den Hinweis von u_ noch zu Ende zu führen:
Deine Zahlen stehen in A1 und A2 (auch Dezimalzahlen):
=SUMMENPRODUKT(TEIL(WECHSELN(A1;",";)*10^(16-LÄNGE(WECHSELN(A1;",";)));ZEILE(1:16);1)*10^(ZEILE(1:16)-1))&WIEDERHOLEN(0;12-LÄNGE(WECHSELN(A1;",";))-LÄNGE(WECHSELN(A2;",";)))&SUMMENPRODUKT(TEIL(WECHSELN(A2;",";)*10^(16-LÄNGE(WECHSELN(A2;",";)));ZEILE(1:16);1)*10^(ZEILE(1:16)-1))
Grüße Boris
Bild

Betrifft: ein bischen kürzer ;-)
von: FP
Geschrieben am: 01.04.2005 20:40:55
Hallo Boris,
Tabelle2
 ABC
112345,6 654321123456
26,54321  
Formeln der Tabelle
C1 : {=SUMME(TEIL(WECHSELN(A1&"00000000";",";"");SPALTE(A1:H1);1)*10^SPALTE(A1:H1))/10&WIEDERHOLEN("0";12-SUMME(LÄNGE(WECHSELN(A1:A2;",";""))))&SUMME(TEIL(WECHSELN(A2&"00000000";",";"");SPALTE(A2:H2);1)*10^SPALTE(A2:H2))/10}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
 
Diagramm - Grafik - Excel Tabellen einfach im Web darstellen    Excel Jeanie HTML  3.0    Download  

und so, müssen nicht einmal Zahlen eingetragen sein :-)
Tabelle2
 ABC
1  000000000000
2   
Formeln der Tabelle
C1 : {=TEXT(SUMME(TEIL(WECHSELN(A1&"00000000";",";"");SPALTE(A1:H1);1)*10^SPALTE(A1:H1))/10;"#")&WIEDERHOLEN("0";12-SUMME(LÄNGE(WECHSELN(A1:A2;",";""))))&TEXT(SUMME(TEIL(WECHSELN(A2&"00000000";",";"");SPALTE(A2:H2);1)*10^SPALTE(A2:H2))/10;"#")}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
 
Diagramm - Grafik - Excel Tabellen einfach im Web darstellen    Excel Jeanie HTML  3.0    Download  

und so dürfen die Zahlen sogar mehr als 6 Stellen haben ;-)
Tabelle2
 ABC
11,234567 765432234567
27,654321  
Formeln der Tabelle
C1 : {=TEXT(SUMME(TEIL(WECHSELN(RECHTS(A1;6+(KÜRZEN(A1)<>A1))&"00000000";",";"");SPALTE(A1:H1);1)*10^SPALTE(A1:H1))/10;"#")&WIEDERHOLEN("0";12-SUMME(LÄNGE(WECHSELN(RECHTS(A1;6+(KÜRZEN(A1)<>A1))&LINKS(A2;6+(KÜRZEN(A2)<>A2));",";""))))&TEXT(SUMME(TEIL(WECHSELN(LINKS(A2;6+(KÜRZEN(A2)<>A2));",";"")&"00000000";SPALTE(A2:H2);1)*10^SPALTE(A2:H2))/10;"#")}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
 
Diagramm - Grafik - Excel Tabellen einfach im Web darstellen    Excel Jeanie HTML  3.0    Download  

Na, bist Du jetzt zufrieden, diese Formel wird doch wirklich allen Aufgaben gerecht...
halt, diesen Fall hätte ich doch glatt wieder übersehen :D
Tabelle2
 ABC
50 000000000000
60  
Formeln der Tabelle
C5 : {=TEXT(SUMME(TEIL(WECHSELN(RECHTS(A5;6+(KÜRZEN(A5)<>A5))&"00000000";",";"");SPALTE(A5:H5);1)*10^SPALTE(A5:H5))/10;"#")&WIEDERHOLEN("0";12-SUMME(LÄNGE(WECHSELN(TEXT(RECHTS(A5;6+(KÜRZEN(A5)<>A5));"#")&TEXT(LINKS(A6;6+(KÜRZEN(A6)<>A6));"#");",";""))))&TEXT(SUMME(TEIL(WECHSELN(LINKS(A6;6+(KÜRZEN(A6)<>A6));",";"")&"00000000";SPALTE(A6:H6);1)*10^SPALTE(A6:H6))/10;"#")}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
 
Diagramm - Grafik - Excel Tabellen einfach im Web darstellen    Excel Jeanie HTML  3.0    Download  

Servus aus dem Salzkammergut
Franz
Bild

Betrifft: man könnte...
von: FP
Geschrieben am: 02.04.2005 00:02:39
Hallo Boris,
die Aufgabe natürlich auch so verstehen und lösen:
Tabelle2
 ABC
1900000 000009234567
27,65432  
3123,4567 654321700000
47  
56,5432 234560432100
612,34  
Formeln der Tabelle
C1 : {=TEXT(SUMME(TEIL(TEXT(WECHSELN(A1;",";"");"000000");ZEILE($1:$6);1)*10^ZEILE($1:$6))/10;"000000")&SUMME(TEIL(LINKS(TEXT(WECHSELN(A2;",";"");"000000");6);ZEILE($1:$6);1)*10^ZEILE($1:$6))/10}
C3 : {=TEXT(SUMME(TEIL(TEXT(WECHSELN(A3;",";"");"000000");ZEILE($1:$6);1)*10^ZEILE($1:$6))/10;"000000")&SUMME(TEIL(LINKS(TEXT(WECHSELN(A4;",";"");"000000");6);ZEILE($1:$6);1)*10^ZEILE($1:$6))/10}
C5 : {=TEXT(SUMME(TEIL(TEXT(WECHSELN(A5;",";"");"000000");ZEILE($1:$6);1)*10^ZEILE($1:$6))/10;"000000")&SUMME(TEIL(LINKS(TEXT(WECHSELN(A6;",";"");"000000");6);ZEILE($1:$6);1)*10^ZEILE($1:$6))/10}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
 
Diagramm - Grafik - Excel Tabellen einfach im Web darstellen    Excel Jeanie HTML  3.0    Download  

Servus aus dem Salzkammergut
Franz
Bild

Betrifft: AW: immer diese Leerzellen...
von: FP
Geschrieben am: 02.04.2005 00:11:39
Hallo Boris,
Forderungen erfüllt:
1) immer 12 Ziffern - auch wenn beide Zellen leer sind
2) Fliesskomma muss möglich sein und in Ganzzahl konvertiert werden
3) die Ziffern müssen gespiegelt werden - 900000 wird zu 000009
Tabelle2
 ABC
5  000000000000
6   
Formeln der Tabelle
C5 : {=TEXT(SUMME(TEIL(TEXT(WECHSELN(A5+0;",";"");"000000");ZEILE($1:$6);1)*10^ZEILE($1:$6))/10;"000000")&TEXT(SUMME(TEIL(LINKS(TEXT(WECHSELN(A6+0;",";"");"000000");6);ZEILE($1:$6);1)*10^ZEILE($1:$6))/10;"000000")}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
 
Diagramm - Grafik - Excel Tabellen einfach im Web darstellen    Excel Jeanie HTML  3.0    Download  

Servus aus dem Salzkammergut
Franz
Bild

Betrifft: AW: Zahlen Drehen/Spiegeln
von: Thorsten
Geschrieben am: 02.04.2005 12:09:22
Hallo.
Nochmal ich, die Lösung von Boris war bis jetzt die Beste! Nur im 2 Teil der Formel benötige ich keine Drehung, ich habe zwar versucht die Formel umzubauen, leider ohne Erfolg.
Also wie gesagt: aus den beiden Zahlen 1,23 und 4,56 müsste die Zahlenkolonne 321000000456 werden.
Gruß Thorten
Bild

Betrifft: AW: Zahlen Drehen/Spiegeln
von: Boris
Geschrieben am: 02.04.2005 12:58:48
Hi Thorsten,
dann einfach so:
=SUMMENPRODUKT(TEIL(WECHSELN(A1;",";)*10^(16-LÄNGE(WECHSELN(A1;",";)));ZEILE(1:16);1)*10^(ZEILE(1:16)-1))&WIEDERHOLEN(0;12-LÄNGE(WECHSELN(A1;",";))-LÄNGE(WECHSELN(A2;",";)))&WECHSELN(A2;",";)
Grüße Boris
Bild

Betrifft: ich würde es...
von: FP
Geschrieben am: 02.04.2005 13:40:18
Hallo Boris,
... aus diesem Grund ( siehe Beispiel ) trotzdem so lösen:
Tabelle2
 ABCD
3100 00100000045612
44,56 100000045610
Formeln der Tabelle
C3 : =TEXT(SUMMENPRODUKT(TEIL(TEXT(WECHSELN(A3+0;",";"");"000000");ZEILE($1:$6);1)*10^ZEILE($1:$6))/10;"000000")&TEXT(WECHSELN(A4+0;",";"");"000000")
D3 : =LÄNGE(C3)
C4 : =SUMMENPRODUKT(TEIL(WECHSELN(A3;",";)*10^(16-LÄNGE(WECHSELN(A3;",";)));ZEILE(1:16);1)*10^(ZEILE(1:16)-1))&WIEDERHOLEN(0;12-LÄNGE(WECHSELN(A3;",";))-LÄNGE(WECHSELN(A4;",";)))&WECHSELN(A4;",";)
D4 : =LÄNGE(C4)
 
Diagramm - Grafik - Excel Tabellen einfach im Web darstellen    Excel Jeanie HTML  3.0    Download  
Servus aus dem Salzkammergut
Franz
Bild

Betrifft: AW: Zahlen Drehen/Spiegeln
von: Thorsten
Geschrieben am: 01.04.2005 17:21:56
Vielen Dank für die Hilfe
 Bild

Beiträge aus den Excel-Beispielen zum Thema "Zahlen Drehen/Spiegeln"