Maxima und Minima rausschmeissen

Bild

Betrifft: Maxima und Minima rausschmeissen
von: Bernhard Buchwald
Geschrieben am: 15.03.2005 15:19:49
Hallo Freunde!!!
Ich habe eine Tabelle mit mehreren gemessenen Werten. Nun will ich in jeder Spalte das MAximum und das Minimum entfernen, um die Daten zu glätten. Gibt es da eine Funktion, mit der ich mir das SUchen ersparen kann?
Ihr seid meine letzte Hoffnung. Ich weiß nicht mehr weiter.
Vielen Dank
Bernhard Buchwald

Bild

Betrifft: AW: Maxima und Minima rausschmeissen
von: th.heinrich
Geschrieben am: 15.03.2005 16:38:57
hallo Bernhard,
meinst Du das so?
Tabelle3
 AB
2114,33333333
2293
233 
Formeln der Tabelle
B21 : =MITTELWERT(A21:A25)
B22 : =SUMME(A21:A25)-MIN(A21:A25)-MAX(A21:A25)
 
Diagramm - Grafik - Excel Tabellen einfach im Web darstellen    Excel Jeanie HTML  3.0    Download  

gruss thomas
Bild

Betrifft: AW: Maxima und Minima rausschmeissen
von: Martin Beck
Geschrieben am: 15.03.2005 17:00:08
Hallo Bernhard,
angenommen, die Werte stehen in A1:A17. In eine leere Spalte, z.B. in D1 die Formel
=WENN(ODER(A1=MAX($A$1:$A$17);A1=MIN($A$1:$A$17));"";A1)
und dann bis D17 nach unten kopieren. Auf diese Daten kannst Du z.B. die Mittelwertfunktion anwenden. Achtung: wenn max/min mehrfach vorkommen, werden alle eliminiert.
Gruß
Martin Beck
Bild

Betrifft: AW: Maxima und Minima rausschmeissen
von: FP
Geschrieben am: 15.03.2005 20:54:28
Hallo Bernhard,
GESTUTZTMITTEL(Bereich;Prozent) sollte das gewünschte Ergebnis liefern
hier ein paar Beispiele, wie man Mittelwerte ermitteln kann
in den Spalten C bis L stehen die jeweils nicht berücksichtigten Werte
aller klar?
Tabelle1
 ABCDEFGHIJKL
19945,8400          
24645,72454  99      
31544,61464999999      
46536,2043          
5645,72454  99      
63945,5833649999      
79545,1667466799595999999
8744,00001         
99099,00003         
1024Anzahl:100         
1119           
1243Geomittel als Formel          
133836,2043          
1459           
1531           
Formeln der Tabelle
B1 : =MITTELWERT(A:A)
B2 : =(SUMME(A:A)-MIN(A:A)-MAX(A:A))/(ANZAHL(A:A)-2)
B3 : {=MITTELWERT(WENN((A1:A100>MIN(A1:A100))*(A1:A100<MAX(A1:A100));A1:A100))}
B4 : =GEOMITTEL(A:A)
B5 : =GESTUTZTMITTEL(A:A;2/ANZAHL(A:A))
B6 : =GESTUTZTMITTEL(A:A;(ZÄHLENWENN(A:A;MIN(A:A))+ZÄHLENWENN(A:A;MAX(A:A)))/ANZAHL(A:A))
C6 : =KKLEINSTE(A:A;2)
D6 : =MIN(A:A)
E6 : =MAX(A:A)
F6 : =KGRÖSSTE(A:A;2)
B7 : =GESTUTZTMITTEL(A:A;0,1)
C7 : =KKLEINSTE($A:$A;SPALTE(A1))
D7 : =KKLEINSTE($A:$A;SPALTE(B1))
E7 : =KKLEINSTE($A:$A;SPALTE(C1))
F7 : =KKLEINSTE($A:$A;SPALTE(D1))
G7 : =KKLEINSTE($A:$A;SPALTE(E1))
H7 : =KGRÖSSTE($A:$A;6-SPALTE(A1))
I7 : =KGRÖSSTE($A:$A;6-SPALTE(B1))
J7 : =KGRÖSSTE($A:$A;6-SPALTE(C1))
K7 : =KGRÖSSTE($A:$A;6-SPALTE(D1))
L7 : =KGRÖSSTE($A:$A;6-SPALTE(E1))
B8 : =MIN(A:A)
C8 : =ZÄHLENWENN(A:A;B8)
B9 : =MAX(A:A)
C9 : =ZÄHLENWENN(A:A;B9)
C10 : =ANZAHL(A:A)
B13 : =PRODUKT(A1:A100)^(1/ANZAHL(A:A))
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
 
Diagramm - Grafik - Excel Tabellen einfach im Web darstellen    Excel Jeanie HTML  3.0    Download  

Servus aus dem Salzkammergut
Franz
 Bild

Beiträge aus den Excel-Beispielen zum Thema "Maxima und Minima rausschmeissen"