Microsoft Excel

Herbers Excel/VBA-Archiv

Formel die Prozentsatz berechnet

Betrifft: Formel die Prozentsatz berechnet von: Christian
Geschrieben am: 01.11.2014 16:09:52

Hallo alle zusammen,

bevor ihr euch wundert, Prozentrechnung kann ich natürlich selbst, jedoch komme ich mit den Bedingungen nicht weiter und bitte um eure Hilfe.

Ich suche eine Formel, die mir ausgibt, auf wieviel % der Zeilen eine der beiden Möglichkeiten zutrifft und das bitte ohne Hilfsspalten oder -zellen.

1. Möglichkeit: N leer und G größer 400
2. Möglichkeit: N nicht leer und M größer 14/24.

Außerdem wäre es super wenn ich die Formel nicht ändern muss, wenn Zeilen zu den derzeit 516 dazukommen.

Kann mir dabei jemand helfen?

Gruß und danke
Christian

  

Betrifft: AW: Formel die Prozentsatz berechnet von: And
Geschrieben am: 01.11.2014 17:49:36

Hallo,

für Bedingung 1 so:
Zellformat = %
=SUMMENPRODUKT((G1:G1000>400)*(N1:N1000=""))/ANZAHL(G1:G1000)

für bedingung 2 selbst anpassen
8was ist 14/24? Text oder Bruch


  

Betrifft: Da fehlt die entscheidende Definition von: WF
Geschrieben am: 01.11.2014 17:56:57

Hi,

ist ja sehr einfach (ich beschränke mich auf 1.)
=SUMMENPRODUKT((N1:N999>"")*(G1:G999>400))

Da fehlt aber der Divisor, um einen Prozentsatz auszurechnen.
Ist das eine fixe Zahl?
Ist das die Anzahl der gefüllten Zellen in N oder G?
Ist das die Anzahl der gefüllten Zeilen?
Ist das die letzte gefüllte Zelle in N oder G - bzw letzte gefüllte Zeile?

WF


  

Betrifft: AW: Da fehlt die entscheidende Definition von: Christian
Geschrieben am: 01.11.2014 19:56:52

Hallo ich versuche es anders auszudrücken.

Ich schreibe in Spalte O die Formel:

=WENN(ODER(UND(N1="";G1>400);UND(N1<>"";M1>14/24));"X";"")
über die ganze Tabelle kopiere
und dann die Formel (Spalte A, da in Spalte A keine Leerzellen sind)
=((ZÄHLENWENN(O:O;"X")/ANZAHL2(A:A))*100)
berechne, nur das halt ohne die Hilfsspalte.
Ich hoffe das beantwortet eure Frage.

Gruß
Christian


  

Betrifft: immer noch kein Divisor von: WF
Geschrieben am: 01.11.2014 20:17:55

Hi,

Deine Formel in O ohne runterzukopieren - also Dein (ZÄHLENWENN(O:O;"X") ist:
=SUMMENPRODUKT((N1:N999="")*(G1:G999>400)+(N1:N999<>"")*(M1:M999>14/24))

aber
/ANZAHL2(A:A))*100)

was ist das - Spalte A kommt bisher überhaupt nicht vor ?

WF


  

Betrifft: AW: immer noch kein Divisor von: Christian
Geschrieben am: 01.11.2014 21:00:41

Hallo WF,

du hast mir doch eigentlich die Lösung gegeben.
Ich habe eine Formel gesucht, die den prozentualen Anteil der Zeilen die eine der beiden Bedingungen erfüllen ausgibt.

Dazu brauche ich die Anzahl der Zeilen, die die Bedingungen erfüllen, dafür hast du mir die _ Formel

=SUMMENPRODUKT((N1:N999="")*(G1:G999>400)+(N1:N999<>"")*(M1:M999>14/24))
gegeben.

und die Anzahl der Zeilen insgesamt, da es in Spalte A keine Leerzellen gibt, lässt sich diese Anzahl durch =ANZAHL2(A:A) berechnen.

Und da ichs in Prozent haben will das ganze noch mal 100.

Also habe ich mit
=(SUMMENPRODUKT((N1:N999="")*(G1:G999>400)+(N1:N999<>"")*(M1:M999>14/24))/ANZAHL2(A:A)) *100
meine gesuchte Formel.

Danke und noch ein schönes Wochenende
Christian


 

Beiträge aus den Excel-Beispielen zum Thema "Formel die Prozentsatz berechnet"