AW: Wie kann man Private Sub's ablaufen lassen?
03.07.2004 11:45:34
Melanie
Hallo Dieter,
vielleicht kann ich etwas Licht ins Dunkle bringen :-)
Es spielt gar keine Rolle, in welchen Modulen Prozeduren hinterlegt sind und ob sie Private oder Public sind ;-)
Es kommt nur darauf an, wie man sie aufruft!
In einer Arbeitsmappe seinen folgende Prozeduren:
' DieseArbeitsmappe
Private Sub Workbook_Open()
MsgBox "Workbook_Open wurde aufgerufen"
End Sub
' Tabelle1
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
MsgBox Target.Address
End Sub
' Modul1
Private Sub teste01()
MsgBox "
Private Sub teste01 wurde gestartet!"
End Sub
Sub ruf_teste01()
Call teste01
End Sub
Private Sub teste02(text As String, wert1 As Long, wert2 As Long)
MsgBox "
Private Sub teste02 wurde gestartet!" & Chr(10) & _
"Text: " & text & Chr(10) & _
"Wert1: " & wert1 & Chr(10) & _
"Wert2: " & wert2
End Sub
Sub ruf_teste02()
Call teste02("Übergebener Testtext", 12345, 98765)
End Sub
Aufgerufen werden alle diese Prozeduren aus Modul2 heraus:
' Modul2
Sub RufeMakros()
' Public Prozeduren
' nach Eingabe des Punktes werden globale Prozeduren des Moduls angezeigt
Modul1.ruf_teste01
Modul1.ruf_teste02
' Private Prozeduren
Application.Run "Modul1.teste01"
Application.Run "Modul1.teste02", "Melanie", 3, 12
Application.Run "DieseArbeitsmappe.Workbook_Open"
Application.Run "Tabelle1.Worksheet_SelectionChange", Range("A1")
End Sub
Die Ereignisprozeduren werden zwar aufgerufen und der hinterlegte Code ausgeführt,
dass Ereignis selbst wird aber nicht ausgeführt, z.B. beim Close-Ereignis, wird die Mappe nicht durch den manuellen Aufruf geschlossen.
--
Mit freundlichen Grüssen
Melanie Breden
- Microsoft MVP für Excel -
http://excel.codebooks.de (Das Excel-VBA Codebook)
#Excel-Auftragsprogrammierung#