Nur Zeilen mit Werten drucken

Claudia · 2005-11-26T13:29:53+00:00

Hallo liebe Excelgemeinde, habe da ein für mich nicht zu lösendes Problem. Ich habe in einem Tabellenblatt viele Zeilen, es sind mehrere Seiten, wo aber nur jene Zeilen ausgedruckt werden sollen, wenn in der Spalte Summe ein Wert steht. Also wenn z.B.: in Zelle B2 ein Wert steht, dann soll die ganze Zeile gedruckt werden, der Rest ohne inhalt nicht, ist das möglich? Wenn ja, wie kann ich das schaffen? Habe ein Beispiel hochgeladen damit es verständlicher ist. Die Datei https://www.herber.de/bbs/user/28732.xls wurde aus Datenschutzgründen gelöscht Ich danke für jede Hilfe. LG Claudschi

Hi Claudia,
versuch es mal damit:

Public Sub Drucken()
    Dim lngRow As Long, intCalcMode As Integer
    On Error GoTo Err_Exit
    With Application
        .ScreenUpdating = False
        intCalcMode = .Calculation
        .Calculation = xlCalculationManual
        .DisplayAlerts = False
        .Interactive = False
        .EnableEvents = False
    End With
    With ThisWorkbook
        With .ActiveSheet
            For lngRow = 9 To .Cells(.Rows.Count, 1).End(xlUp).Row - 3
                If Trim$(.Cells(lngRow, 3).Text) = "" Then _
                    .Rows(lngRow).Hidden = True
            Next
            .Cells.Copy
        End With
        .Worksheets.Add
        With .ActiveSheet
            .Paste
            With .PageSetup
                .PrintTitleRows = "$1:$8"
                .CenterFooter = "KuLR - Nur für den Dienstgebrauch !"
                .LeftMargin = Application.InchesToPoints(0.4)
                .RightMargin = Application.InchesToPoints(0.7)
                .TopMargin = Application.InchesToPoints(0.8)
                .BottomMargin = Application.InchesToPoints(0.1)
                .HeaderMargin = Application.InchesToPoints(0.2)
                .FooterMargin = Application.InchesToPoints(0.2)
                .PrintQuality = 300
                .CenterHorizontally = True
                .Orientation = xlLandscape
                .BlackAndWhite = True
                .PaperSize = xlPaperA4
                .Zoom = 92
            End With
            .PrintOut
            .Delete
        End With
        .ActiveSheet.Rows.Hidden = False
    End With
    Err_Exit:
    With Application
        .ScreenUpdating = True
        .DisplayAlerts = True
        .Calculation = intCalcMode
        .Interactive = True
        .EnableEvents = True
    End With
    If Err.Number <> 0 Then _
        MsgBox "Fehler " & CStr(Err.Number) & vbLf & vbLf & _
        Err.Description, 16, "Fehlermeldung"
End Sub

Gruß
Nepumuk

Forumthread: Nur Zeilen mit Werten drucken

11
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Infobox / Tutorial