Summe, wenn Zelle einen Wortteil enthält

Forumthread: Summe, wenn Zelle einen Wortteil enthält

10.01.2006 11:51:11

Michael

Hallo zusammen!
Fällt euch eine Formel ein, mit der ich die Summen unten rechts ermitteln kann? Eigentlich müsste das doch einfach sein, aber ich habe da momentan ein Brett vor dem Kopf.
Grüße, Micha.
Spieler der Doppel___________________Punkte
Müller, Hans / Meier, Max______________1
Lustig, Peter / Meier, Max______________2
Meier, Max / Herb, Moritz_______________4
Lustig, Peter / Müller, Hans_____________5
Ergebnis der Spieler in Doppeln______Punkte
Müller, Hans_____________________1+5=6
Lustig, Peter_____________________2+5=7
Meier, Max_______________________1+2+4=7
Herb, Moritz______________________4

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Summe, wenn Zelle einen Wortteil enthält

10.01.2006 12:00:52

th.heinrich

hallo Michael,
trenne, wenn auch doppelpartner die teilnehmer in separate spalten.
dann kannst Du besser auswerten.
gruss thomas

AW: Summe, wenn Zelle einen Wortteil enthält

10.01.2006 12:04:31

Peter

Servus,
so in etwa.

Tabelle1

	A	B
1	Spieler der Doppel___________________Punkte
2	Müller, Hans / Meier, Max______________1	1
3	Lustig, Peter / Meier, Max______________2	2
4	Meier, Max / Herb, Moritz_______________4	4
5	Lustig, Peter / Müller, Hans_____________5	5
6	Müller, Hans	6

Formeln der Tabelle

B6 : {=SUMME(WENN(NICHT(ISTFEHLER(FINDEN(A6;A2:A5)));B2:B5))}
Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
MfG Peter

AW: Summe, wenn Zelle einen Wortteil enthält

ransi

Hallo Micha
zum Thema Tabellenaufbau schau dir das mal an:
http://www.online-excel.de/excel/singsel.php?f=52
wenn du dich dran hältst wird vieles einfacher.

	A	B
1	Spieler der Doppel	Punkte
2	Müller, Hans / Meier, Max	1
3	Lustig, Peter / Meier, Max	2
4	Meier, Max / Herb, Moritz	4
5	Lustig, Peter / Müller, Hans	5
6
7	Ergebnis der Spieler in Doppeln	Punkte
8	Müller, Hans	6
9	Lustig, Peter	7
10	Meier, Max	7
11	Herb, Moritz	4

Formeln der Tabelle

B8 : =SUMMENPRODUKT(ISTZAHL(FINDEN(A8;$A$2:$A$5))*$B$2:$B$5)
B9 : =SUMMENPRODUKT(ISTZAHL(FINDEN(A9;$A$2:$A$5))*$B$2:$B$5)
B10 : =SUMMENPRODUKT(ISTZAHL(FINDEN(A10;$A$2:$A$5))*$B$2:$B$5)
B11 : =SUMMENPRODUKT(ISTZAHL(FINDEN(A11;$A$2:$A$5))*$B$2:$B$5)

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
ransi

=summewenn(a1:a10;"*Müller*";b1:b10)

10.01.2006 14:56:08

ingoG

Hallo zusammen,
folgende formel sollte funzen oder mit verweis:
=summewenn(a1:a10;"*"&A11&"*";b1:b10)
wertet alle zeilen aus, die in a1:a10 den Teilstring a11 besitzen und addiert dann die werte aus b1:b10 ...
Gruß Ingo
PS eine Rückmeldung wäre nett...

Frage nun zu 99 % gelöst

10.01.2006 19:50:10

Michael

Hallo zusammen!
So, mit eurer Hilfe habe ich das Problem nun zu 99 % gelöst.
Feedback: Die Funktion von ingoG fand ich am übersichtlichsten; sie funktionierte ebenso, wie die Lösung von ransi.
Die Vorschläge von Peter W und von hermannZ klappten leider nicht. Kann aber auch daran liegen, dass dass meine zu addierenden Werte "10:3" + "5:4" nur über den Trick der Formatierung als [h]:m in einer Zelle dargestellt werden.
In 1 % der Fälle klappt alles nicht. Das ist dann der Fall, wenn hinter den einzelnen Spielernamen eine Zusatzinfo in Klammern steht [Beispiel: "Müller, Hans (JFG)"] und dieser Zusatz dann bei den Doppeln nicht aufgeführt wird. Ich tüfftel zwar selbst auch, aber wenn ihr schneller seid...
Danke schon mal und schönen Abend noch.
Micha.

AW: Frage nun zu 99 % gelöst

10.01.2006 20:46:58

HermannZ

Hallo Michael;
wenn du schreibst das die Formel von PeterW und HermannZ nicht funktionieren dann liegt das aber nicht an den besagten,sondern an dir und deinen unzureichenden Angaben.Jetzt habe ich festgestellt das du mit Spielerergebnissen im Format 2:3 arbeitest und das geht natürlich so garnicht,aber nur so zum Spass ein beispiel für sowas;
Beispiel;

Versuch

	A	B	C	D
107
108			ges.Name	Summe
109	Müller, Hans / Meier, Max	5:4	Müller, Hans	8
110	Lustig, Peter / Meier, Max	10:2
111	Meier, Max / Herb, Moritz	3:4
112	Lustig, Peter / Müller, Hans	8:3
113
114	oder so
115	Müller, Hans	8
116	Lustig, Peter	18
117	Meier, Max	9
118	Herb, Moritz	4
119		Formel nach unten
120		kopieren

Formeln der Tabelle

D109 : {=SUMME(WENN((LINKS(A109:A112;FINDEN("/";A109:A112)-2)=C109)*1;LINKS(B109:B112;FINDEN(":";B109:B112)-1)*1))+SUMME(WENN((TEIL(A109:A112;FINDEN("/";A109:A112)+2;55)=C109)*1;TEIL(B109:B112;FINDEN(":";B109:B112)+1;2)*1))}
B115 : {=SUMME(WENN((LINKS($A$109:$A$112;FINDEN("/";$A$109:$A$112)-2)=A115)*1;LINKS($B$109:$B$112;FINDEN(":";$B$109:$B$112)-1)*1))+SUMME(WENN((TEIL($A$109:$A$112;FINDEN("/";$A$109:$A$112)+2;55)=A115)*1;TEIL($B$109:$B$112;FINDEN(":";$B$109:$B$112)+1;2)*1))}
Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
Gruß hermann

AW: Frage nun zu 99 % gelöst

10.01.2006 21:25:12

Michael

Klar, geht auf meine Kappe. Logisch, hatte versucht, das ganze möglichst einfach darzustellen. Ging nach hinten los, sorry. Danke trotzdem, hat mir sehr weitergeholfen!
Grüße, Michael.

AW: Summe, wenn Zelle einen Wortteil enthält

10.01.2006 12:05:17

HermannZ

Hallo Michael;
Beispiel;

Versuch

	A	B	C	D
92			ges. Name	Summe
93	Müller, Hans / Meier, Max	1	Meier, Max	7
94	Lustig, Peter / Meier, Max	2
95	Meier, Max / Herb, Moritz	4
96	Lustig, Peter / Müller, Hans	5
97
98	oder so
99	Müller, Hans	6
100	Lustig, Peter	7
101	Meier, Max	7
102	Lustig, Peter	7
103	Herb, Moritz	4
104

Formeln der Tabelle

D93 : {=SUMME(WENN(ISTZAHL(FINDEN(C93;A93:A96));B93:B96))}
B99 : {=SUMME(WENN(ISTZAHL(FINDEN(A99;$A$93:$A$96));$B$93:$B$96))}
B100 : {=SUMME(WENN(ISTZAHL(FINDEN(A100;$A$93:$A$96));$B$93:$B$96))}
B101 : {=SUMME(WENN(ISTZAHL(FINDEN(A101;$A$93:$A$96));$B$93:$B$96))}
B102 : {=SUMME(WENN(ISTZAHL(FINDEN(A102;$A$93:$A$96));$B$93:$B$96))}
B103 : {=SUMME(WENN(ISTZAHL(FINDEN(A103;$A$93:$A$96));$B$93:$B$96))}
Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
Gruß hermann

AW: Summe, wenn Zelle einen Wortteil enthält

10.01.2006 19:11:41

Michael

Danke schon einmal für die vielen Antworten. Mit so einer großen Resnonanz hab ich gar nicht gerechnet. Ich hab einige Lösungsvorschläge vorhin mal kurz durchgespielt, scheitere aber noch an anderen "Kleinigkeiten". Aber ich denke, jetzt hab ich die Funktion "finden" besser verstanden und müsste mich durchschlagen können.
Habe jetzt auch Zeit und werde die Vorschläge durchtüffteln und mich dann noch mal melden.
Warum ich nicht einfach, die Spielernamen der Doppel in zwei Zellen getrennt habe? Ich möchte die Daten in Zukunft aus dem Internet importieren, um mir die Vereinsarbeit zu erleichtern. Und die gibts leider nur in diesem Format...
Bis nachher, und vielen Dank!
Michael.

Infobox / Tutorial

Schritt-für-Schritt-Anleitung

Um in Excel die Summe zu berechnen, wenn eine Zelle einen bestimmten Wortteil enthält, kannst Du die SUMMEWENN-Funktion verwenden. Hier ist eine einfache Schritt-für-Schritt-Anleitung:

Daten vorbereiten: Stelle sicher, dass Du eine Tabelle mit den entsprechenden Spielernamen und deren Punkten hast. Zum Beispiel:
```
Spieler der Doppel | Punkte
-------------------|-------
Müller, Hans / Meier, Max | 1
Lustig, Peter / Meier, Max | 2
```
Formel eingeben: Gehe zur Zelle, in der Du die Summe berechnen möchtest, und gib folgende Formel ein:
```
=SUMMEWENN(A2:A5; "*Müller*"; B2:B5)
```
Diese Formel summiert die Punkte in der Spalte B, wenn in der Spalte A der Name "Müller" enthalten ist.
Matrixformel (optional): Wenn Du eine komplexere Abfrage benötigst, kannst Du die Matrixformel verwenden:
```
{=SUMME(WENN(NICHT(ISTFEHLER(FINDEN(A6; A2:A5))); B2:B5))}
```
Diese Formel muss mit STRG + SHIFT + ENTER eingegeben werden.

Häufige Fehler und Lösungen

Formel funktioniert nicht: Stelle sicher, dass Du die Matrixformel korrekt eingegeben hast. Wenn Du die geschweiften Klammern siehst, hast Du sie richtig eingegeben.
Suchkriterium nicht gefunden: Achte darauf, dass das Suchkriterium (z.B. "Müller") korrekt geschrieben ist und keine zusätzlichen Leerzeichen enthält.
Werte nicht summiert: Prüfe, ob die Punkte in der richtigen Spalte stehen und dass die Daten korrekt formatiert sind (z.B. als Zahl).

Alternative Methoden

SUMMENPRODUKT: Eine weitere Möglichkeit, die Summe zu berechnen, wenn ein Wortteil in einer Zelle enthalten ist, ist die Verwendung der SUMMENPRODUKT-Funktion. Zum Beispiel:
```
=SUMMENPRODUKT(ISTZAHL(FINDEN("Müller"; A2:A5)) * B2:B5)
```
Filter und Pivot-Tabellen: Du kannst auch Filter oder Pivot-Tabellen verwenden, um die Daten zu aggregieren und die gewünschten Summen zu berechnen.

Praktische Beispiele

Hier sind einige Beispiele, wie Du die SUMMEWENN-Funktion nutzen kannst:

Beispiel 1: Summe der Punkte von "Lustig, Peter":
```
=SUMMEWENN(A2:A5; "*Lustig*"; B2:B5)
```
Beispiel 2: Summe der Punkte, wenn ein Spieler in Klammern steht:
```
=SUMMEWENN(A2:A5; "*Müller, Hans (JFG)*"; B2:B5)
```

Diese Beispiele zeigen, wie man die SUMMEWENN-Funktion anpassen kann, um verschiedene Suchkriterien zu berücksichtigen.

Tipps für Profis

Wildcard verwenden: Nutze Platzhalter wie * (Sternchen) für beliebige Zeichenfolgen, um flexiblere Suchkriterien zu erstellen.
Datenvalidierung: Überprüfe Deine Daten regelmäßig, um sicherzustellen, dass sie korrekt eingegeben sind, insbesondere wenn Du Texte oder Namen verwendest.
Einheitliche Formatierung: Achte darauf, dass die Zellen, die Du summieren möchtest, im richtigen Zahlenformat vorliegen, um Fehler zu vermeiden.

FAQ: Häufige Fragen

1. Frage
Wie kann ich die Summe für mehrere Spieler gleichzeitig berechnen?
Antwort: Du kannst mehrere SUMMEWENN-Funktionen kombinieren oder die SUMMENPRODUKT-Funktion verwenden, um mehrere Bedingungen zu berücksichtigen.

2. Frage
Kann ich die Formeln auch in Excel Online verwenden?
Antwort: Ja, alle genannten Funktionen sind auch in der Online-Version von Excel verfügbar. Achte darauf, dass die Formeln korrekt eingegeben werden.

Beliebteste Forumthreads (12 Monate)

Summe, wenn Zelle einen Wortteil enthält

Forumthread: Summe, wenn Zelle einen Wortteil enthält

9
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Infobox / Tutorial

Summe, wenn Zelle einen Wortteil enthält

Schritt-für-Schritt-Anleitung

Häufige Fehler und Lösungen

Alternative Methoden

Praktische Beispiele

Tipps für Profis

FAQ: Häufige Fragen

Beliebteste Forumthreads (12 Monate)

Summe, wenn Zelle einen Wortteil enthält

Forumthread: Summe, wenn Zelle einen Wortteil enthält

9 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Infobox / Tutorial

Summe, wenn Zelle einen Wortteil enthält

Schritt-für-Schritt-Anleitung

Häufige Fehler und Lösungen

Alternative Methoden

Praktische Beispiele

Tipps für Profis

FAQ: Häufige Fragen

Beliebteste Forumthreads (12 Monate)

9
Beiträge zum Forumthread

Beiträge zu diesem Forumthread