Live-Forum - Die aktuellen Beiträge
Datum
Titel
28.03.2024 21:12:36
28.03.2024 18:31:49
Anzeige
Archiv - Navigation
880to884
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
880to884
880to884
Aktuelles Verzeichnis
Verzeichnis Index
Verzeichnis Index
Übersicht Verzeichnisse
Inhaltsverzeichnis

Application.DisplayAlerts = True ?

Application.DisplayAlerts = True ?
02.07.2007 19:47:00
Walter
Guten Abend,
wie kann ich die Meldung im unterem Drittel des Bildschirms anzeigen lassen ?
Application.DisplayAlerts = True
mfg Walter B

14
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Application.DisplayAlerts = True ?
02.07.2007 19:57:50
Nepumuk
Hallo Walter,
welche Meldung?
Gruß
Nepumuk

Wenn ich die Datei speichere
02.07.2007 20:15:09
Walter
Hallo Nepumuk,
oh entschuldige, hatte ganz vergessen.
mfg walter B

AW: Wenn ich die Datei speichere
02.07.2007 20:22:00
Nepumuk
Hallo Walter,
was kommt da für eine Meldung? Bei mir kommt da nix.
Gruß
Nepumuk

AW: Wenn ich die Datei speichere
02.07.2007 20:35:00
Walter
Hallo Nepumuk,
Application.DisplayAlerts = True
ActiveWorkbook.SaveAs Filename:= _
"C:\Lager\Stände\aktuellvom 02.07.2007.xls" _
, FileFormat:=xlNormal, Password:="", WriteResPassword:="", _
ReadOnlyRecommended:=False, CreateBackup:=False
mfg Walter B

AW: Wenn ich die Datei speichere
02.07.2007 20:39:00
Nepumuk
Hallo Walter,
meinst du die Meldung, dass die Datei schon existiert und ob du sie überschreiben willst?
Gruß
Nepumuk

Anzeige
Ja genau das...
02.07.2007 20:41:00
Walter
Hallo Nepumuk,
genau das !
mfg Walter B

AW: Ja genau das...
02.07.2007 20:58:15
Nepumuk
Hallo Walter,
schreib das doch gleich.
' **********************************************************************
' Modul: Modul1 Typ: Allgemeines Modul
' **********************************************************************

Option Explicit

Private Declare Function KillTimer Lib "user32.dll" ( _
    ByVal hWnd As Long, _
    ByVal nIDEvent As Long) As Long
Private Declare Function SetTimer Lib "user32.dll" ( _
    ByVal hWnd As Long, _
    ByVal nIDEvent As Long, _
    ByVal uElapse As Long, _
    ByVal lpTimerFunc As Long) As Long
Private Declare Function FindWindow Lib "user32.dll" Alias "FindWindowA" ( _
    ByVal lpClassName As String, _
    ByVal lpWindowName As String) As Long
Private Declare Function SetWindowPos Lib "user32.dll" ( _
    ByVal hWnd As Long, _
    ByVal hWndInsertAfter As Long, _
    ByVal x As Long, _
    ByVal y As Long, _
    ByVal cx As Long, _
    ByVal cy As Long, _
    ByVal wFlags As Long) As Long

Private Const GC_CLASSNAMEMSDIALOG = "#32770"
Private Const GC_CLASSNAMEMSEXCEL = "XLMAIN"

Private Const SWP_NOSIZE = &H1&
Private Const SWP_NOZORDER = &H4&
Private Const SWP_NOACTIVATE = &H10&
Private Const SWP_SHOWWINDOW = &H40&

Private hWnd As Long
Private hWndBox As Long

Public Sub test()
    Call prcStartTimer
    ThisWorkbook.SaveAs "C:\Dokumente und Einstellungen\Max Kaffl\Desktop\Mappe1.xls"
End Sub

Private Sub prcStartTimer()
    hWnd = FindWindow(GC_CLASSNAMEMSEXCEL, Application.Caption)
    SetTimer hWnd, 0, 100, AddressOf prcTimer
End Sub

Private Sub prcStopTimer()
    KillTimer hWnd, 0
End Sub

Private Sub prcTimer(ByVal hWnd As Long, ByVal nIDEvent As Long, _
        ByVal uElapse As Long, ByVal lpTimerFunc As Long)

    On Error Resume Next
    hWndBox = FindWindow(GC_CLASSNAMEMSDIALOG, vbNullString)
    If hWndBox <> 0 Then
        Call prcStopTimer
        Call prcMoveWindow
    End If
End Sub

Private Sub prcMoveWindow()
    Const POS_X = 100& 'Abstand von links
    Const POS_Y = 500& 'Abstand von oben
    Call SetWindowPos(hWndBox, 0&, POS_X, POS_Y, 0&, 0&, _
        SWP_NOSIZE Or SWP_NOZORDER Or SWP_NOACTIVATE Or SWP_SHOWWINDOW)
End Sub

Gruß
Nepumuk

Anzeige
Danke !!!! -)
02.07.2007 21:04:00
Walter
Entschuldige bitte für das unklare, Danke für deine Unterstützung,
mfg Walter B

AW: Ja genau das...
02.07.2007 23:01:24
Hannes
Hallo Nepumuk,
was soll den dieser Code bewirken ?
Grüße Hannes

AW: Ja genau das...
02.07.2007 23:16:00
Nepumuk
Hallo Hannes,
na das die Box, welche die Warnmeldung ausgibt, dahin geschoben wird wo du willst.
Gruß
Nepumuk

AW: Ja genau das...
03.07.2007 23:05:00
Hannes
hallo Nepumuk,
hier wird doch gar nichts verschoben...
außer irgend ein Fenster von der Firewall...
Grüße Hannes
Userbild

AW: Ja genau das...
04.07.2007 07:04:20
Nepumuk
Hallo Hannes,
versuch es mal wenn du den Titel der Box in die FindWindow - Funktion eingibst.
hWndBox = FindWindow(GC_CLASSNAMEMSDIALOG, "Microsoft Excel")
Gruß
Nepumuk

Anzeige
Ergänzung
03.07.2007 07:43:00
Nepumuk
Hallo Walter,
ergänze den Aufruf um diese Zeile, denn sonst läuft der Timer weiter, wenn keine Warnmeldung kommt, weil es die Datei noch nicht gibt.

Public Sub test()
Call prcStartTimer
ThisWorkbook.SaveAs "C:\Dokumente und Einstellungen\Max Kaffl\Desktop\Mappe1.xls"
Call prcStopTimer
End Sub


Gruß
Nepumuk

Danke nochmals !!! -)
04.07.2007 21:36:00
Walter
Hallo Nepumuk,
Danke,
mfg Walter B

78 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige