nur bestimmte dezimalstellen

Forumthread: nur bestimmte dezimalstellen

30.09.2021 00:32:09

zoe

Hallo,
Ich bräuchte eine Formel die es mir ermöglicht, dass nur auf bestimmte Dezimalstellen aufgerundet wird.
Es geht um Produktpreise. Ich möchte dass sie auf ,20 oder ,50 oder ,95 enden.
Wenn ich meinen Verkaufspreis berechnet habe muss ich immer selbst noch aufrunden und würde mir wünschen dass das die excel Tabelle für mich macht.
Als Beispiel: der Verkaufspreis wären 5,13 so sollte das auf 5,20 gerundet werden. Oder 5,60 so sollte dieser Pries zu 5,95 werden
Ich wollte es mir VRUNDEN probieren aber da die Dezimalstellen die ich brauche ja kein Vielfaches von der gleichen Zahl sind klappt das leider nicht. Genauso wie es keine gleichmäßige Zahlenreihenfolge wäre.
Dankeschön!
Grüße

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Das könnte man wie folgt machen, ...

30.09.2021 03:17:15

Luc:-?
AW: nur bestimmte dezimalstellen

30.09.2021 05:38:26

Daniel
AW: sicherlich nur für Wert >0 ...

02.10.2021 14:18:15

neopa
Ich ging davon aus, ...

03.10.2021 15:11:14

aus,

Das könnte man wie folgt machen, ...

30.09.2021 03:17:15

Luc:-?

…Zoe,
wobei die nachstehenden Fmln 2 gleichwertige Varianten mit je einer Untervariante zeigen, deren Anwendung davon abhängt, ob die Originalwerte bereits auf 2 Dezimalen gerundet vorliegen oder nicht, also ggf erst noch gerundet oder abgerundet wdn müssen, damit die eigentliche FmlAktion fktioniert:
=GANZZAHL(A45)+MIN(WENN(--RECHTS(TEXT(A45;"0,00");3)<{0,2.0,5.0,95};{0,2.0,5.0,95};1,2))
=GANZZAHL(A45)+MIN(WENN(--RECHTS(TEXT(RUNDEN(A45;2);"0,00");3)<{0,2.0,5.0,95};{0,2.0,5.0,95};1,2))
=GANZZAHL(A45)+INDEX({0,2.0,5.0,95.1,2};5-SUMME(--(--RECHTS(TEXT(A45;"0,00");3)<{0,2.0,5.0,95.1})) )
=GANZZAHL(A45)+INDEX({0,2.0,5.0,95.1,2};5-SUMME(--(--RECHTS(TEXT(ABRUNDEN(A45;2);"0,00");3)< {0,2.0,5.0,95.1})))
Meine QuellAdresse (A45) durch die deine ersetzen nicht vergessen!
Morhn, Luc :-?
Die universelle Befähigung zur Unfähigkeit macht jede menschliche Leistung zu einem unglaublichen Wunder. Stapps ironisches Paradoxon

AW: nur bestimmte dezimalstellen

30.09.2021 05:38:26

Daniel

Hi
Mit dem Preis in A1


=Ganzzahl(A1)+SVerweis(Rest(A1;1)*100;{0.20;21.60;61.95;96.120};2;wahr)/100

Oder


=Ganzzahl(A1)+Verweis(Rest(A1;1)*100;{0;21;61;96};{20;60;95;120})/100

Gruß Daniel

AW: sicherlich nur für Wert >0 ...

02.10.2021 14:18:15

neopa

Hallo,
... Luc und Daniel haben Dir ja schon eine Menge an Formelalternativen zur Wahl vorgegeben. Die Formeln von Luc runden dabei allerdings auch die Werte auf, deren Dezimalanteil indentisch Denen Vorgabewerten sind (also z.B. wird aus 6,5 ein 6,95, was sicherlich nicht gewollt ist, oder?) und bei seinen und Daniels Formeln wird aus "Nichts" ein 0,2. Das muss&kann noch abgefangen werden.
Mein nachfolgender Vorschlag deshalb, basierend auf Anpassung der 2. Formel von Daniel (wobei er wohl aus Versehen anstelle 0,5 auf 0,6 aufgerundet hat) so:
=KÜRZEN(A1)+(A1&gt0)*VERWEIS(REST(A1;1)/1%;{0;21;51;96};{20;50;95;120})%
Gruß Werner
.. , - ...

Ich ging davon aus, ...

03.10.2021 15:11:14

aus,

…Werner,
dass …
1. wie einleitend erwähnt, der RohPreis berechnet wird und deshalb nie 0 ergibt, weil ein solcher Preis wohl kaum sinnvoll wäre; ;-)
2. der EndPreis stets höher als das BerechnungsErgebnis sein soll; anderenfalls wäre der PreisbildungsProzess ja komplizierter und könnte auch Abrundungen beinhalten, wobei das alles bereits in der primären PreisBerechnung enthalten sein sollte, so dass es jetzt nur noch um die End-„Kosmetik“ geht.
Das alles kann aber nur Zoe wissen, die aber offensichtlich kein Feedback zu geben gedenkt (… :-[ ), weshalb weitere Diskussionen wohl rein akademisch wären und mein Kommentar nur zur Erläuterung der Beweggründe meines Vorgehens - für Dich - dient.
Gruß+schöSo, Luc :-?

Beliebteste Forumthreads (12 Monate)

Forumthread: nur bestimmte dezimalstellen

4 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

4
Beiträge zum Forumthread

Beiträge zu diesem Forumthread