Herbers Excel-Forum - das Archiv

Bewerten Sie hier bitte das Excel-Portal

Datum

  • Datum von Bärbel vom 28.12.2006 09:49:58
Bild

Betrifft: Datum
von: Bärbel

Geschrieben am: 28.12.2006 09:49:58
Hallo Excelexperten
Bei der Arbeit mit meinen Exceltabellen brauche ich früh oft das aktuelle Datum.
Geht das Datum irgendwie in der Menüleiste dauerhaft anzuzeigen? Und wenn ja ,wie?
Schon im voraus vielen Dank für s`knobeln.
Gruß Bärbel
Bild

Betrifft: AW: Datum
von: Nepumuk

Geschrieben am: 28.12.2006 10:10:26
Hallo Bärbel,
Rechtsklick auf das Excelicon in der Menüleiste ganz links - Code anzeigen. Folgende Prozeduren in das sich öffnende Editorfenster kopieren, Mappe speichern, schließen und wieder öffnen.
Option Explicit

Private Const BUTTON_TAG = "Datum"

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    Call prcDeleteButton
End Sub

Private Sub Workbook_Open()
    Dim intIndex As Integer
    Dim objButton As CommandBarButton
    Call prcDeleteButton
    For intIndex = 1 To 2
        Set objButton = Application.CommandBars(intIndex).Controls.Add( _
            Type:=msoControlButton, Temporary:=True)
        With objButton
            .Caption = CStr(Date)
            .Style = msoButtonCaption
            .Tag = BUTTON_TAG
        End With
    Next
End Sub

Private Sub prcDeleteButton()
    Dim intIndex As Integer
    Dim objControl As CommandBarControl
    For intIndex = 1 To 2
        With Application.CommandBars(intIndex)
            For Each objControl In .Controls
                If objControl.Tag = BUTTON_TAG Then objControl.Delete
            Next
        End With
    Next
End Sub



Gruß


Nepumuk



Bild






Betrifft: AW: Datum



von: haw













Geschrieben am: 28.12.2006 12:44:26


Hallo Bärbel,


so z.B.:



Private Sub Workbook_Open()
Application.Caption = "Heute ist " & Format(Date, "dddd,") & " der " & Format(Date, "d/mmmm yyyy") & ">"
End Sub



Dann steht das Datum und ein eventueller Text in der Titelleiste


Gruß Heinz


Bild






Betrifft: AW: Datum



von: Bärbel













Geschrieben am: 28.12.2006 15:48:22


Hallo Heinz und Nepumuk


Hat auf Anhieb geklappt.


Vielen Dank für die wertvolle Hilfe.


Allen Forumteilnehmern ein frohes erfolgreiches sowie gesundes Exceljahr 2007.


Gruß Bärbel





 Bild