Command Button einrichten zu Word Dokument

Forumthread: Command Button einrichten zu Word Dokument

14.11.2005 16:41:02

Markus

Hallo,
ich versuche über einen Command Button zu erreichen, dass bei Klick ein Word Dokument geöffnet wird. Ist dies möglich?
Vielen Dank für die Unterstützung!
Gruß Markus

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Command Button einrichten zu Word Dokument

14.11.2005 20:11:34

Heiko

Hallo Markus,
ja das geht.
In diesem Makro (auch mal hier im Forum gefunden) den Dateipfad und gegebenenfalls die Zeilen mit der WORD Version anpassen, dann das ganze einem Button zuweisen.
Geht sicherlich auch mit weniger Aufwand, aber hier kannst du dann das Worddokument aus EXCEL heraus sogar steuern.
Beispiel hier, nur öffnen.


Sub Word_open_File()
Application.ScreenUpdating = False
Dim myWord As Object
'Fehlerroutine für die Objectabfrage aktivieren
On Error Resume Next
' Abfragen einer bestehenden WORD-Instanz um wiederholtes starten zu verhindern
' 9  = Word 2000
' 10 = Word XP
' 11 = Word2003
Set myWord = GetObject(, "Word.Application.9")
'Set myWord = GetObject(,"Word.Application.10")
'Set myWord = GetObject(,"Word.Application.11")
If Err.Number <> 0 Then
'Fehlervariable leeren wenn Instanz noch nicht besteht
Err.Clear
'Zuweisung der Instanz
Set myWord = CreateObject("Word.Application.9")
' Set myWord = CreateObject("Word.Application.10")
' Set myWord = CreateObject("Word.Application.11")
'Instanz öffnen
myWord.Visible = True
Else
'Instanz besteht bereits
myWord.Activate
'Instanz in der Vordergrund bringen.
myWord.Visible = True
End If
'Hier muss der der Dateiname stehen der verwendet werden soll
'myWord.Application.Documents.Open "\\myser\test\test.doc"
myWord.Application.Documents.Open "C:\Copy\test.doc"
'Das aktive WordDokument drucken
'myWord.ActiveDocument.PrintOut
'Dokument schliessen ohne speichern
'myWord.ActiveDocument.Close savechanges:=False
'WORD-Instanz schliessen
'myWord.Application.Quit (True)
'Variable leeren
Set myWord = Nothing
Application.ScreenUpdating = True
End Sub

Gruß Heiko
PS: Rückmeldung wäre nett

AW: Command Button einrichten zu Word Dokument

14.11.2005 22:20:41

Nepumuk

Hallo Markus,
oder so:

' **********************************************************************
' Modul: Tabelle1 Typ: Element der Mappe(Sheet, Workbook, ...)
' **********************************************************************

Option Explicit

Private Declare Function GetShortPathName Lib "kernel32.dll" Alias "GetShortPathNameA" ( _
    ByVal lpszLongPath As String, _
    ByVal lpszShortPath As String, _
    ByVal cchBuffer As Long) As Long

Private Declare Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" ( _
    ByVal hwnd As Long, _
    ByVal lpOperation As String, _
    ByVal lpFile As String, _
    ByVal lpParameters As String, _
    ByVal lpDirectory As String, _
    ByVal nShowCmd As Long) As Long

Private Declare Function GetActiveWindow Lib "user32.dll" () As Long

Private Const MAX_PATH = 260&
Private Const SW_MAXIMIZE = 3&

Private Sub CommandButton1_Click()
    Dim strPath As String, strShortPath As String, strFile As String
    strFile = "Addin_Anleitung.doc"
    strPath = "D:\Eigene Dateien\Eigene Dokumente\"
    strShortPath = Space(MAX_PATH)
    GetShortPathName strPath & strFile, strShortPath, MAX_PATH
    strShortPath = Left$(strShortPath, InStr(1, strShortPath, vbNullChar) - 1)
    ShellExecute GetActiveWindow, "open", strShortPath, "", strPath, SW_MAXIMIZE
End Sub

Gruß
Nepumuk

AW: Command Button einrichten zu Word Dokument

15.11.2005 10:24:56

Rolf

Hallo Markus,
geht auch kurz


Sub open_WordFile()
Dim Shell32 As New Shell        'Verweis auf Shell32.dll setzen
Dim strFile$
strFile = "c:\datei.doc"
Shell32.Open strFile
End Sub

fG
Rolf

AW: Command Button einrichten zu Word Dokument

15.11.2005 21:50:22

Markus

Vielen Dank für Eure Hilfe!!!!
Gruß Markus

Geschlossen.

16.11.2005 07:22:33

Heiko

Beliebteste Forumthreads (12 Monate)

Command Button einrichten zu Word Dokument

Forumthread: Command Button einrichten zu Word Dokument

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Command Button einrichten zu Word Dokument

Forumthread: Command Button einrichten zu Word Dokument

5 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

5
Beiträge zum Forumthread

Beiträge zu diesem Forumthread