Live-Forum - Die aktuellen Beiträge
Datum
Titel
29.03.2024 13:14:12
28.03.2024 21:12:36
28.03.2024 18:31:49
Anzeige
Archiv - Navigation
1688to1692
Aktuelles Verzeichnis
Verzeichnis Index
Übersicht Verzeichnisse
Vorheriger Thread
Rückwärts Blättern
Nächster Thread
Vorwärts blättern
Anzeige
HERBERS
Excel-Forum (Archiv)
20+ Jahre Excel-Kompetenz: Von Anwendern, für Anwender
Inhaltsverzeichnis

Barcodes in Excel aus EAN Nummer

Barcodes in Excel aus EAN Nummer
24.04.2019 12:55:15
Jule
Moin,
kann man eingescannte EAN Nummern intern in Excel in der Spalte in für einen Handscanner lesbaren Barcode umwandeln?
Damit meine ich keine Schriftart, die die Zeichen umwandelt, da diese nicht lesbar sind für den Handscanner.
LG
Jule

8
Beiträge zum Forumthread
Beiträge zu diesem Forumthread

Betreff
Datum
Anwender
Anzeige
AW: Barcodes in Excel aus EAN Nummer
24.04.2019 13:03:45
UweD
Hi
ja, das geht, der Aufwand ist abhängig davon, welchen Code du verwenden möchtest
Code 39 (der Einfachste)
Code 128
EAN 128
EAN 13 bzw. GTIN 13
2/5 interleaved.
usw.
LG UweD
Beispiel
24.04.2019 13:18:24
UweD
Userbild
AW: Beispiel
24.04.2019 16:26:56
Jule
Hay Uwe
Code128 brauchen wir für unseren Zweck, muss ich dann die Zeichen für jeden Code so eingeben oder wie kann ich das auf die ganze Spalte übertragen?
LG
Jule
AW: Beispiel
24.04.2019 16:36:07
UweD
Hallo
du brauchst
- die Schriftart
- dieses Makro in einem normalen Modul..
Public Function Code128$(Text$)
    Dim x%, y%, fehlzeichen%, checksumme&
    Dim Zeichensatz As Variant
    Zeichensatz = Array("ß", "!", Chr(34), "#", "$", "%", "&", "'", "(", ")", "*", "+", ",", "-", ".", "/", "0", "1", "2", "3", "4", "5", "6", "7", "8", "9", ":", ";", "<", "=", ">", "?", "@", "A", "B", "C", "D", "E", "F", "G", "H", "I", "J", "K", "L", "M", "N", "O", "P", "Q", "R", "S", "T", "U", "V", "W", "X", "Y", "Z", "[", "\", "]", "^", "_", "`", "a", "b", "c", "d", "e", "f", "g", "h", "i", "j", "k", "l", "m", "n", "o", "p", "q", "r", "s", "t", "u", "v", "w", "x", "y", "z", "{", "|", "}", "~", "´", "ä", "ö", "ü", "Ä", "Ö", "Ü", "µ", "À", "Á", "Â", "È")
    Code128$ = ""

    'Die Maximallänge des Textes wird auf 40 Zeichen begrenzt, um fehlerhafte Scans zu vermeiden. 
    If (Len(Text$) > 40) Then
        x% = MsgBox("Der zu codierende Text ist " & Str(Len(Text$) - 40) & " Zeichen zu lang." & Chr(13) & "Um Fehler beim Scannen des Barcodes zu vermeiden, ist dieses Makro auf 40 Zeichen begrenzt.", 64, "Barcode-Generator (Code 128)")
        Exit Function
    End If

    'Wenn kein Text zu codieren ist, dann Funktion beenden. 
    If (Len(Text$) = 0 Or Text$ = "0") Then
        Exit Function
    End If

    'Testen, ob im Ausgangstext ein ß enthalten ist 
    If (InStr(Text$, "ß") <> 0) Then
        x% = MsgBox("Das Zeichen ß kann nicht dargestellt werden.", 64, "Barcode-Generator (Code 128)")
        Exit Function
    End If

    'Das Startzeichen hat den Wert 104 
    checksumme& = 104

    'Leerzeichen durch ß ersetzen 
    Text$ = Replace(Text$, " ", "ß")


    'Prüfziffer berechnen 
    For x% = 1 To Len(Text$)
        fehlzeichen% = 1
        For y% = 0 To 94
            If (Mid$(Text$, x%, 1) = Zeichensatz(y%)) Then
                fehlzeichen% = 0
                checksumme& = checksumme& + (x% * y%)
                Exit For
            End If
        Next y%
        If fehlzeichen% = 1 Then
            x% = MsgBox("Das Zeichen " & Mid$(Text$, x%, 1) & " kann nicht dargestellt werden.", 64, "Barcode-Generator (Code 128)")
            Exit Function
        End If
    Next x%

    'Rest ermitteln 
    checksumme& = checksumme& Mod 103

    'Ergebnis = Startzeichen + Text + Prüfziffer + Stoppzeichen 
    Code128$ = "Á" & Text$ & Zeichensatz(checksumme&) & "È"
End Function

- in der Zelle dann so aufrufen
=Code128(A2)

- Achte darauf, dass um die Zelle genug Rand bleibt, Es gibt eine Ruhezone Links und Rechts
LG UweD
Anzeige
AW: Beispiel
25.04.2019 11:12:50
Jule
So nach bisschen rumprobieren hab ich es geschafft, vielen Dank ... jetzt kann die Inventur kommen :)
LG Jule
Danke für die Rückmeldung owT
25.04.2019 14:13:41
UweD
AW: Doppelt
24.04.2019 16:24:06
Jule
Sorry, das war keine absicht, scheinbar ist da was schief gelaufen :(

59 Forumthreads zu ähnlichen Themen

Anzeige
Anzeige
Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige

Beliebteste Forumthreads (12 Monate)

Anzeige
Anzeige
Anzeige