Daten eintragen mit Inputbox ohne doppelte Daten

Forumthread: Daten eintragen mit Inputbox ohne doppelte Daten

21.06.2016 17:54:21

Lupo

Hallo Forum,
ich möchte auf dem Sheet "Stammdaten" mit einer Inputbox Daten in die Spalte A eintragen. Dabei sollen die neuen Daten in die erste freie Zeile geschrieben werden. Das läuft auch so weit, allerdings möchte ich verhindern das Daten doppelt eingetragen werden. Um das zu verhindern soll ein Msg.box erscheinen mit dem Hinweis, dass die Daten schon vorhanden sind.
Hat jemand eine Idee?
Schöne Grüße,
Lupo
Folgenden Code habe ich schon:

Sub Neuen_Bereich_eintragen()
Dim sTxt As String
sTxt = InputBox("Bitte neuen Bereich eintragen:", "Neuen Bereich eintragen")
If sTxt = "" Then Exit Sub
Sheets("Stammdaten").Select
Worksheets("Stammdaten").Range("A" & Range("A65536").End(xlUp).Row + 1).Value = sTxt
End Sub

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Daten eintragen mit Inputbox ohne doppelte Daten

21.06.2016 20:15:45

Nepumuk

Hallo,
teste mal:

Option Explicit

Public Sub Neuen_Bereich_eintragen()

    Dim strText As String

    strText = InputBox("Bitte neuen Bereich eintragen:", "Neuen Bereich eintragen")

    If strText <> "" Then

        With Worksheets("Stammdaten")

            If WorksheetFunction.CountIf(.Columns(1), strText) = 0 Then

                .Cells(.Rows.Count, 1).End(xlUp).Offset(1, 0).Value = strText

            Else
                Call MsgBox("Dieser Wert ist schon in der Liste.", vbExclamation, "Hinweis")
            End If
        End With
    End If
End Sub

Gruß
Nepumuk

AW: Daten eintragen mit Inputbox ohne doppelte Daten

21.06.2016 20:17:36

Crazy

Hallo
eine weitere Möglichkeit

Sub Neuen_Bereich_eintragen()
Dim sTxt As String
Dim lngLetzte As Long
Dim c As Range
sTxt = InputBox("Bitte neuen Bereich eintragen:", "Neuen Bereich eintragen")
If sTxt = "" Then Exit Sub
With Sheets("Stammdaten")
lngLetzte = .Cells(.Rows.Count, 1).End(xlUp).Row
Set c = .Range("A1:A" & lngLetzte).Find(sTxt, _
LookIn:=xlValues, _
lookat:=xlWhole)
If Not c Is Nothing Then
MsgBox "Daten schon vorhanden"
Else
.Range("A" & lngLetzte + 1).Value = sTxt
End If
End With
End Sub

MfG Tom

AW: Daten eintragen mit Inputbox ohne doppelte Daten

21.06.2016 20:30:44

Lupo

Hallo ihr,
danke für die Hilfe!
Ich habe mich für die Variante von Crazy Tom entschieden und konnte sie gut in das gesamt Marko einfügen.
Schöne Grüße,
Lupo

Beliebteste Forumthreads (12 Monate)

Daten eintragen mit Inputbox ohne doppelte Daten

Forumthread: Daten eintragen mit Inputbox ohne doppelte Daten

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Daten eintragen mit Inputbox ohne doppelte Daten

Forumthread: Daten eintragen mit Inputbox ohne doppelte Daten

3 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

3
Beiträge zum Forumthread

Beiträge zu diesem Forumthread