Live-Forum - Die aktuellen Beiträge
Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
796to800
796to800
Aktuelles Verzeichnis
Verzeichnis Index
Verzeichnis Index
Übersicht Verzeichnisse
Inhaltsverzeichnis

Teilergebnis mit summe wenn

Teilergebnis mit summe wenn
05.09.2006 08:02:24
chris
Hallo und wunderschönen guten morgen Excelprofis,
habe heute eine frage zu Formeln und hoffe wiedermal auf eure Hilfe.
Habe eine teilergebnis formel.
=TEILERGEBNIS(9;$R$3:$R$10000)
diese formel sollte zusätzlich noch mit einer wenn funktion verschachtelt werden ich weiß aber nicht ob das funktioniert ?
Wäre super wenn ihr mir da weiterhelfen könntet.
Die summe wenn formel sollte in etwa so sein.
es werden ja durch teilergebniss nur die Felder summiert die nch angezeigt werden.
es werden jetzt also beispiel in Spalte T werte angezeigt zwischen 1 und 9
es sollen jetzt als beispiel nur die summiert werden die angezeigt werden und die zahl in Spalte T eine 3 ist.
Ich hoffe ich habe mich verständlich ausgedrückt.
Schon im vorraus vielen Dank gruß Christian

13
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Teilergebnis mit summe wenn
05.09.2006 08:28:42
heikoS
Hallo Christian,
das geht so:
=summenprodukt(teilergebnis(3;indirekt("t"&zeile(3:1000)))*(t3:t1000=3)*r3:r1000)
Klappt´s?
Gruß Heiko
AW: Teilergebnis mit summe wenn
05.09.2006 08:34:14
chris
Hallo heiko,
klappt wunderbar.
Muss mir jetzt die Formel mal genauer anschauen das ich sie auch verstehe.
Aber an dich vielen dank und schönen Tag !!
Bitte! Danke für Deine Rückmeldung! mT
05.09.2006 08:40:12
heikoS
Hallo Chris,
falls das mit dem verstehen nicht klappt, melde Dich einfach noch mal.
Gruß Heiko
AW: Bitte! Danke für Deine Rückmeldung! mT
05.09.2006 09:23:59
chris
Hallo Heiko,
danke für dein Angebot.
Wenn es dir nicht zu viel Arbeit macht wäre super wenn du sie mir kurz erklären könntest.
Danke
Erläuterung
05.09.2006 11:05:30
heikoS
Hallo Chris,
ich habe mir ein verkürztes Beispiel gebastelt, damit die Formeln, bzw. deren Ergebnisse, auch angezeigt werden können. Am besten baust Du es kurz nach; Bereich R5:T20.
Spalte:
R S T
1 aa 1
2 b 2
3 aa 3
4 b 5
5 aa 4
6 aa 7
78 aa 5
32 b 3
3 aa 3
52 aa 3
2 aa 2
32 aa 5
2 aa 4
2 aa 1
2 aa 3
2 aa 5
Jetzt wird Spalte S nach "aa" gefiltert.
Die Formel =SUMMENPRODUKT(TEILERGEBNIS(3;INDIREKT("T"&ZEILE(5:20)))*(T5:T20=3)*R5:R20) liefert als Ergenis 60.
Man muß die Formel in ihre Bestandteile zerlegen, um zu verstehen, was da eigentlich multipliziert wird.
TEILERGEBNIS(3;INDIREKT("T"&ZEILE(5:20)))
liefert als Ergebnis {1;0;1;0;1;1;1;0;1;1;1;1;1;1;1;1}, d.h. ist die angesprochene Zelle eingeblendet, wird eine 1 ermittelt, sonst 0.
(T5:T20=3)
gleicht ab, ob in den Zellen der Wert 3 steht und liefert daher als Ergebnis: {FALSCH;FALSCH;WAHR;FALSCH;FALSCH;FALSCH;FALSCH;WAHR;WAHR;WAHR;FALSCH;FALSCH;FALSCH;FALSCH;WAHR;FALSCH}
Werden diese beiden Formelergebnisse nun multipliziert, ergibt sich folgendes Zwischenergebnis: {0;0;1;0;0;0;0;0;1;1;0;0;0;0;1;0} D.h. nur die Werte aus der 3., 9., 10. und vorletzten Zelle ensprechen unseren beiden Kriterien
a. Zeile ist eingeblendet und
b. eine 3 in T
Daher die Einsen in obigem Ergebnis.
R5:R20
liefert unsere Daten aus dem Bereich {1;2;3;4;5;6;78;32;3;52;2;32;2;2;2;2}
Werden diese beiden Teilergebnisse nun multipliziert, erhalten wir folgendes Ergebnis: {0;0;3;0;0;0;0;0;3;52;0;0;0;0;2;0}. In Summe ergibt das 60.
So einfach kann´s sein. ;-)
Kurz gesagt, werden im ersten Teil der Formel Wahrheitswerte ermittelt, um dann die dazu passenden Werte aus der Spalte R addieren zu können.
Ist´s klar geworden?
Gruß Heiko
Anzeige
AW: Erläuterung
05.09.2006 16:11:44
chris
Boa Heiko vielen Dank ! freu mich das du mir weitergeholfen hast. Danke und schönen Tag !
Bitte, gern geschehen! oT
05.09.2006 17:19:38
heikoS
noch eine zusatzfrage
06.09.2006 13:18:03
chris
Hallo Heiko, habe doch noch eine frage zusätzlich der letzten.
und zwar werden ja die werte multipliziert.Also die 1,0,1,1,0,0 usw.. und die wahrheitswerte wahr,falsch,wahr, wahr usw...
jetzt habe ich versucht die formel so umzubauen wie sie im editor funktioniert da werden ja auch die matricen multipliziert zumindest habe ich es so verstanden.Also habe ich die * zeichen entfernt und aufgeteilt jede einzelne rechnung in einen matrix bekomme aber als ergebniss 0 angezeigt.
Die formel würde so aussehen.
Nur warum funktioniert sie so nicht ?
=SUMMENPRODUKT(TEILERGEBNIS(3;INDIREKT("T"&ZEILE(1:16)));T1:T16=3;R1:R16)
Danke Heiko
Anzeige
AW: noch eine zusatzfrage
08.09.2006 09:44:25
heikoS
Hallo Chris,
sorry, ich war zwei Tage auf Reisen und hatte dort nur eine dünne Leitung auf der das sonstige Arbeiten schon keine Freude war, daher war ich nicht auf herber.de.
Zu Deiner Frage: Dein Ansatz ist richtig. summenprodukt() multipliziert einzelne Matrizen. Allerdings müssen das (in der Notation mit den Semikola) dann auch Zahlen sein. Enthält eine Matrix keine Zahlen, sondern Texte (also auch WAHR und/oder FALSCH) so liefert die Funktion einen Fehler. Man kann sich sehr gut damit behelfen, die Texte in Zahlen umzuwandeln. Ich mache das am liebsten mit dem Doppelminus, also so: =summenprodukt(--(matrix1);--(matrix2)).
Machst Du das nicht, solltest Du die Matrizen explizit ausmultiplizieren lassen, d.h. die Funktion so aufbauen:
=summenprodukt((matrix1)*(matrix2)).
Zu summenprodukt() im allgemeinen und zum Doppelminus im speziellen ist der Inhalt des folgende Links genial: http://www.xldynamic.com/source/xld.SUMPRODUCT.html
Gruß Heiko
Anzeige
AW: noch eine zusatzfrage
08.09.2006 20:09:29
chris
Auch hierfür danke Heiko :)
AW: Erläuterung frage noch dazu
06.09.2006 07:07:48
chris
Hallo Heiko,
falls du diesen Thread noch lesen solltest hätte ich noch eine frage.
Nur wenn es möglich ist zu erklären.
Und zwar warum erbigt '=TEILERGEBNIS(3;INDIREKT("T"&ZEILE(1:16)))
diese Formel 1 und 0 das versteh ich noch nicht.Oder ist das einfach so und mann kann es nicht erklären.
Danke dir !
gruß Christian
AW: Erläuterung frage noch dazu
08.09.2006 09:54:03
heikoS
Hallo Chris,
Gegenfrage: Was macht denn =teilergebnis(3;...)?
Das ist doch nichts anderes als anzahl2() bei gefilterten Daten, oder?
Und was macht anzahl2()? Antwort aus der F1-Hilfe: "Berechnet, wie viele Werte eine Liste von Argumenten enthält. Verwenden Sie ANZAHL2, wenn Sie wissen möchten, wie viele zu einem Bereich oder einer Matrix gehörende Zellen Daten enthalten."
Ist es auf diese Weise klar geworden?
;-)
Gruß Heiko
Anzeige
AW: Erläuterung frage noch dazu
08.09.2006 20:07:48
chris
ja bischen klarer:)
Danke Heiko und schönes WE

306 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige