EIN Diagramm erstellen, benennen, verschieben,...

Bild

Betrifft: EIN Diagramm erstellen, benennen, verschieben,...
von: Christian
Geschrieben am: 20.03.2005 12:00:51
Hi Forum - Leuts,
ich bin grad am Rande der Verzweiflung, da ich anscheinend zu doof bin mir EIN Diagramm zu erstellen. Ich will:
- EIN Diagram (Zeitreihenplot) erstellen
- Dieses mit o.g. Namen versehen
- Auf die richtige Position im Sheet verschieben
- Wieder löschen
- Und wieder erstellen (ganze Prozedur quasi von vorn).
Ich hab noch nicht wirklich alle Punkte versucht, da ich am Anfang schon scheitere, aber hier trotzdem mal der Code:
************************************************


Function addGraphik(groesse As Integer)
    
    Dim dia As Object
    Set dia = Charts.Add
    dia.name = "Zeitreihenplot"
    dia.ChartType = xlLine
    dia.SetSourceData Source:=Sheets("Zeitreihe").Range("C4:C" & groesse + 4), _
        PlotBy:=xlColumns
    dia.Location Where:=xlLocationAsObject, name:="Zeitreihe"
    
    'Hab damit nur überprüft
    'Dim te As Variant
    'te = ActiveSheet.ChartObjects.Count
    'Worksheets("Zeitreihe").Cells(1, 5).Value = dia.name <- mag er nicht 
    
    
    With dia
        .HasTitle = True
        .ChartTitle.Characters.Text = "Zeitreihenplot"
        .Axes(xlCategory, xlPrimary).HasTitle = True
        .Axes(xlCategory, xlPrimary).AxisTitle.Characters.Text = "Tag"
        .Axes(xlValue, xlPrimary).HasTitle = True
        .Axes(xlValue, xlPrimary).AxisTitle.Characters.Text = "Absatz"
    End With
    ActiveChart.HasDataTable = False
    Application.ScreenUpdating = True
        
End Function


Wenn ich auch in den ChartObjects oder so nach "Zeitreihenplot" suche, findet er auch nix. Mag er nicht.
Bin für jede Hilfe sowas von danbar!
Chris
Bild

Betrifft: AW: EIN Diagramm erstellen, benennen, verschieben,...
von: Herbert H.
Geschrieben am: 20.03.2005 14:39:36
Hallo Chris,
vielleicht kommst du damit weiter,
hier als Sub ausgeführt...


Sub diagr_erst()
Dim dia As Object, lz%
lz = Cells(Rows.Count, 3).End(xlUp).Row
Application.ScreenUpdating = False
Set dia = Charts.Add
With dia
  .ChartType = xlLine
  .SetSourceData Source:=Sheets("Zeitreihe") _
       .Range("C4:C" & lz), PlotBy:=xlColumns
  .HasTitle = True
  .ChartTitle.Characters.Text = "Zeitreihenpilot"
  .Axes(xlCategory, xlPrimary).HasTitle = True
  .Axes(xlCategory, xlPrimary).AxisTitle. _
                  Characters.Text = "Tag"
  .Axes(xlValue, xlPrimary).HasTitle = True
  .Axes(xlValue, xlPrimary).AxisTitle _
                 .Characters.Text = "Absatz"
  .Location Where:=xlLocationAsObject, _
                   Name:="Zeitreihe"
End With
With Worksheets("Zeitreihe")
     .ChartObjects(1).Name = "Zeitreihenplot"
     .Cells(1, 5).Value = _
     .ChartObjects(1).Name
End With
ActiveSheet.[g20].Select
Application.ScreenUpdating = True
End Sub

     gruß Herbert
 Bild

Beiträge aus den Excel-Beispielen zum Thema "EIN Diagramm erstellen, benennen, verschieben,..."