Thema: Hyperlinks automatisch starten

Hallo Forum
Hab da mal nen "Problemchen".
In Tabelle1 Spalte A stehen untereinander mehrere Hyperlinks ins www.
Diese Hyperlinks würd ich gerne automatisch stündlich anwählen und nach Anwahl die IE-Fenster wieder schliessen lassen.
Also:
Starte HL in A1 im IE.
Schliesse IE.
Starte HL in A2 im IE
Schliesse IE.
usw.
Könnte mir da mal jemand mit nem Makro behilflich sein?
Danke Euch.
Gruß aus dem Sauerland
Jens

Hi,
erscheint ziemlich sinnlos, oder?
mfg Heinz

Hallo
Wenn es für sinnlos wäre, würd ich nicht nach einer Lösung fragen.
Gruß aus dem Sauerland
Jens

Hi,
deine Antwort gibt keinerlei Aufschluss darüber, was du damit erreichen willst.
mfg Heinz

Hallo
Ich muss die Links stündlich aufrufen, um von dort Daten abzufragen.
Die Datenabfrage ist nicht das Problem. Lediglich der stündliche Aufruf der Link ist entscheidend.
Gruß aus dem Sauerland
Jens

Hallo,
so müsste es gehen.
Über MeineWB wird eine Schleife gestartet die alle Webseiten ab A1 bis zur letzten gefüllten durchläuft und diese an die Funktion Linkaufruf übergibt.
Durch StartTimer wird der nächste durchlauf eingestellt, hier eine Stunde.
Auf eine Fehlerbehandlung für den Webaufruf habe ich jetzt mal verzichtet, kannst du ja selbst einbauen.
In ein Modul

Option Explicit
Public Zeit As Date
Sub StartTimer()
Application.OnTime Zeit, "MeineWB"
End Sub
Sub ResetTimer()
On Error Resume Next
Application.OnTime earliesttime:=Zeit, _
procedure:="MeineWB", schedule:=False
On Error GoTo 0
End Sub
Sub MeineWB()
Dim A As Long
For A = 1 To Cells(Rows.Count, 1).End(xlUp).Row
If Cells(A, 1) > "" Then Linkaufruf Cells(A, 1)
Next A
Zeit = Now + CDate("01:00:00")
StartTimer
End Sub
Function Linkaufruf(strSeite As String)
Dim appIE As Object
Set appIE = CreateObject("InternetExplorer.application")
appIE.Visible = True  'False ist unsichtbar    True ist Sichtbar
appIE.Navigate strSeite
While Not appIE.ReadyState = 4 'Warte auf Webseite
DoEvents
Wend
appIE.Quit
Set appIE = Nothing
End Function

In DieseArbeitsmappe als Code

Private Sub Workbook_BeforeClose(Cancel As Boolean)
Call ResetTimer
End Sub

Gruß Tino

www.VBA-Excel.de

Hallo Tino
Genau so hab ich das gemeint.
Danke Dir für Deine Hilfe :-)
Fehlerroutine etc. sollte kein Problem sein.
Gruß aus dem Sauerland
Jens