Live-Forum - Die aktuellen Beiträge
Datum
Titel
29.03.2024 13:14:12
28.03.2024 21:12:36
28.03.2024 18:31:49
Anzeige
Archiv - Navigation
1332to1336
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Kalenderwochen subtrahieren

Kalenderwochen subtrahieren
08.10.2013 11:23:03
Mekerde
Hallo,
ich habe als Ausgabeformat KW/JJ oder JJ/KW, jetzt möchte ich 49 Wochen von dem KW-Wert subtrahieren.
Wie kann ich das ohne Makros realisieren?
Vielen Dank im Voraus.
Mekerde

10
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
KW-Textangaben addieren und subtrahieren ...
08.10.2013 12:18:50
neopa
Hallo Mekerde,
... mit nachfolgender Formel kannst Du KW-Textangaben addieren und subtrahieren. Ich setze voraus, dass Du immer das gleiche Format z.B. KW/JJ nutzt und die KW- und JJ-Angaben in KW/JJ immer zweistellig hast (anderenfalls müsste man noch etwas anpassen):
Tabelle1

 ABC
1KW/JJKWKW/JJ
207/13-4910/12
337/134934/14

Formeln der Tabelle
ZelleFormel
C2=KALENDERWOCHE(("4.1."&RECHTS(A2;2))+LINKS(A2;2)*7-7-REST("2.1."&RECHTS(A2;2); 7)+B2*7)&"/"&RECHTS(JAHR(("4.1."&RECHTS(A2;2))+LINKS(A2;2)*7-7-REST("2.1."&RECHTS(A2;2); 7)+B2*7); 2)


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Werner
.. , - ...

Anzeige
nicht ganz
08.10.2013 12:33:25
Erich
Hi Werner,
da muss noch ein kleiner Wurm drin sein. :-(
Wenn man mit deiner Formel 1 Woche von der 1. KW im Jahr 2006 abzieht, kommt die 53. KW in 2005 raus.
In 2005 ist die größte KW aber die 52.
Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

weil fehlender Parameter 21 in KALENDERWOCHE() ...
08.10.2013 13:39:16
neopa
Hallo Erich,
... Du hast Recht, ich hatte nicht getestet und den Parameter 21 vergessen :-(
Also die Formel =KALENDERWOCHE(("4.1."&RECHTS(A2;2))+LINKS(A2;2)*7-7-REST("2.1."&RECHTS(A2;2);7)+B2*7;21) &"/"&RECHTS(JAHR(("4.1."&RECHTS(A2;2))+LINKS(A2;2)*7-7-REST("2.1."&RECHTS(A2;2);7)+B2*7);2) sollte aber passen. Habe aber wieder nicht getestet.
Gruß Werner
.. , - ...

Anzeige
nun noch das KW-Jahr
09.10.2013 01:26:31
Erich
Hi Werner,
da klemmt es noch an einer Stelle beim KW-Jahr: Es wird bestimmt als das Jahr, in den der Montag der KW liegt.
Maßgeblich ist aber der Donnerstag.
Ich habe hier darauf verzichtet, KW und Jahr zusammen in einer Zelle unterzubringen, ist übersichtlicher.
In D2 und D4:D11 steht im Prinzip deine Formel, in D3 habe ich "+3" ergänzt.
In Spalte F steht meine KW-Jahr-Formel.
Meine KW-Formel in Spalte G sollte man besser gleich wieder vergessen...
 ABCDEFGHI
1KW-JahrKWplusKWKW-Jahr1KW1KW-Jahr2KW2BegDatoder
22007152200712008131.12.200731.12.2007
32008152200912009129.12.200829.12.2008
4200915220095320095328.12.200928.12.2009
52010152201112011103.01.201103.01.2011
62011152201212012102.01.201202.01.2012
72012152201212013131.12.201231.12.2012
82013152201312014130.12.201330.12.2013
92014152201412015129.12.201429.12.2014
10201515220155320155328.12.201528.12.2015
112016152201712017102.01.201702.01.2017

Formeln der Tabelle
ZelleFormel
D2=JAHR(("4.1."&A2)+B2*7-7-REST("2.1."&A2;7)+C2*7)
E2=KALENDERWOCHE(("4.1."&A2)+B2*7-7-REST("2.1."&A2;7)+C2*7;21)
F2=JAHR(7*DM((7&1-A2)/7+B2+C2;)+180-REST(7*DM((7&1-A2)/7+B2+C2;)+175;7))
G2=DM((7*DM((7&1-A2)/7+B2+C2;)+177)/7-38,7;) - DM((4&1-JAHR(7*DM((7&1-A2)/7+B2+C2;)+180-REST(7*DM((7&1-A2)/7+B2+C2;)+175;7)))/7;)
H2=7*DM((7&1-A2)/7+B2;)+177+C2*7
I2=("4.1."&A2)+B2*7-7-REST("2.1."&A2;7)+C2*7
D3=JAHR(("4.1."&A3)+B3*7-7-REST("2.1."&A3;7)+C3*7+3)

Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich - Test - Test - Test - ... :-)

Anzeige
ZeitRechnung ist mE Interpetationsangelegenheit ..
09.10.2013 15:17:33
neopa
Hallo Erich,
... ich bin der Meinung, dass das Ergebnis meiner Formel zumindest nicht falsch ist aber Deine Interpretation auch richtig sein kann. Deine Rechnung geht davon aus, dass die angegebene KW in Spalte B abgelaufen ist und ich ging/geh davon aus, dass sie noch zur "Verfügung" steht. Damit ergibt sich z.B. in D2 mit meiner Formel aus der Addition von 52KW als Datum der 31.12.2007 und somit auch das KJ 2007. Analog in D3 und D7:D9.
Also müsste hier sich zunächst der Fragesteller festlegen, was er wie ermitteln will.
Gruß Werner
.. , - ...

Missverständnis
09.10.2013 17:48:38
Erich
Hi Werner,
da verstehen wir uns wohl miss.
Deine Erklärung "Deine Rechnung geht davon aus, dass die angegebene KW in Spalte B abgelaufen ist
und ich ging/geh davon aus, dass sie noch zur 'Verfügung' steht."
verstehe ich ehrlich gesagt gar nicht.
Unsere Formeln berechnen die Nummer der KW doch übereinstimmend - nach deiner Erklärung wäre
eine Differenz unm eine Woche denkbar.
Ich sehe das so:
Eine KW ist gegeben durch das Jahr, zu dem die Woche gehört, und eine KW-Nummer (1 bis 52 oder 53).
Eine Woche gehört zu dem Jahr, in dem mindestens 4 Tage der Woche liegen.
Aus KW-Jahr und KW lässt sich z.B. der Montag dieser KW als Datum berechnen.
Die KW 2008/01 beginnt am 31.12.2007,
die KW 2007/01 beginnt am 01.01.2007.
Folgte man deiner Berechnung, wäre die Ergebnisse für
2007/01 + 52 KW
2007/01 + 00 KW
identisch - nämlich 2007/01. Ich denke: Dat kann nich!
Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

Anzeige
... und Asche auf mein Haupt ...
10.10.2013 17:37:13
neopa
Hallo Erich,
... ich hab Deinen Beitrag gestern leider nur so "nebenher" angeschaut und mir offensichtlich nicht wirklich die Ausgangsfragestellung nochmal vor Augen gehalten. Ich hatte dann irgendwie nur das Kalender Jahr des Ergebnisdatums als maßgeblich betrachtet aber nicht das KW-Jahr. Tut mir leid, wenn ich dadurch nur unnötig Staub aufgewirbelt habe.
Hab jetzt allerdings auch keine Zeit mehr, mich Deines neuen Vorschlags anzunehmen, denn ich muss noch etwas schaffen und Morgen früh geht es dann ja schon ab Richtung Duisburg.
Ich freue mich schon jetzt auf unser Treffen.
Bis in Bälde dann.
Gruß Werner
.. , - ...

Anzeige
AW: nicht ganz
08.10.2013 15:18:36
Mekerde
Vielen Dank für die Hilfe, klappt super!

Kalenderwochen subtrahieren
08.10.2013 12:19:38
Erich
Hi Vorname,
vielleicht so - mit Hilfsdatum in Spalte C:
 ABCD
1JJ/KWabzgl. WoDatum altKWalt
213/444919.11.201212/47
304/01122.12.200303/52
405/01127.12.200404/53
506/01126.12.200505/52

Formeln der Tabelle
ZelleFormel
C2=7*DM((7&1-2000-LINKS(A2;2))/7+RECHTS(A2;2); )+177-7*B2
D2=RECHTS(JAHR(C2+3-REST(C2-2;7)); 2) & TEXT(DM((C2-(1&-JAHR(C2+3-REST(C2-2;7)))-REST(C2-2;7))/7;)+1;"\/00")


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
KW (44) und Jahr (2013) würde ich grundsätzlich in getrennten Zellen unterbringen.
Das erleichterte die Arbeit sehr.
Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich

Anzeige
Kalenderwochen subtrahieren
09.10.2013 18:02:17
Erich
Hi,
hier noch ein Vorschlag, aufbauend auf Werners:
 ABCDE
1KW-JahrKWplusKWKW-JahrKW
2200715220081
3200815220091
42009152200953

Formeln der Tabelle
ZelleFormel
D2=JAHR(("7.1."&A2)+(B2+C2-1)*7-REST("2.1."&A2;7))
E2=KALENDERWOCHE(("4.1."&A2)+(B2+C2-1)*7-REST("2.1."&A2;7); 21)

Rückmeldung wäre nett! - Grüße aus Kamp-Lintfort von Erich
Anzeige

76 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige