Microsoft Excel

Herbers Excel/VBA-Archiv

KGRÖSSTE aus zwei Spalten | Herbers Excel-Forum


Betrifft: KGRÖSSTE aus zwei Spalten von: Andre´
Geschrieben am: 25.01.2012 08:20:48

Hallo alle zusammen,

In der angehängen Datei: https://www.herber.de/bbs/user/78585.xls

soll erst in Spalte B der größte Wert gesucht werden Im Bsp. sind es die Zellen B2 und B5
und dann in die Spalte C nach dem größten Wert.

Auch hier kann es vorkommen, dass die Werte in Spalte B und C gleich sein können.

In meinem Bsp.müsste das Formelergebnis in den Zellen wie folg aussehen

J2 = A
J3 = D
J4 = B
J5 = C

Ich hoffe mir kann jemand helfen.

Vielen Dank im Voraus!

MFG Andre

  

Betrifft: AW: KGRÖSSTE aus zwei Spalten von: Josef Ehrensberger
Geschrieben am: 25.01.2012 08:32:51


Hallo Andre,

so?

Rang

 ABCDEFGHIJK
1TextWert1Wert2      Text 
2A617      A 
3B418      D 
4C020      B 
5D616      C 
6           
7           

Formeln der Tabelle
ZelleFormel
J2{=INDEX($A$2:$A$5;VERGLEICH(KGRÖSSTE((($B$2:$B$5*10^6)-ZEILE($2:$5)/10^3)+(($C$2:$C$5*10^3)-ZEILE($2:$5)/10^3); ZEILE(A1)); (($B$2:$B$5*10^6)-ZEILE($2:$5)/10^3)+(($C$2:$C$5*10^3)-ZEILE($2:$5)/10^3); 0))}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4






« Gruß Sepp »



  

Betrifft: AW: KGRÖSSTE aus zwei Spalten von: Andre´
Geschrieben am: 25.01.2012 09:11:07

Hallo Sepp,

vielen Dank für die schnelle Antwort, funktioniert wie gewünscht und auch noch ohne Hilfsspalten :-)))

MFG Andre


  

Betrifft: AW: KGRÖSSTE aus drei Spalten von: Andre´
Geschrieben am: 25.01.2012 12:29:50

Hallo Sepp,
geht das auch mit 3 Spalten?

Mein Versuch in Spalte K bringt nicht das richtige Ergebnis.

Rang

 ABCDEFGHIJK
1TextWert1Wert2Wert3   Platz Rang aus Wert1 und Wert2Rang aus Wert1, Wert2 und Wert 3
2A6172   1 BD
3B6183   2 AB
4C641   3 DA
5D6175   4 CC

Formeln der Tabelle
ZelleFormel
J2{=INDEX($A$2:$A$5;VERGLEICH(KGRÖSSTE((($B$2:$B$5*10^6)-ZEILE($2:$5)/10^3)+(($C$2:$C$5*10^3)-ZEILE($2:$5)/10^3); ZEILE(A1)); (($B$2:$B$5*10^6)-ZEILE($2:$5)/10^3)+(($C$2:$C$5*10^3)-ZEILE($2:$5)/10^3); 0))}
K2{=INDEX($A$2:$A$5;VERGLEICH(KGRÖSSTE((($B$2:$B$5*10^6)-ZEILE($2:$5)/10^3)+(($C$2:$C$5*10^3)-ZEILE($2:$5)/10^3)+(($D$2:$D$5*10^3)-ZEILE($2:$5)/10^3); ZEILE(A1)); (($B$2:$B$5*10^6)-ZEILE($2:$5)/10^3)+(($C$2:$C$5*10^3)-ZEILE($2:$5)/10^3)+(($D$2:$D$5*10^3)-ZEILE($2:$5)/10^3); 0))}
J3{=INDEX($A$2:$A$5;VERGLEICH(KGRÖSSTE((($B$2:$B$5*10^6)-ZEILE($2:$5)/10^3)+(($C$2:$C$5*10^3)-ZEILE($2:$5)/10^3); ZEILE(A2)); (($B$2:$B$5*10^6)-ZEILE($2:$5)/10^3)+(($C$2:$C$5*10^3)-ZEILE($2:$5)/10^3); 0))}
K3{=INDEX($A$2:$A$5;VERGLEICH(KGRÖSSTE((($B$2:$B$5*10^6)-ZEILE($2:$5)/10^3)+(($C$2:$C$5*10^3)-ZEILE($2:$5)/10^3)+(($D$2:$D$5*10^3)-ZEILE($2:$5)/10^3); ZEILE(A2)); (($B$2:$B$5*10^6)-ZEILE($2:$5)/10^3)+(($C$2:$C$5*10^3)-ZEILE($2:$5)/10^3)+(($D$2:$D$5*10^3)-ZEILE($2:$5)/10^3); 0))}
J4{=INDEX($A$2:$A$5;VERGLEICH(KGRÖSSTE((($B$2:$B$5*10^6)-ZEILE($2:$5)/10^3)+(($C$2:$C$5*10^3)-ZEILE($2:$5)/10^3); ZEILE(A3)); (($B$2:$B$5*10^6)-ZEILE($2:$5)/10^3)+(($C$2:$C$5*10^3)-ZEILE($2:$5)/10^3); 0))}
K4{=INDEX($A$2:$A$5;VERGLEICH(KGRÖSSTE((($B$2:$B$5*10^6)-ZEILE($2:$5)/10^3)+(($C$2:$C$5*10^3)-ZEILE($2:$5)/10^3)+(($D$2:$D$5*10^3)-ZEILE($2:$5)/10^3); ZEILE(A3)); (($B$2:$B$5*10^6)-ZEILE($2:$5)/10^3)+(($C$2:$C$5*10^3)-ZEILE($2:$5)/10^3)+(($D$2:$D$5*10^3)-ZEILE($2:$5)/10^3); 0))}
J5{=INDEX($A$2:$A$5;VERGLEICH(KGRÖSSTE((($B$2:$B$5*10^6)-ZEILE($2:$5)/10^3)+(($C$2:$C$5*10^3)-ZEILE($2:$5)/10^3); ZEILE(A4)); (($B$2:$B$5*10^6)-ZEILE($2:$5)/10^3)+(($C$2:$C$5*10^3)-ZEILE($2:$5)/10^3); 0))}
K5{=INDEX($A$2:$A$5;VERGLEICH(KGRÖSSTE((($B$2:$B$5*10^6)-ZEILE($2:$5)/10^3)+(($C$2:$C$5*10^3)-ZEILE($2:$5)/10^3)+(($D$2:$D$5*10^3)-ZEILE($2:$5)/10^3); ZEILE(A4)); (($B$2:$B$5*10^6)-ZEILE($2:$5)/10^3)+(($C$2:$C$5*10^3)-ZEILE($2:$5)/10^3)+(($D$2:$D$5*10^3)-ZEILE($2:$5)/10^3); 0))}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4



Gibt es dafür auch eine Lösung?

MFG Andre


  

Betrifft: AW: KGRÖSSTE aus drei Spalten von: Josef Ehrensberger
Geschrieben am: 25.01.2012 18:20:31


Hallo Andre,

so?

Rang

 ABCDEFGHIJK
1TextWert1Wert2Wert3     Rang 1+2Rang1+2+3
2A6172    1BB
3B6183    2AD
4C641    3DA
5D6175    4CC

Formeln der Tabelle
ZelleFormel
J2{=INDEX($A$2:$A$5;VERGLEICH(KGRÖSSTE((($B$2:$B$5*10^6)+($C$2:$C$5*10^3))-ZEILE($2:$5)/10^3;ZEILE(A1)); (($B$2:$B$5*10^6)+($C$2:$C$5*10^3))-ZEILE($2:$5)/10^3;0))}
K2{=INDEX($A$2:$A$5;VERGLEICH(KGRÖSSTE((($B$2:$B$5*10^9)+($C$2:$C$5*10^6)+($D$2:$D$5*10^3))-ZEILE($2:$5)/10^3;ZEILE(A1)); (($B$2:$B$5*10^9)+($C$2:$C$5*10^6)+($D$2:$D$5*10^3))-ZEILE($2:$5)/10^3;0))}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4






« Gruß Sepp »



  

Betrifft: AW: KGRÖSSTE aus drei Spalten von: Andre´
Geschrieben am: 25.01.2012 18:34:40

Hallo Sepp,
deine Formel ist kürzer (als mein Ansatz) und funktioniert auch.

Vielen Dank nochmals für die Meldung.

MFG Andre


  

Betrifft: AW: KGRÖSSTE aus drei Spalten aber.. von: Andre´
Geschrieben am: 25.01.2012 20:30:55

Hallo Sepp,

warum kommt bei nachfolgender Darstellung nicht das richtige Ergebnis heraus?








Gibt es dafür eine Lösung?


MFG Andre


  

Betrifft: AW: KGRÖSSTE aus drei Spalten aber.. von: Josef Ehrensberger
Geschrieben am: 25.01.2012 21:21:37


Hallo Andre,

wenn die Werte zu weit auseinander liegen, muss man die Faktoren anders wählen.

Rang

 ABCDEFGHIJK
1TextWert1Wert2Wert3     Rang 1+2Rang1+2+3
2A5103    1AA
3B230003    2CC
4C5102    3DD
5D4111    4BB

Formeln der Tabelle
ZelleFormel
J2{=INDEX($A$2:$A$5;VERGLEICH(KGRÖSSTE(($B$2:$B$5+($C$2:$C$5*10^-9))-ZEILE($2:$5)*10^-12;ZEILE(A1)); ($B$2:$B$5+($C$2:$C$5*10^-9))-ZEILE($2:$5)*10^-12;0))}
K2{=INDEX($A$2:$A$5;VERGLEICH(KGRÖSSTE(($B$2:$B$5+($C$2:$C$5*10^-9)+($D$2:$D$5*10^-12))-ZEILE($2:$5)*10^-15;ZEILE(A1)); ($B$2:$B$5+($C$2:$C$5*10^-9)+($D$2:$D$5*10^-12))-ZEILE($2:$5)*10^-15;0))}
Enthält Matrixformel:
Umrandende
{ } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4






« Gruß Sepp »



  

Betrifft: Vielen, vielen DANK! für die Info/ Lösung oT. von: Andre´
Geschrieben am: 25.01.2012 21:52:43




  

Betrifft: habs gelöst von: Andre´
Geschrieben am: 25.01.2012 18:27:31



K2={INDEX($A$2:$A$5;VERGLEICH(KGRÖSSTE((($B$2:$B$5*10^6)-ZEILE($2:$5)/10^3)+(($C$2:$C$5*10^3)-ZEILE($2:$5)/10^3)+(($D$2:$D$5*10^3)-ZEILE($2:$5)/10^3); ZEILE(A1));(($B$2:$B$5*10^6)-ZEILE($2:$5)/10^3)+(($C$2:$C$5*10^3)-ZEILE($2:$5)/10^3)+(($D$2:$D$5*10^3)-ZEILE($2:$5)/10^3);0))}


  

Betrifft: kleiner Fehler von mir...so wäre von: Andre´
Geschrieben am: 25.01.2012 19:19:35

es richtig:

K2 = {=INDEX($A$2:$A$5;VERGLEICH(KGRÖSSTE((($B$2:$B$5*10^9)-ZEILE($2:$5)/10^3)+(($C$2:$C$5*10^6)-ZEILE($2:$5)/10^3)+(($D$2:$D$5*10^3)-ZEILE($2:$5)/10^3); ZEILE(A1));(($B$2:$B$5*10^9)-ZEILE($2:$5)/10^3)+(($C$2:$C$5*10^6)-ZEILE($2:$5)/10^3)+(($D$2:$D$5*10^3)-ZEILE($2:$5)/10^3);0))}


Beiträge aus den Excel-Beispielen zum Thema "KGRÖSSTE aus zwei Spalten"