Menüleiste

Informationen und Beispiele zu den hier genannten Dialog-Elementen:


Excel-Version: 8.0 (Office 97)
nach unten

Betrifft: Menüleiste
von: Bianca
Geschrieben am: 18.07.2002 - 17:58:27

Hallöchen

Wer kann mir sagen wie ich in Excel die Menü- und die vorhandenen Symbolleisten per VBA beim öffnen
Workbook_open entferne und beim schliessen
Workbook_beforeclose wieder auf den ursprünglichen Zustand bringe.


nach oben   nach unten

Re: Menüleiste
von: GraFri
Geschrieben am: 18.07.2002 - 18:05:36

Hallo

Alles in ein Modul:


Option Explicit
     Dim Cn%
     Dim CdbList()

     Dim Status_FormulaBar As Boolean
     Dim Status_HorScroll As Boolean
     Dim Status_StatusBar As Boolean
     Dim Status_VerScroll As Boolean
     Dim Status_Gridlines As Boolean
     Dim Status_Headings As Boolean

     Dim xCn%
     Dim xCdbList()

     Dim xStatus_FormulaBar As Boolean
     Dim xStatus_HorScroll As Boolean
     Dim xStatus_StatusBar As Boolean
     Dim xStatus_VerScroll As Boolean
     Dim xStatus_Gridlines As Boolean
     Dim xStatus_Headings As Boolean


     Sub Auto_Open()
     Dim Cdb As CommandBar

     'Wenn Titelleiste von Excel geändern werden soll
        Application.Caption = "Meine Mustervorlage"

     'falls die eigenen Symbolleisten auch ausgeblendet werden sollen, dann
     'den Code 'And Cdb.BuiltIn = True' aus nachstehender Zeile entfernen
     Cn = 1
     For Each Cdb In Application.CommandBars
         If Cdb.Visible And Cdb.Type <> msoBarTypeMenuBar Then 'And Cdb.BuiltIn = True Then
             ReDim Preserve CdbList(Cn)
             CdbList(Cn) = Cdb.Name
             Cn = Cn + 1
             Cdb.Visible = False
         End If
     Next

     With ActiveWindow
         Status_HorScroll = .DisplayHorizontalScrollBar
         If .DisplayHorizontalScrollBar = True Then .DisplayHorizontalScrollBar = False

         Status_VerScroll = .DisplayVerticalScrollBar
         If .DisplayVerticalScrollBar = True Then .DisplayVerticalScrollBar = False

         Status_Gridlines = .DisplayGridlines
         If .DisplayGridlines = True Then .DisplayGridlines = False

         Status_Headings = .DisplayHeadings
         If .DisplayHeadings = True Then .DisplayHeadings = False
     End With

     With Application
         Status_StatusBar = .DisplayStatusBar
         If .DisplayStatusBar = True Then .DisplayStatusBar = False

         Status_FormulaBar = .DisplayFormulaBar
         If .DisplayFormulaBar = True Then .DisplayFormulaBar = False
     End With

     CommandBars(1).Enabled = False

     End Sub


     Sub Auto_Close()
     Dim Cdb As CommandBar
     Dim Ci%


     For Ci = 1 To Cn - 1
         Application.CommandBars(CdbList(Ci)).Visible = True
     Next Ci

     With ActiveWindow
         .DisplayHeadings = Status_Headings
         .DisplayHorizontalScrollBar = Status_HorScroll
         .DisplayVerticalScrollBar = Status_VerScroll
         .DisplayGridlines = Status_Gridlines
     End With

     With Application
         .DisplayStatusBar = Status_StatusBar
         .DisplayFormulaBar = Status_FormulaBar
     End With

     CommandBars(1).Enabled = True
     End Sub

mfg, GraFri

nach oben   nach unten

Re: Menüleiste
von: Bianca
Geschrieben am: 18.07.2002 - 18:58:48

Danke werds ausprobieren

 nach oben

Beiträge aus den Excel-Beispielen zum Thema "zellen mit sich selbst"