Microsoft Excel

Herbers Excel/VBA-Archiv

Spalte für Gültigkeit ohne Leerzellen + Kriterium | Herbers Excel-Forum


Betrifft: Spalte für Gültigkeit ohne Leerzellen + Kriterium von: Andre
Geschrieben am: 15.12.2009 14:55:54

Hallo,

hab mal wieder eine Frage. Ich denke das Ergebnis des Themas könnte viele interessieren. Ist brauchbar für offene Bestände.

Ich benötige eine Formel, die mir in einer anderen Spalte die Werte einer Spalte untereinander anzeigt, jedoch ohne Leerzellen und nur wenn ein bestimmtes Kriterium erfüllt ist.

Das Thema habe ich des öfteren gefunden, jedoch nie eine verständliche Lösung.

Hier das Beispiel, hoffe es ist nicht zu schwierig. Würdet mir sehr helfen.


gruss André

  

Betrifft: AW: Spalte für Gültigkeit ohne Leerzellen + Kriterium von: Matthias5
Geschrieben am: 15.12.2009 15:05:23

Hallo André,


Tabelle2

 ABCD
11erledigt  2
22offen  1
31offen  3
4      6
55erledigt  22
63offen  21
7      24
86offen   
97erledigt   
1022offen   
1121offen   
1224offen   
13       
14       

verwendete Formeln
Zelle Formel
D1 {=WENN(ZEILE(A1)>ZÄHLENWENN(B:B;"offen");"";INDEX(A:A;KKLEINSTE(WENN(($A$1:$A$100<>"")*($B$1:$B$100="offen");ZEILE($1:$100));ZEILE(A1))))}
{} Matrixformel mit Strg+Umschalt+Enter abschließen

Tabellendarstellung in Foren Version 4.8

Gruß,
Matthias


  

Betrifft: AW: Spalte für Gültigkeit ohne Leerzellen + Kriterium von: Andre
Geschrieben am: 15.12.2009 15:09:14


G.E.I.L

... danke!


  

Betrifft: AW: Spalte für Gültigkeit ohne Leerzellen + Kriterium von: Andre
Geschrieben am: 15.12.2009 15:40:36

Hallo,

ich habe versucht es ab Zeile19 zu berechnen, doch es will einfach nicht funktionieren.

=WENN(ZEILE(B19)>ZÄHLENWENN(D:D;"open");"";INDEX(B:B;KKLEINSTE(WENN(($B$19:$B$100<>"") *($D$19:$D$100="open");ZEILE($19:$100));ZEILE(B19))))

B ist meine Spalte mit den Werten und D mit dem Kriterium.

Wenn die Werte bei B1 anfangen und ich die Formel auf B1 änder geht es.... hmmm


  

Betrifft: Start ab Zeile 19 von: Matthias5
Geschrieben am: 15.12.2009 15:48:57

Hallo André;

ab Zeile 19 würde es so gehen:
{=WENN(ZEILE(A1)>ZÄHLENWENN(B:B;"offen");"";INDEX(A:A;KKLEINSTE(WENN(($A$19:$A$118<>"") *($B$19:$B$118="offen");ZEILE($19:$118));ZEILE(A1)))) }

Zeile(A1) bleibt so immer für die erste Formel bestehen, habe ich hier heute schon mal erklärt:
http://www.online-excel.de/fom/fo_read.php?f=1&bzh=45859&h=45855#a123x

Gruß,
Matthias


  

Betrifft: AW: Start ab Zeile 19 von: Andre
Geschrieben am: 15.12.2009 16:04:05

Hallo,

ja super, habe noch vergessen zu erwähnen, da ich mir nur Gedanken über die Formel im Allgemeinen gemacht habe, das sie über 2 Tabellenblätter geht,

Also die eigentliche Liste ist heisst 'Verkauf'! doch das bekomme ich einfach nicht hin, liegt wohl am nichtverstehen des ganzen Sinns der Formel... sry

Da fangen die Werte in A19 an und in O19 sollte open stehen...


  

Betrifft: AW: Start ab Zeile 19 von: Matthias5
Geschrieben am: 15.12.2009 16:30:43

Hi,

das sollte so gehen:
{=WENN(ZEILE(A1)>ZÄHLENWENN(Verkauf!O:O;"offen");"";INDEX(Verkauf!A:A; KKLEINSTE(WENN((Verkauf!$A$19:$A$118<>"")*(Verkauf!$O$19:$O$118="offen");ZEILE($19:$118)); ZEILE(A1)))) }

Ich bin jetzt erstmal weg und kann ggf. nicht mehr antworten.

Viele Erfolg!
Matthias


Beiträge aus den Excel-Beispielen zum Thema "Spalte für Gültigkeit ohne Leerzellen + Kriterium"