ListBox Inhalt audrucken....

Informationen und Beispiele zu den hier genannten Dialog-Elementen:
Bild

Betrifft: ListBox Inhalt audrucken.... von: Drazen
Geschrieben am: 22.02.2005 20:50:45

Hallo,

ich habe mir verschiedene Daten in eine UF-Listbox eingelesen, kann ich jetzt nur diese Daten ausdrucken lassen? Irgendwie mit einem Snapshot oder mit einfügen des ListBox-Inhalts in eine temporäre Mappe und dann drucken?
ListBoxen sind zwar sehr sehr hilfreich wenn man das Programieren derselben kann oder?

Vielen Dank für die Hilfe im vorraus.

Grüsse
Drazen

Bild


Betrifft: AW: ListBox Inhalt audrucken.... von: GerdW
Geschrieben am: 22.02.2005 20:53:34

Temporäres Blatt oder Mappe ist doch eine gute Idee!

GerdW


Bild


Betrifft: AW: ListBox Inhalt audrucken.... von: Drazen
Geschrieben am: 22.02.2005 20:57:52

Hallo Gerd,

ja klar aber wie übergebe ich die Daten an die neue Mappe?

Sheets("Tabelle1").Range("A1") = ListBox1.Value ???

Ich hab schon alles mögliche ausprobiert und komme nicht drauf?

Grüsse
Drazen


Bild


Betrifft: AW: ListBox Inhalt audrucken.... von: GerdW
Geschrieben am: 22.02.2005 21:12:40

Ist die ein- oder mehrspaltig?

GerdW


Bild


Betrifft: AW: ListBox Inhalt audrucken.... von: Drazen
Geschrieben am: 22.02.2005 21:18:01

Hallo Gerd,

vieledn Dank für deine Mühe, hiermit werden die Daten eingelesen:

Dim arr() As Variant
Dim iRowL As Integer, sRow As Integer, iCol As Integer, iRowU As Integer
lstAufstellung.Clear
iRowL = Cells(Rows.Count, 10).End(xlUp).Row
For sRow = 1 To iRowL
If (Cells(sRow, 10)) > 0 Then 'Not IsEmpty
ReDim Preserve arr(0 To 9, 0 To iRowU)
arr(0, iRowU) = Cells(sRow, 1)
arr(1, iRowU) = Cells(sRow, 2)
arr(2, iRowU) = Cells(sRow, 3)
arr(3, iRowU) = Cells(sRow, 4)
arr(4, iRowU) = Cells(sRow, 5)
arr(5, iRowU) = Cells(sRow, 6)
arr(6, iRowU) = Cells(sRow, 7)
arr(7, iRowU) = Cells(sRow, 8)
arr(8, iRowU) = Cells(sRow, 9)
arr(9, iRowU) = Cells(sRow, 10)
iRowU = iRowU + 1
End If
Next sRow
lstAufstellung.Column = arr

also mehrspaltig. Ich habe in der Recherche folgenden Coden gefunden, mit dem wir aber nur die erste Spalte an die temporäre Datei übergeben:

Sub Liste()
Dim i As Byte
Workbooks.Add xlWBATWorksheet
For i = 1 To lstAufstellung.ListCount
Cells(i, 1).Value = lstAufstellung.List(i - 1)
Next i
End Sub


Ich weiss nicht wie ich den für mich umbauen könnte


Bild


Betrifft: AW: ListBox Inhalt audrucken.... von: GerdW
Geschrieben am: 22.02.2005 21:30:27

Private Sub CommandButton1_Click()
Dim arrList As Variant, lngR As Long, intC As Integer
Dim wb As Workbook
arrList = ListBox1.List
lngR = ListBox1.ListCount
intC = ListBox1.ColumnCount
Set wb = Workbooks.Add(1)
With wb.Sheets(1)
  .Range(.Cells(1, 1), .Cells(lngR, intC)) = arrList
End With
End Sub


GerdW


Bild


Betrifft: AW: ListBox Inhalt audrucken.... von: Drazen
Geschrieben am: 22.02.2005 21:37:17

Hallo Gerd,

na da iss es ja, ich wäre da NIE drauf gekommen, ich muss anscheinend noch sehr viel lernen, das klappt TOP, Danke.

ZusatzFrage: die gleiche Listbox wir zusätzlich nach Kunden gefiltert und dann so eingelesen, geht das Drucken dann mit dem gleiche Code oder muss ich komplett anders angehen?

Private Sub FILTER()
    lstAufstellung.Clear
    Dim Zeile As Long
    Dim i As Long
    Dim letzte As Long
    With ActiveSheet
        lstAufstellung.ColumnCount = 11
        letzte = .UsedRange.SpecialCells(xlCellTypeLastCell).Row
        Zeile = 0
        For i = 1 To letzte
            If Rows(i).EntireRow.Hidden = False Then
                lstAufstellung.AddItem .Cells(i, 1)
                lstAufstellung.List(Zeile, 1) = .Cells(i, 2)
                lstAufstellung.List(Zeile, 2) = .Cells(i, 3)
                lstAufstellung.List(Zeile, 3) = .Cells(i, 4)
                lstAufstellung.List(Zeile, 4) = .Cells(i, 5)
                lstAufstellung.List(Zeile, 5) = .Cells(i, 6)
                lstAufstellung.List(Zeile, 6) = .Cells(i, 7)
                lstAufstellung.List(Zeile, 7) = .Cells(i, 8)
                lstAufstellung.List(Zeile, 8) = .Cells(i, 9)
                lstAufstellung.List(Zeile, 9) = .Cells(i, 10)
                
                Zeile = Zeile + 1
            End If
        Next i
    End With
End Sub


Grüsse
Drazen


Bild


Betrifft: AW: ListBox Inhalt audrucken.... von: GerdW
Geschrieben am: 22.02.2005 21:49:15

Ich entnehme dem, dass du wissbegierig bist und das selbst lernen willst?
Mein Tipp, versuch meinen Code zu verstehen, dann erübrigt sich die Frage.
Oder du probierst es einfach.

GerdW


Bild


Betrifft: AW: ListBox Inhalt audrucken.... von: Drazen
Geschrieben am: 22.02.2005 21:55:18

Hi Gerd,

hab den Code jetzt etwas detailierter gelesen, und ja er klappt hervoragend, vielen Dank!!
Wieder um einen Schritt weiter, das mit den Arrays ist halt etwas hoch für mich...

Grüsse
Drazen


 Bild

Beiträge aus den Excel-Beispielen zum Thema "ListBox Inhalt audrucken...."