kumulieren - Formel jeden Monat anpassen?

Forumthread: kumulieren - Formel jeden Monat anpassen?

Christiane

Hallo,
ich bräuchte bitte einmal Hilfe bzw. eine Vereinfachung, wenn es geht.
Ich habe folgendes Problem:
Es existiert in meinem neuen Job eine Tabelle die in etwa wie folgt aussieht:
1______________A_______________B_______C______D__________E__________F
2____________________________________________________________________
3_____________________________Jan______Feb____März________April_______Mai
4__________Materialkosten_______1000____1050___2000_________750_______1800
Nun existiert eine andere Arbeitsmappe, die eine Formel beinhaltet, in der Werte
z. B im März kumuliert werden =b4+c4+d4
Im April wird diese Arbeitsmappe kopiert und die Formel um +e4 ergänzt. Also
=b4+c4+d4+e4
Es gibt nicht nur Materialkosten, darunter kommt noch einer sehr große Menge anderer Kosten,
mit analogen Formeln.
Nun meine Frage:
Es ist sehr lästig und umfangreich, alle Zeilen mit diesen Formeln jeden Monat zu ergänzen bzw. abzuändern. Kann man dies irgendwie vereinfachen? Oder gibt es ein Tool, wie man Formeln schnell
ändern kann?
Schon im voraus lieben Danke für die Hilfe.

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Benutzer

AW: kumulieren - Formel jeden Monat anpassen?

30.05.2010 19:16:16

OttoH

Hallo Christiane,
hilft dir diese lösung vielleicht weiter?
Ich habe die Startzelle für die Kumulierung einfach fixiert und muss nun, wenn ein Monat hinzukommt, lediglich die Vorgängerzelle um eins nach rechts ziehen.

Tabelle1

	A	B	C	D	E	F	G
1
2		Januar	Februar	März	April	Mai
3	Kosten	1000	1050	2000	750	1800
4	kumuliert	1000	2050	4050	4800	6600
5
6

Formeln der Tabelle

B4 : =SUMME($B3:B3)
C4 : =SUMME($B3:C3)
D4 : =SUMME($B3:D3)
E4 : =SUMME($B3:E3)
F4 : =SUMME($B3:F3)

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
Gruß OttoH

BEREICH.VERSCHIEBEN()

30.05.2010 23:13:17

Jockel

hi Christiane, es geht auch (etwas) einfacher...
Details

	A	B	C	D	E	F	G
24							Sume bis
25		Jan	Feb	März	April	Mai	März
26	Materialkosten	1000	1050	2000	750	1800	4050

verwendete Formeln
Zelle	Formel	Bereich
G26	=SUMME(BEREICH.VERSCHIEBEN(B26;;;;MONAT($G$25&1)))

Tabellendarstellung in Foren Version 5.27

cu jörg eine rückmeldung wäre ganz reizend

AW: kumulieren - Formel jeden Monat anpassen?

30.05.2010 19:16:32

Hajo_Zi

Hallo Christiane,
Details

	A	B	C	D	E	F	G
24							Sume bis
25		Jan	Feb	März	April	Mai	April
26	Materialkosten	1000	1050	2000	750	1800	4800

verwendete Formeln
Zelle	Formel	Bereich
G26	=SUMME(INDIREKT("B" & ZEILE() &":" & ADRESSE(ZEILE();VERGLEICH(G25;A25:F25;0))))

Tabellendarstellung in Foren Version 5.27

AW: kumulieren - Formel jeden Monat anpassen?

30.05.2010 19:21:37

Christian

Hallo Christiane
in dem Tabellenblatt für die kummulierte Summe legst Du eine Hilfszelle mit dem Monatsnamen an. Dann kannst Du wie folgt arbeiten:
Tabelle2

	A	B
1	Mrz
2
3	Materialkosten	4050
4	Lohnkosten	23622

Formeln der Tabelle

Zelle	Formel
B3	=SUMME(BEREICH.VERSCHIEBEN(Tabelle1!$B$4;VERGLEICH(Tabelle2!$A3;Tabelle1!$A$4:A10;0)-1;;;VERGLEICH(Tabelle2!$A$1;Tabelle1!$B$3:$M$3;0)))

Tabelle1

	A	B	C	D	E	F	G	H
3		Jan	Feb	Mrz	Apr	Mai	Jun	Jul
4	Materialkosten	1000	1050	2000	750	1800
5	Lohnkosten	7854	7874	7894	7914	7934

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
MfG Christian

kleine Korrektur

30.05.2010 19:49:12

Christian

Hallo Christiane,
die Bezüge stimmten noch nicht ganz, so ist die Formel kopierbar:
Tabelle2

	A	B
1	Mai
2
3	Materialkosten	6600
4	Lohnkosten	39470

Formeln der Tabelle

Zelle	Formel
B3	=SUMME(BEREICH.VERSCHIEBEN(Tabelle1!$B$4;VERGLEICH($A3;Tabelle1!$A$4:$A$10;0)-1;;;VERGLEICH($A$1;Tabelle1!$B$3:$M$3;0)))

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
MfG Christian

AW: kumulieren - Formel jeden Monat anpassen?

30.05.2010 20:53:08

Christiane

Vielen Dank, ich werde versuchen das gleich nächste Woche umzusetzen.
Christiane

Infobox / Tutorial

Kumulieren in Excel: Formeln einfach anpassen

Schritt-für-Schritt-Anleitung
Häufige Fehler und Lösungen
Alternative Methoden
Praktische Beispiele
Tipps für Profis
FAQ: Häufige Fragen

Schritt-für-Schritt-Anleitung

Um die kumulierte Summe in Excel effizient zu gestalten, kannst Du folgende Schritte befolgen:

Tabelle erstellen: Beginne mit einer Excel-Tabelle, in der Du die Daten für die Monate eingibst.

Beispiel:

|         | Jan  | Feb  | Mär  | Apr  | Mai  |
|---------|------|------|------|------|------|
| Kosten  | 1000 | 1050 | 2000 | 750  | 1800 |

Formel für die kumulierte Summe: In der Zelle, in der die kumulierte Summe erscheinen soll, benutze die folgende Formel:
```
=SUMME($B$2:B2)
```
Diese Formel summiert alle Werte von Zelle B2 bis zur aktuellen Zelle.
Formel nach rechts ziehen: Wenn Du einen neuen Monat hinzufügst, ziehe einfach die untere rechte Ecke der Zelle nach rechts, um die Formel auf die nächsten Monate anzuwenden.
Ergänzen neuer Monate: Wenn ein neuer Monat hinzukommt, musst Du lediglich die letzte Zelle der kumulierten Summe um einen Monat erweitern, z.B. von =SUMME($B$2:C2) auf =SUMME($B$2:D2).

Häufige Fehler und Lösungen

Fehler: #BEZUG!: Dies geschieht oft, wenn Du versuchst, auf eine nicht existierende Zelle zuzugreifen. Überprüfe die Zellreferenzen in Deiner Formel.
Lösung: Relative und absolute Zellreferenzen: Stelle sicher, dass Du $-Zeichen für absolute Zellreferenzen verwendest, damit die Formel korrekt funktioniert, wenn Du sie nach rechts ziehst.
Fehler bei der Summierung: Wenn die kumulierte Summe nicht korrekt berechnet wird, überprüfe, ob Du die richtigen Zellen in der Formel referenzierst.

Alternative Methoden

BEREICH.VERSCHIEBEN: Eine alternative Methode zur Berechnung der kumulierten Summe ist die Verwendung von BEREICH.VERSCHIEBEN:
```
=SUMME(BEREICH.VERSCHIEBEN(A1;0;0;1;MONAT(HEUTE())))
```
Dies ermöglicht es Dir, die summierten Werte dynamisch basierend auf dem aktuellen Monat zu berechnen.
INDIREKT: Eine weitere Möglichkeit ist die Verwendung von INDIREKT, um auf dynamische Zellreferenzen zuzugreifen:
```
=SUMME(INDIREKT("B2:" & ADRESSE(2; MONAT(HEUTE()) + 1)))
```

Praktische Beispiele

Hier ist ein einfaches Beispiel, wie Du die kumulierte Summe in einer Tabelle einrichtest:

Tabelle1: Enthält die monatlichen Kosten.
Tabelle2: Enthält die Formeln zur Berechnung der kumulierten Summe.

In Tabelle1:

|        | Jan | Feb | Mär | Apr | Mai |
|--------|-----|-----|-----|-----|-----|
| Kosten | 1000| 1050| 2000| 750 | 1800|

In Tabelle2 kannst Du die kumulierte Summe mit der Formel =SUMME(Tabelle1!B2:B2) erstellen und diese nach rechts ziehen.

Tipps für Profis

Verwende benannte Bereiche: Wenn Du oft mit den gleichen Zellbereichen arbeitest, kannst Du diese benennen. Dies macht Deine Formeln einfacher und übersichtlicher.
Diagramme erstellen: Nutze die kumulierten Werte, um ein Excel-Diagramm zu erstellen, das die Entwicklung der Kosten über die Monate visualisiert.
Kombination von Funktionen: Experimentiere mit der Kombination von WENN-Funktionen, um bestimmte Bedingungen in der Kalkulation zu berücksichtigen:
```
=WENN(B2>1000;SUMME(BEREICH.VERSCHIEBEN(B2;0;0;1;MONAT(HEUTE())));"Keine Daten")
```

FAQ: Häufige Fragen

1. Was heisst kumuliert?
Kumuliert bedeutet, dass Werte summiert werden, um einen Gesamtwert über einen bestimmten Zeitraum anzuzeigen.

2. Wie kann ich die kumulierte Summe für verschiedene Kategorien erstellen?
Du kannst für jede Kategorie eine separate Tabelle oder Spalte erstellen und die Formeln entsprechend anpassen.

3. Unterstützen alle Excel-Versionen diese Funktionen?
Ja, die beschriebenen Funktionen sind in den meisten modernen Excel-Versionen verfügbar.

4. Wie kann ich sicherstellen, dass meine Formeln immer aktuell sind?
Verwende dynamische Zellreferenzen und halte Deine Datenbank regelmäßig aktualisiert, um sicherzustellen, dass die kumulierten Werte korrekt sind.

Beliebteste Forumthreads (12 Monate)

kumulieren - Formel jeden Monat anpassen?

Forumthread: kumulieren - Formel jeden Monat anpassen?

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Infobox / Tutorial

Kumulieren in Excel: Formeln einfach anpassen

Schritt-für-Schritt-Anleitung

Häufige Fehler und Lösungen

Alternative Methoden

Praktische Beispiele

Tipps für Profis

FAQ: Häufige Fragen

Beliebteste Forumthreads (12 Monate)

kumulieren - Formel jeden Monat anpassen?

Forumthread: kumulieren - Formel jeden Monat anpassen?

6 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Infobox / Tutorial

Kumulieren in Excel: Formeln einfach anpassen

Schritt-für-Schritt-Anleitung

Häufige Fehler und Lösungen

Alternative Methoden

Praktische Beispiele

Tipps für Profis

FAQ: Häufige Fragen

Beliebteste Forumthreads (12 Monate)

6
Beiträge zum Forumthread

Beiträge zu diesem Forumthread