Einordnung von Werten in eine Klasse

Bild

Betrifft: Einordnung von Werten in eine Klasse
von: Simon Privat
Geschrieben am: 06.10.2015 16:43:29

Hey,
ich habe folgendes Problem:
Ich habe eine Liste von Vorgaben für die Zuordnung zu bestimmten Klassen aus einer Norm.
Für jede Zeile (Klasse) sind 2 Werte für mich relevant (Durchmesser und Dicke). Außerdem ist eine Toleranz zum jeweiligen Wert gegeben.
Nun möchte ich herausfinden, ob ich in meiner Datenbasis (Tabelle auf einem weiteren Sheet) ein (oder mehrere) Item(s) habe, welche die Kriterien erfüllen, sich also sowohl bei Durchmesser und Dicke innerhalb des Bereichs einer Normklasse befinden (Durchmesser von meinem Item < Durchmesser Norm plus Toleranz und Durchmesser Item > Durchmesser Norm minus Toleranz). Falls ja, so sollten die Item Nummern angezeigt werden.
Hatte es zuerst mit einer etwas verschachtelten IF(AND(...... Kombination versucht, was jedoch nicht so geklappt hat.
Ob ich das mit Excel lösen kann oder VBA dafür brauche bin ich mir nicht sicher.
Danke schon mal für eure Hilfe :)
LG

Bild

Betrifft: AW: Einordnung von Werten in eine Klasse
von: Sepp
Geschrieben am: 06.10.2015 19:02:30
Hallo Simon,
da wäre eine Beispieldatei mit Beschreibung und Beispielen der gewünschten Ergebnisse hilfreich.

Gruß Sepp


Bild

Betrifft: AW: Einordnung von Werten in eine Klasse
von: Simon Privat
Geschrieben am: 07.10.2015 16:24:03
Hey Sepp,
danke für deine Antwort :)
ich habe mal eben eine Beispieldatei erstellt und hochgeladen.
https://www.herber.de/bbs/user/100644.xlsm
Auf dem ersten Sheet sind die Klassen.
Auf dem Zweiten meine Teile mit Nummer und Eigenschaften.
Nun möchte ich herausfinden, ob denn ein Teil einer Klasse zugeordnet werden kann oder nicht.
Also entweder soll auf Sheet 1 erscheinen hinter der Klasse zugehörige Teilenummern xxxxx oder auf Sheet 2 hinter dem Teil zugehörig zu Klasse x.
Hoffe das ist verständlich :)
Danke

Bild

Betrifft: AW: Einordnung von Werten in eine Klasse
von: Simon Privat
Geschrieben am: 07.10.2015 16:44:31
Sorry für den Doppelpost, aber irgendwie bin ich gerade zu blöd, die Editierfunktion zu finden... :)
Ich hatte vergessen zu erwähnen, dass ich eine englische Version von Excel benutze, die Codes also auf englisch sein müssen....
Danke!

Bild

Betrifft: Das ist keine Beispieldatei!
von: Sepp
Geschrieben am: 07.10.2015 19:18:13
Hallo Simon,
sorry, aber das ist keine Beispieldatei! Deine Werte sind Zufallszahlen, die in deiner Vergleichstabelle nicht vorkommen. Außerdem weiß ich nicht, was und wo angezeigt werden soll.
Wenn du dir nicht die Mühe machst ein ordentliches Beispiel zu erstelle, kannst du wohl nicht erwarten, dass dir jemand hilft!

Gruß Sepp


Bild

Betrifft: AW: Das ist keine Beispieldatei!
von: Simon Privat
Geschrieben am: 08.10.2015 09:05:22
Hey,
tut mir leid, dass sich die Zufallszahlen jedes mal neu berechnen hatte ich nicht bedacht.
Habs jetzt nochmal versucht.... hoffe es passt so.
https://www.herber.de/bbs/user/100653.xlsm
Also auf dem ersten Sheet befinden sich meine Klassen. auf dem Zweiten die praktischen Daten.
Nun sollen die Daten (wenn möglich) einer Klasse zugeordnet werden.
Ob dazu auf dem ersten Sheet hinter den Klassen die dort zugehörigen Teilenummern angeführt werden oder auf Sheet 2 zu jeder Teilenummer eine Klasse (sofern es zu einer Klasse gehört) angezeigt wird, ist für mich persönlich egal.... habe mal beide Optionen manuell in die Tabelle eingetragen in rot.
So in etwa hatte ich mir das vorgestellt.
Da die manuelle Überprüfung natürlich zu aufwendig ist, wäre es super wenn das automatisch funktionieren könnte.
Danke!
LG

Bild

Betrifft: AW: Das ist keine Beispieldatei!
von: Sepp
Geschrieben am: 08.10.2015 20:07:37
Hallo Simon,
Klassen

 BCDEFGHIJKL
3KlasseInnendurchmesserToleranz InnendurchmesserQuerschnittToleranz QuerschnittZugehörige Teilenummern     
4A10110,121107     
5B1011,50,1534168     
6C3031,50,157778934016    
7D50330,499104     
8E70330,4      
9F75430,4      
10G100550,5      
11H1205101      
12I30010101      
13J3501010176583     

Formeln der Tabelle
ZelleFormel
G4{=WENNFEHLER(INDEX(Table1[Teilenummer];KKLEINSTE(WENN((Table1[Innendurchmesser]<=$C4+$D4)*(Table1[Innendurchmesser]>=$C4-$D4)*(Table1[Querschnitt]<=$E4+$F4)*(Table1[Querschnitt]>=$E4-$F4); ZEILE($A$1:INDEX($A:$A;ANZAHL2(Table1[Teilenummer])))); SPALTE(A$1))); "")}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8
Daten

 BCDE
3TeilenummerInnendurchmesserQuerschnittEinordnung in Klasse
4749429,001,25 
5211079,801,1A
63416810,201,5B
78618711,003,53 
84520211,502,5 
99904225,007,56 
109361228,004,5 
115723725,001,1 
127861632,001,1 
137778933,001,45C
143401630,001,45C
152976835,001,08 
1672638100,003,4 
172414180,002 
189910452,503,35D
193460295,502,78 
202822997,203,21 
218218096,801,05 
2254347135,001,65 
2360797122,002 
2459927188,002 
2557572189,002 
2625046320,002 
2767557310,002 
2876583345,0010,57J
2966168347,6012,5 
304153120,006,5 
318061922,601,5 
328182435,501 

Formeln der Tabelle
ZelleFormel
E4{=WENNFEHLER(INDEX(Klassen!$B$4:$B$13;MIN(WENN((Klassen!$C$4:$C$13+Klassen!$D$4:$D$13>=[@Innendurchmesser])*(Klassen!$C$4:$C$13-Klassen!$D$4:$D$13<=[@Innendurchmesser])*(Klassen!$E$4:$E$13+Klassen!$F$4:$F$13>=[@Querschnitt])*(Klassen!$E$4:$E$13-Klassen!$F$4:$F$13<=[@Querschnitt]); ZEILE($A$1:$A$10); 10^9))); "")}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8
Gruß Sepp


 Bild

Beiträge aus den Excel-Beispielen zum Thema "Einordnung von Werten in eine Klasse"