Ich möchte in meiner MsGBox einen Text "H2O" mit tiefergestellter 2 erstellen.
Mit freundlichem Gruß
G.
Label1.Caption = "H" & ChrW(8322) & "O"
Gruß Ralf
MsgBox "H" & ChrW(8322) & "O"
Man müsste folglich ein Label in einem Userform nehmen, bei dem man die Schriftart einstellen kann.
Private Declare PtrSafe Function MessageBoxW Lib "User32" (ByVal hWnd As LongPtr, ByVal lpText As LongPtr, ByVal lpCaption As LongPtr, ByVal uType As Long) As Long
Public Function MsgBoxW(Prompt As String, Optional Buttons As VbMsgBoxStyle = vbOKOnly, Optional Title As String = "Microsoft Excel") As VbMsgBoxResult
MsgBoxW = MessageBoxW(Application.hWnd, StrPtr(Prompt), StrPtr(Title), Buttons)
End Function
Ungetestet
Sub test()
MsgBoxW "H" & ChrW(8322) & "O"
End Sub
und das sah aus, als würde es funktionieren.
Option Explicit
Private Declare PtrSafe Function MessageBoxW Lib "User32" (ByVal hWnd As LongPtr, ByVal lpText As LongPtr, ByVal lpCaption As LongPtr, ByVal uType As Long) As Long
'Public Function MsgBoxW(Prompt As String, Optional Buttons As VbMsgBoxStyle = vbOKOnly, Optional Title As String = "Microsoft Excel") As VbMsgBoxResult
'MsgBoxW = MessageBoxW(Application.hWnd, StrPtr(Prompt), StrPtr(Title), Buttons)
'End Function
Public Function MsgBox(Prompt As String, Optional Buttons As VbMsgBoxStyle = vbOKOnly, Optional Title As String = "Microsoft Excel") As VbMsgBoxResult
MsgBox = MessageBoxW(Application.hWnd, StrPtr(Prompt), StrPtr(Title), Buttons)
End Function
Public Sub test()
MsgBox "H" & ChrW(8322) & "O"
End Sub
überschreiben
Private Declare PtrSafe Function MessageBoxW Lib "User32" (ByVal hWnd As LongPtr, ByVal lpText As LongPtr, ByVal lpCaption As LongPtr, ByVal uType As Long) As Long
Sub test()
Dim FehlerT As String
FehlerT = "H" & ChrW(8322) & "O: Zählerstand ist keine Zahl, oder fehlt"
If MsgBoxW(FehlerT, vbExclamation + vbOKOnly, "blabla") = vbOK Then Exit Sub
MsgBox "fertig"
End Sub
Public Function MsgBoxW(Prompt As String, Optional Buttons As VbMsgBoxStyle = vbOKOnly, Optional Title As String = "Microsoft Excel") As VbMsgBoxResult
MsgBoxW = MessageBoxW(Application.hWnd, StrPtr(Prompt), StrPtr(Title), Buttons)
End Function
In ein Modul rein gesetzt, und das funktioniert.Code:Private Declare PtrSafe Function MeineMsgBox Lib "User32" Alias "MessageBoxW" ( _ ByVal hWnd As LongPtr, ByVal lpText As LongPtr, _ ByVal lpCaption As LongPtr, ByVal uType As Long) As Long Sub Test() Dim FehlerHT As String, Zeile As Long, FehlerNr Zeile = 1 FehlerT = "H" & ChrW(8322) & "O: Zählerstand ist keine Zahl, oder fehlt" If MeineMsgBox(Application.hWnd, StrPtr(FehlerT), StrPtr("Parzelle: " _ & Range("A" & Zeile) & ", " & Range("E" & Zeile) _ & " Fehler " & FehlerNr), vbExclamation + vbOKCancel) = vbOK Then Exit Sub End Sub
Option Explicit
Private Declare PtrSafe Function MessageBoxW Lib "User32" (ByVal hWnd As LongPtr, ByVal lpText As LongPtr, ByVal lpCaption As LongPtr, ByVal uType As Long) As Long
Public Function MsgBox(Prompt As String, Optional Buttons As VbMsgBoxStyle = vbOKOnly, Optional Title As String = "Microsoft Excel") As VbMsgBoxResult
MsgBox = MessageBoxW(Application.hWnd, StrPtr(Prompt), StrPtr(Title), Buttons)
End Function
Public Sub test()
Dim FehlerT As String, Titel As String
Titel = "Parzelle: " & "4711" & ", " _
& "/123" & " Fehler " & "0815"
FehlerT = "H" & ChrW(8322) & "O: Zählerstand ist keine Zahl, oder fehlt"
If MsgBox(FehlerT, vbExclamation + vbOKCancel, Titel) = vbCancel Then Exit Sub
MsgBox "mach was"
End Sub
Gruß Gerd
Option Explicit
Public Enum enMsgBox
MB_ABORTRETRYIGNORE = &H2
' The message box contains three push buttons: Abort, Retry, and Ignore.
MB_CANCELTRYCONTINUE = &H6
' The message box contains three push buttons: Cancel, Try Again, Continue. Use this message box type instead of MB_ABORTRETRYIGNORE.
MB_HELP = &H4000
' Adds a Help button to the message box. When the user clicks the Help button or presses F1, the system sends a WM_HELP message to the owner.
MB_OK = &H0
' The message box contains one push button: OK. This is the default.
MB_OKCANCEL = &H1
' The message box contains two push buttons: OK and Cancel.
MB_RETRYCANCEL = &H5
' The message box contains two push buttons: Retry and Cancel.
MB_YESNO = &H4
' The message box contains two push buttons: Yes and No.
MB_YESNOCANCEL = &H3
' The message box contains three push buttons: Yes, No, and Cancel.
' To display an icon in the message box, specify one of the following values.
MB_ICONEXCLAMATION = &H30
' An exclamation-point icon appears in the message box.
MB_ICONWARNING = &H30
' An exclamation-point icon appears in the message box.
MB_ICONINFORMATION = &H40
' An icon consisting of a lowercase letter i in a circle appears in the message box.
MB_ICONASTERISK = &H40
' An icon consisting of a lowercase letter i in a circle appears in the message box.
MB_ICONQUESTION = &H20
' A question-mark icon appears in the message box. The question-mark message icon is no longer recommended because it does not clearly represent a specific type of message and because the phrasing of a message as a question could apply to any message type. In addition, users can confuse the message symbol question mark with Help information. Therefore, do not use this question mark message symbol in your message boxes. The system continues to support its inclusion only for backward compatibility.
MB_ICONSTOP = &H10
' A stop-sign icon appears in the message box.
MB_ICONERROR = &H10
' A stop-sign icon appears in the message box.
MB_ICONHAND = &H10
' A stop-sign icon appears in the message box.
' To indicate the default button, specify one of the following values.
MB_DEFBUTTON1 = &H0
' The first button is the default button.
' MB_DEFBUTTON1 is the default unless MB_DEFBUTTON2, MB_DEFBUTTON3, or MB_DEFBUTTON4 is specified.
MB_DEFBUTTON2 = &H100
' The second button is the default button.
MB_DEFBUTTON3 = &H200
' The third button is the default button.
MB_DEFBUTTON4 = &H300
' The fourth button is the default button.
' To indicate the modality of the dialog box, specify one of the following values.
MB_APPLMODAL = &H0
' The user must respond to the message box before continuing work in the window identified by the hWnd parameter. However, the user can move to the windows of other threads and work in those windows.
' Depending on the hierarchy of windows in the application, the user may be able to move to other windows within the thread. All child windows of the parent of the message box are automatically disabled, but pop-up windows are not.
' MB_APPLMODAL is the default if neither MB_SYSTEMMODAL nor MB_TASKMODAL is specified.
MB_SYSTEMMODAL = &H1000
' Same as MB_APPLMODAL except that the message box has the WS_EX_TOPMOST style. Use system-modal message boxes to notify the user of serious, potentially damaging errors that require immediate attention (for example, running out of memory. This flag has no effect on the user's ability to interact with windows other than those associated with hWnd.
MB_TASKMODAL = &H2000
' Same as MB_APPLMODAL except that all the top-level windows belonging to the current thread are disabled if the hWnd parameter is NULL. Use this flag when the calling application or library does not have a window handle available but still needs to prevent input to other windows in the calling thread without suspending other threads.
' To specify other options, use one or more of the following values.
MB_DEFAULT_DESKTOP_ONLY = &H20000
' Same as desktop of the interactive window station. For more information, see Window Stations.
' If the current input desktop is not the default desktop, MessageBox does not return until the user switches to the default desktop.
MB_RIGHT = &H80000
' The text is right-justified.
MB_RTLREADING = &H100000
' Displays message and caption text using right-to-left reading order on Hebrew and Arabic systems.
MB_SETFOREGROUND = &H10000
'The message box becomes the foreground window. Internally, the system calls the SetForegroundWindow function for the message box.
MB_TOPMOST = &H40000
'The message box is created with the WS_EX_TOPMOST window style.
MB_SERVICE_NOTIFICATION = &H200000
'The caller is a service notifying the user of an event. The function displays a message box on the current active desktop, even if there is no user logged on to the computer.
'Terminal Services: If the calling thread has an impersonation token, the function directs the message box to the session specified in the impersonation token.
'If this flag is set, the hWnd parameter must be NULL. This is so that the message box can appear on a desktop other than the desktop corresponding to the hWnd.
'For information on security considerations in regard to using this flag, see Interactive Services. In particular, be aware that this flag can produce interactive content on a locked desktop and should therefore be used for only a very limited set of scenarios, such as resource exhaustion.
End Enum
Private Declare PtrSafe Function MessageBoxW Lib "User32" (ByVal hWnd As LongPtr, ByVal lpText As LongPtr, ByVal lpCaption As LongPtr, ByVal uType As Long) As Long
Public Function MsgBox(Prompt As String, Optional Buttons As enMsgBox = enMsgBox.MB_DEFBUTTON1 + enMsgBox.MB_OKCANCEL + enMsgBox.MB_ICONWARNING, Optional Title As String = "Microsoft Excel") As VbMsgBoxResult
MsgBox = MessageBoxW(Application.hWnd, StrPtr(Prompt), StrPtr(Title), Buttons)
End Function
Public Sub test()
MsgBox "H" & ChrW(8322) & "O"
End Sub
hth