Live-Forum - Die aktuellen Beiträge
Datum
Titel
26.09.2025 22:18:24
Liste mit Links - tricky
26.09.2025 18:34:36
Welches Datum gibt mein M-Code aus?
26.09.2025 10:29:46
Wert aus einer Zelle bei jeder Eingabe in neue Zelle
26.09.2025 08:51:00
Teilinhalt einer Zelle vergleichen
Keine passende Antwort im Forumarchiv gefunden?
Stelle deine Frage im Live-Forum
Anzeige
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Vorheriger Thread
Vorheriger Thread
Rückwärts Blättern
1516to1520
1516to1520
Aktuelles Verzeichnis
Verzeichnis Übersicht
Verzeichnis Übersicht
Übersicht Verzeichnisse
Nächster Thread
Nächster Thread
Vorwärts blättern
Inhaltsverzeichnis

Anzahl unterschiedlicher Texte

Forumthread: Anzahl unterschiedlicher Texte

Anzahl unterschiedlicher Texte
05.10.2016 07:13:27
Georg
Hallo,
wahrscheinlich einfach für Euch - ich finde den Dreh nicht:
Ich habe eine Tabelle mit folgenden Spalten:
A : Datum
B : irgendein Text
Nun will ich die Anzahl unterschiedlicher Texte zu einem Datum herausfinden. Mit Pivot (das ich sehr viel nutze) kriege ich es nicht hin.
Hoffe, jemand kennt eine Lösung.
Danke !
Georg
Anzeige

17
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
Anzahl unterschiedlicher Texte pro Datum
05.10.2016 07:25:26
WF
Hi,
das auszuwertende Datum steht in C1.
Die Anzahl unterschiedlicher Texte ist:
=SUMMENPRODUKT((A1:A99=C1)/ZÄHLENWENN(B1:B99;B1:B99&""))
Salut WF
AW: Anzahl unterschiedlicher Texte pro Datum
05.10.2016 07:58:16
Georg
supi, funzt - danke :)
AW: hmm, wie das? ...
05.10.2016 08:12:59
...
Hallo Georg,
... ich kann das so nicht nachvollziehen.
Die Lösungsformel von WF steht in D1:D2 meine in E4:E5:
 ABCD
128.09.2016Text_128.09.20164,366666667
228.09.2016Text_104.10.20161,633333333
328.09.2016Text_2  
428.09.2016Text_228.09.20166
528.09.2016Text_204.10.20163
6    
704.10.2016Text_5  
804.10.2016Text_5  
904.10.2016Text_6  
1004.10.2016Text_5  
11    
1228.09.2016Text_4  
1304.10.2016Text_1  
1404.10.2016Text_5  
15    
1628.09.2016Text_5  
1728.09.2016Text_6  
1828.09.2016Text_7  
19    

Formeln der Tabelle
ZelleFormel
D1=SUMMENPRODUKT((A$1:A$99=C1)/ZÄHLENWENN(B$1:B$99;B$1:B$99&""))
D2=SUMMENPRODUKT((A$1:A$99=C2)/ZÄHLENWENN(B$1:B$99;B$1:B$99&""))
C4=C1
D4{=SUMME(N(HÄUFIGKEIT(WENN(A$1:A$99=C4;VERGLEICH(B$1:B$99&"";B$1:B$99&"";)); ZEILE(A$1:A$99))>0))}
C5=C2
D5{=SUMME(N(HÄUFIGKEIT(WENN(A$1:A$99=C5;VERGLEICH(B$1:B$99&"";B$1:B$99&"";)); ZEILE(A$1:A$99))>0))}
Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Werner
.. , - ...
Anzeige
na ja: bei gleichen Texten in verschiedenen Daten
05.10.2016 08:56:05
WF
.
AW: diese Deine Aussage verstehe ich nicht ...
05.10.2016 09:11:51
...
Hallo WF,
... gesucht war doch: "...die Anzahl unterschiedlicher Texte zu einem Datum..." und genau das macht der von mir dargestellte Formelvorschlag, den wenn ich mich richtig erinnere, in dieser (oder ähnlicher Form) mal Sepp Burch einbrachte.
Dagegen ergibt Dein hier eingestellter Formelvorschlag kein ganzzahliges Ergebnis, was nun ja wirklich nicht gesucht sein kann.
Oder was meinst Du mit Deiner letzten Betreffzeile?
Gruß Werner
.. , - ...
Anzeige
das tritt nur auf, wenn ein gleicher Text
05.10.2016 09:24:50
WF
bei verschiedenen Datümern auftaucht.
Das ist dann aber einfacher zu lösen durch:
=ANZAHL(1/((VERGLEICH(A1:A99&B1:B99;C1&B1:B99;0)=ZEILE(1:99))))+1
WF
AW: auch so nicht, denn ...
05.10.2016 09:36:29
...
Hallo nochmal,
... aber zunächst für Mitleser sollten wir angeben, dass Dein neuer Formelvorschlag als Matrixformel einzugeben ist.
Diese Formel ergibt aber z.B. in meinem Beispieldatensatz für den Wert in C1 ein inkorrektes Ergebnis:
 ABCDE
1DatumText28.09.20163,3666666674
228.09.2016Text_104.10.20161,6333333333
328.09.2016Text_2   
428.09.2016Text_228.09.20165 
528.09.2016Text_204.10.20163 
6     
704.10.2016Text_5   
804.10.2016Text_5   
904.10.2016Text_6   
1004.10.2016Text_5   
11     
1228.09.2016Text_4   
1304.10.2016Text_1   
1404.10.2016Text_5   
15     
1628.09.2016Text_5   
1728.09.2016Text_6   
1828.09.2016Text_1   
19     

Formeln der Tabelle
ZelleFormel
D1=SUMMENPRODUKT((A$1:A$99=C1)/ZÄHLENWENN(B$1:B$99;B$1:B$99&""))
E1{=ANZAHL(1/((VERGLEICH(A$1:A$99&B$1:B$99;C1&B$1:B$99;0)=ZEILE(A$1:A$99))))+1}
D4{=SUMME(N(HÄUFIGKEIT(WENN(A$1:A$99=C4;VERGLEICH(B$1:B$99&"";B$1:B$99&"";)); ZEILE(A$1:A$99))>0))}
Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Werner
.. , - ...
Anzeige
stimmt: es muss andersrum ohne +1 sein
05.10.2016 10:06:40
WF
{=ANZAHL(1/((VERGLEICH(C1&B1:B99;A1:A99&B1:B99;0)=ZEILE(X1:X99))))}
WF
haben wir ja schon als Nr. 334
05.10.2016 10:30:45
WF
http://www.excelformeln.de/formeln.html?welcher=334
daraus:
=SUMMENPRODUKT((VERGLEICH(A1:A99&B1:B99;A1:A99&B1:B99;0)=ZEILE(1:99)*(A1:A99=C1))*1)
meine Anzahl werde ich dazupacken.
WF
Anzeige
AW: aber bitte nicht mit ZEILE(X1:X99) ...
05.10.2016 10:46:51
...
Hallo WF,
... denn die Spalte X könnte gelöscht werden und dann sitzt man auf dem trockenen.
Man sollte für die Zeilennummermatrix grundsätzlich immer eine Spalte nutzen, die nicht aus Versehen gelöscht werden kann, ohne die Auswirkung offensichtlich zu sehen. Hier also Spalte A oder B, weill wenn diese gelöscht wird steht die Aufgabe auch nicht mehr an.
Somit: {=ANZAHL(1/((VERGLEICH(C1&B$1:B$99;A$1:A$99&B$1:B$99;0)=ZEILE(A$1:A$99))))}
Und in {}-freier Version dann einfach so:
=ANZAHL(INDEX(1/((VERGLEICH(C1&B$1:B$99;A$1:A$99&B$1:B$99;0)=ZEILE(A$1:A$99)));))
Gruß Werner
.. , - ...
Anzeige
extra mit ZEILE(X1:X99) ...
05.10.2016 11:09:40
WF
Hi,
damit die nicht gelöscht wir, gehe ich doch soweit nach rechts.
Spalte A wird eher versehentlich gelöscht.
Und das Wichtigste: ein nicht versierter User, der bei uns die Formel findet, denkt (Rückfragen gab's genug), dass Zeile(A1:A99) irgendwas mit dem Inhalt der Zellen zu tun hat und nicht nur ein Zähler ist.
WF
Anzeige
AW: sehe ich anders ...
05.10.2016 11:20:54
...
Hallo,
... wenn Spalte A oder Spalte B aus Versehen gelöscht wird, wird auch ein DAU merken, das er etwas falsch gemacht hat. Er wird es aber gar nicht merken, wenn er er aus Versehen Spalte X löscht, sondern sich bestenfalls fragen, warum rechnet die Formel nicht mehr richtig.
Welche wahre Bedeutung der Formelteil ZEILE(A1:A99) hat und welche nicht, kann und sollte man mE sowieso kurz erläutern.
Gruß Werner
.. , - ...
Anzeige
sicher nicht
05.10.2016 11:29:55
WF
ZEILE(... kommt bei uns in ca. 250 Beiträgen vor und diese werden wir nicht mit 250 Erläuterungen zumüllen.
WF
AW: wenn Du meinst, ist ja Deine Entscheidung owT
05.10.2016 11:35:44
...
Gruß Werner
.. , - ...
Hiermit hättet ihr das Problem gar nicht erst, ...
05.10.2016 16:06:57
Luc:-?
…Folks: ;-]
{=ANZAHL2(VSplit(VJoin(WENN(A$1:A$18=C1;B$1:B$18;"");;-1)))}
🙈 🙉 🙊 Gruß, Luc :-?
Besser informiert mit …
Anzeige
AW: Anzahl unterschiedlicher Texte pro Datum
05.10.2016 16:28:43
Daniel
Hi
besser wahrscheinlich so:
=SUMMENPRODUKT((A1:A99=C1)/ZÄHLENWENNS(A1:A99;A1:A99&"";B1:B99;B1:B99&"")) dann werden Texte, die nicht nur beim gesuchten, sondern auch an einem anderen Datum vorkommen, nicht mitgezählt.
Gruß Daniel
AW: geht auch in Kombination mit PIVOTauswert. ...
05.10.2016 09:18:28
...
Hallo Georg,
... jedenfalls, so wie ich Deine Aufgabenstellung interpretiert habe.
Die Formel in I2 einfach nach unten kopieren. Die Pivotauswertung (unten in Spalte G:H) beruht darauf, dass Datum und Text in das Zeilenbeschriftungsfeld gezogen werden und dafür dann das Tabellenlayot aktiviert wird und Teilergebnisse wie das Gesamtergebnis deaktiviert sind. Für das Datumsfeld wird "leer" ausgefiltert.
 ABCDEFGHI
1DatumText28.09.20163,366666667  DatumTextAnzahl
228.09.2016Text_104.10.20161,633333333  28.09.2016Text_15
328.09.2016Text_2     Text_2 
428.09.2016Text_228.09.20165   Text_4 
528.09.2016Text_204.10.20163   Text_5 
6       Text_6 
704.10.2016Text_5    04.10.2016Text_13
804.10.2016Text_5     Text_5 
904.10.2016Text_6     Text_6 
1004.10.2016Text_5       
11         
1228.09.2016Text_4       
1304.10.2016Text_1       
1404.10.2016Text_5       
15         
1628.09.2016Text_5       
1728.09.2016Text_6       
1828.09.2016Text_1       
19         

Formeln der Tabelle
ZelleFormel
D1=SUMMENPRODUKT((A$1:A$99=C1)/ZÄHLENWENN(B$1:B$99;B$1:B$99&""))
I2=WENN(G2="";"";ANZAHL2(H2:INDEX(H:H;AGGREGAT(15;6;ZEILE(G3:G91)/((G3:G91>0)+(H3:H91=0)); 1)-1)))
D4{=SUMME(N(HÄUFIGKEIT(WENN(A$1:A$99=C4;VERGLEICH(B$1:B$99&"";B$1:B$99&"";)); ZEILE(A$1:A$99))>0))}
Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!
Matrix verstehen


Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
Gruß Werner
.. , - ...
Anzeige
;

Forumthreads zu verwandten Themen

Formel gesucht: Anzahl vesch. Werte in Zellbereich
Martin

Hallo liebe Excelianer,
gibt es eine Formel, die die Anzahl verschiedener Zelleninhalte für einen Bereich ermittelt? Zum Beispiel wenn ich 15 Zellen hätte, in denen 3mal die 5 steht und 12mal die 7 steht. Da ja nur 2 verschiedene Werte in den 15 Zellen stehen, müsste also 2 herauskommen. Nu...
19.09.2008 13:25:00
Thread-ID: 1011022
4 Beiträge
Zählenwenn mit 2 Bedingungen, aber Text | Herbers Excel-Forum
Jack
Hallo zusammen,
ich habe da ein Problem, was für die Profis unter euch sicherlich leicht zu lösen ist, mir aber seit gestern Abend Kopfzerbrechen bereitet:
Wie in der Überschrift beschrieben, möchte ich, dass in einem definiertem Feld ein Zählung vorgenommen wird, sofern die Kombination 2 b...
12.01.2010 10:43:11
Thread-ID: 1129091
4 Beiträge
Zählenwenn bei Textausschnitt
Tommi

Liebe Excel-Gemeinde,
ich habe in Spalte B eine Reihe von Dateipfaden. Sie beginnen mit /Home/... oder /My Documents/... etc. Ich würde nun gern zählen, wieviele Einträge mit /Home/... beginnen und wieviele mit anderen Anfangspfaden.
Problematisch hierbei ist leider, dass /Home/... nic...
04.03.2010 14:45:09
Thread-ID: 1143372
4 Beiträge
Zellen mit gleichem Inhalt zählen
addi23

Hallo Zusammen,
ich habe zwei kleine Frage, die für Euch sicherlich ein Kinderspiel sind:
1. In einer großen Exeldatei möchte ich in einem Bestimmten Bereich (z.B. eine komplette Spalte, oder ein markierter Bereich) die Anzahl unterschiedlicher Zellwerte ermitteln.
2. In der selben...
19.04.2011 15:18:58
Thread-ID: 1211066
6 Beiträge
Anzahl positiver Werte zählen
DirkR

Hallo zusammen,
ich habe ein kleines Problem in Excel, evtl. hat jemand von euch dafür eine Lösung. In meinem Excelsheet habe ich mehrere Datenreihen die alle ungefähr so aussehen:
108.01
105.02
106.04
103.45
98.70
100
D.h. die Datenreihen starten alle unten bei...
05.08.2011 11:20:39
Thread-ID: 1225022
3 Beiträge
Anzahl unterschiedlicher Einträge zählen
Dieter

Hallo zusammen,
folgende Formel habe ich vor längerer Zeit hier im Forum entdeckt:
=SUMME(N(HÄUFIGKEIT(ZEILE(3:689);TEILERGEBNIS(3;INDIREKT("d"&ZEILE(3:689)))*VERGLEICH(E3:E689&""; E3:E689&"";))>0)) -1
Mit dieser Formel wird die Anzahl verschiedener Einträge in einer...
11.08.2011 14:31:47
Thread-ID: 1225718
3 Beiträge
Zählenwenn text in zwei spalten
André

Hallo,
Wenn die Spalte b "Eskalation zurück nach" oder "zurück nach" enthält und in Spalte F "neu" steht, dann soll die Zeile gezählt werden. Mit Summenprodukt komme ich nicht weiter. für eine Bedingung in Spalte b habe ich das geschafft. Das Problem ist, dass noch mehr text in Spalte B st...
26.08.2011 11:45:43
Thread-ID: 1227647
4 Beiträge
Zählenwenn Text <>""
Fritz_W

Hallo Forumsbesucher,
mit welcher Formel kann ich ermitteln, welche Zellen des Zellbereichs E1:E2000 einen Text enthalten. Zellen, mit dem Formelergebnis "" sollten jedoch nicht mitgezählt werden.
Vielen Dank für eure Unterstützung.
mfg
Fritz
26.10.2011 15:56:07
Thread-ID: 1235517
15 Beiträge
Anzeige
Zellen mit Inhalt mehrere Spalten zählen
Chris

Hallo Leutz,
wie kann man per Formel Zellen mit Inhalt (nur zahlen) von nicht aneinandergrenzenden Spalten zählen?
Also zum Beispiel: zähle alle zellen mit Inhalt der Spalten: E, H, J (also jede zweite ab E).
Geht das?
Chris
26.04.2013 13:46:39
Thread-ID: 1310635
13 Beiträge
Hilfe: Anzahl verschiedener Zahlen zählen
Wolfi

Hallo, wie kann ich die Anzahl verschiedener Zahlen in einer Spalte zählen, aber nur solche, die mit dem Filter gefiltert wurden, d.h. nur die, die sichtbar sind?
Danke
09.07.2002 16:18:35
Thread-ID: 135114
2 Beiträge
Anzahl gleicher Werte in Textboxen
xelleron

Frohes Neues wünsche ich,
Und gleich ein "Problemchen".
Ich habe eine UF mit 14 Textboxen, in denen jeweils Werte angezeigt werden. Jetzt möchte ich prüfen, ob in 6 aufeinander folgenden Boxen die gleichen Werte stehen.
Als Bsp. In Textbox 3-8 steht eine 1, dann soll ein OK ausgegeb...
03.01.2014 10:13:28
Thread-ID: 1343991
6 Beiträge
Anzeige
Zählen Anzahl zwischen 2 Werten(0)
René

Hallo zusammen
Bin wieder mal gespannt auf Eure Lösungsansätze :-)
in Spalte A werden Messwerte dargestellt , die Messwerte können die Zahl 0 enthalten,
wie könnte die Anzahl zwischen 2 0 Werten angezeigt werden ,anbei eine Bsp Datei um die Frage zu verdeutlichen
https://www.he...
16.04.2015 12:06:17
Thread-ID: 1421181
3 Beiträge
Entdecke relevante Threads

Schau dir verwandte Threads basierend auf dem aktuellen Thema an

Alle relevanten Threads mit Inhaltsvorschau entdecken
Anzeige
Anzeige

Infobox / Tutorial

Anzahl unterschiedlicher Texte in Excel ermitteln

Schritt-für-Schritt-Anleitung

Um die Anzahl unterschiedlicher Texte zu zählen in Excel, folge diesen Schritten:

  1. Daten vorbereiten: Stelle sicher, dass deine Daten in zwei Spalten angeordnet sind. Beispielsweise:

    • Spalte A: Datum
    • Spalte B: Text

  2. Datum festlegen: Bestimme, in welcher Zelle (z.B. C1) das Datum steht, für das du die unterschiedlichen Texte zählen möchtest.

  3. Formel eingeben: Verwende die folgende Formel in einer leeren Zelle (z.B. D1):

    =SUMMENPRODUKT((A1:A99=C1)/ZÄHLENWENN(B1:B99;B1:B99&""))

    Diese Formel zählt die Anzahl unterschiedlicher Texte für das angegebene Datum in C1.

  4. Ergebnis überprüfen: Drücke Enter, um das Ergebnis anzuzeigen.

Häufige Fehler und Lösungen

  • Fehler: Ergebnis ist nicht korrekt.

    • Lösung: Überprüfe, ob das Datum in C1 korrekt ist und ob die Spalten A und B die richtigen Daten enthalten.

  • Fehler: Formel funktioniert nicht.

    • Lösung: Stelle sicher, dass die Formel korrekt eingegeben wurde. Achte darauf, dass du die Formel als Matrixformel eingibst, indem du STRG + SHIFT + ENTER drückst, wenn du eine Matrixformel verwendest.

Alternative Methoden

  1. Verwendung von ZÄHLENWENN: Eine alternative Formel könnte so aussehen:

    =ZÄHLENWENN(A1:A99;C1)

    Diese zählt die Anzahl der Zellen mit dem Datum in C1, bietet jedoch keine Anzahl unterschiedlicher Texte.

  2. Pivot-Tabellen: Wenn du mit Pivot-Tabellen vertraut bist, kannst du auch eine Pivot-Tabelle erstellen, die die Texte nach Datum gruppiert. Dies könnte jedoch komplizierter sein, wenn du nur die Anzahl unterschiedlicher Texte benötigst.

Praktische Beispiele

Angenommen, du hast folgende Daten:

A B
28.09.2016 Text_1
28.09.2016 Text_2
28.09.2016 Text_1
04.10.2016 Text_2
04.10.2016 Text_3

Wenn in C1 das Datum 28.09.2016 steht, gibt die Formel in D1 2 zurück, da es zwei unterschiedliche Texte (Text_1 und Text_2) für dieses Datum gibt.

Tipps für Profis

  • Verwendung von Zellen mit unterschiedlichem Inhalt zählen: Um die Anzahl unterschiedlicher Werte in Excel zu zählen, kannst du die Formel in Kombination mit anderen Funktionen verwenden, z.B. mit HÄUFIGKEIT oder VERGLEICH.

  • Einsatz von AGGREGAT: Für größere Datenmengen kann die Verwendung von AGGREGAT nützlich sein, um die Berechnung effizienter zu gestalten.

FAQ: Häufige Fragen

1. Wie zähle ich die Anzahl unterschiedlicher Wörter in einer Zelle?
Verwende die Funktion =ANZAHL2(WENN(BEREICH.VERSCHIEBEN(A1;0;0;ANZAHL(A:A);1);BEREICH.VERSCHIEBEN(A1;0;0;ANZAHL(A:A);1)&"")>=1).

2. Was mache ich, wenn ich Daten nach mehreren Kriterien zählen möchte?
Nutze die Funktion ZÄHLENWENNS, um mehrere Kriterien zu berücksichtigen. Zum Beispiel:

=ZÄHLENWENNS(A:A;C1;B:B;"Text_1")

Diese Formel zählt die Anzahl der Zellen, die sowohl das Datum in C1 als auch den Text "Text_1" enthalten.

Beliebteste Forumthreads (12 Monate)

Jetzt das Excel-Portal bewerten: Deine Stimme zählt!
Anzeige
Anzeige
Entdecke mehr
Finde genau, was du suchst

Die erweiterte Suchfunktion hilft dir, gezielt die besten Antworten zu finden

Suche nach den besten Antworten
Unsere beliebtesten Threads

Entdecke unsere meistgeklickten Beiträge in der Google Suche

Top 100 Threads jetzt ansehen
Anzeige