Zählenwenn mit Adresse und Vergleich

Forumthread: Zählenwenn mit Adresse und Vergleich

07.02.2019 19:23:42

CMFA

Hallo und guten Abend,
ich habe ein kleines Problem mit meiner Zählenwenn Formel. Die EInzelteile der Formel _
funktionieren, nur das Zusammen will mir nicht gelingen. Hat wer eine Tip für mich? ZÄHLENWENN("ADRESSE(VERGLEICH(J4+K4;'[Spachtelliste 2019.xlsm]Spachtler'!$C:$C);AC4;4;4):ADRESSE(VERGLEICH(R4+S4;'[Spachtelliste 2019.xlsm]Spachtler'!$C:$C);AC4;4;1)";"X")
In J4 und K4 sowie in R4 und S4 stehen Datum und Uhrzeit dieser Wert soll in einer anderen Tabelle gesucht werden und dann in dieser Tabelle die "x" gezählt werden.
VG CMFA

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Zählenwenn mit Adresse und Vergleich

08.02.2019 06:11:02

fcs
AW: Zählenwenn mit Adresse und Vergleich

08.02.2019 08:42:23

CMFA

AW: Zählenwenn mit Adresse und Vergleich

08.02.2019 06:11:02

fcs

Hallo CMFA,
in deinem Formelkonstrukt wird der Zellbereich, den die Funktion ZÄHLENWENN auswerten soll als Text berechnet.
Die Funktion verlangt aber als Parameter einen Zellbereich einer Tabelle.
Das kann man mit der Funktion INDIREKT erreichen, funktioniert bei Zellbereichen in externen Arbeitsmappen aber nur dann korrekt wenn die die externe Datei geöffnet ist.
Bei Verwendung von Alternativen wie ZÄHLENWENNS oder INDEX gibt ebenfalls Probleme mit externen Dateien - sobald die externe Datei geschlossen wird wird im Ergebnis der Formel bei Neuberechnung ein Fehlerwert angezeigt.
Eine Auswertung ist möglich mit Funktion SUMMENPRODUKT wenn Daten in externer Quelle. Allerdings kann man hier die auszuwertende Spalte nicht dynamisch per Zellwert ändern.
Die Berechnung mit dieser Funktion dauert verhältnismäßig lange. Deshalb sollte man hier nicht die kompletten Spalten als Zellbereich angeben sondern einen bestimmten Zeilenbereich, der alle Daten erfasst.
LG
Franz
Tabelle6

	A	B	C	D	J	K	R	S	AC
3	INDIREKT	Zelle 1	Zelle 2	Alternativen	Datum 1	Zeit 1	Datum 2	Zeit 2	Spalte
4	6	D103	D253	6	03.01.2019	03:00	06.01.2019	06:01	4
5				6
6				6

Formeln der Tabelle

Zelle	Formel
A4	=ZÄHLENWENN(INDIREKT("'[Spachtelliste 2019.xlsm]Spachtler'!" & ADRESSE(VERGLEICH(J4+K4;'[Spachtelliste 2019.xlsm]Spachtler'!$C:$C); AC4;4;1) & ":" & ADRESSE(VERGLEICH(R4+S4;'[Spachtelliste 2019.xlsm]Spachtler'!$C:$C); AC4;4;1); WAHR); "X")
B4	=ADRESSE(VERGLEICH(J4+K4;'[Spachtelliste 2019.xlsm]Spachtler'!$C:$C); AC4;4;1)
C4	=ADRESSE(VERGLEICH(R4+S4;'[Spachtelliste 2019.xlsm]Spachtler'!$C:$C); AC4;4;1)
D4	=SUMMENPRODUKT(('[Spachtelliste 2019.xlsm]Spachtler'!$C$1:$C$5000>=(J4+K4))('[Spachtelliste 2019.xlsm]Spachtler'!$C$1:$C$5000<(R4+S4))('[Spachtelliste 2019.xlsm]Spachtler'!D$1:D$5000="X"))
D5	=ZÄHLENWENNS('[Spachtelliste 2019.xlsm]Spachtler'!$C:$C;">=" &(J4+K4); '[Spachtelliste 2019.xlsm]Spachtler'!$C:$C;"<"&(R4+S4); '[Spachtelliste 2019.xlsm]Spachtler'!D:D;"X")
D6	=ZÄHLENWENN(INDEX('[Spachtelliste 2019.xlsm]Spachtler'!$A$1:$AB$10000;VERGLEICH(J4+K4;'[Spachtelliste 2019.xlsm]Spachtler'!$C:$C); AC4) :INDEX('[Spachtelliste 2019.xlsm]Spachtler'!$A$1:$AB$10000;VERGLEICH(R4+S4;'[Spachtelliste 2019.xlsm]Spachtler'!$C:$C); AC4); "X")

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4.8

AW: Zählenwenn mit Adresse und Vergleich

08.02.2019 08:42:23

CMFA

Hallo Franz,
danke für die Erklärung, hatte es mir fast gedacht mit dem Text. Formel funktioniert jetzt wie gewünscht.
VG CMAF

Infobox / Tutorial

Zählenwenn-Funktionen in Excel effektiv nutzen

Schritt-für-Schritt-Anleitung
Häufige Fehler und Lösungen
Alternative Methoden
Praktische Beispiele
Tipps für Profis
FAQ: Häufige Fragen

Schritt-für-Schritt-Anleitung

Formel erstellen: Beginne mit der Erstellung deiner ZÄHLENWENN- oder ZÄHLENWENNS-Formel. Achte darauf, dass du den Zellbereich korrekt angibst. Bei externen Dateien ist es wichtig, dass diese geöffnet sind, sonst wird die Funktion nicht korrekt ausgeführt.

Beispiel:
```
=ZÄHLENWENN(INDIREKT("'[Spachtelliste 2019.xlsm]Spachtler'!" & ADRESSE(VERGLEICH(J4+K4;'[Spachtelliste 2019.xlsm]Spachtler'!$C:$C); AC4; 4; 1) & ":" & ADRESSE(VERGLEICH(R4+S4;'[Spachtelliste 2019.xlsm]Spachtler'!$C:$C); AC4; 4; 1)); "X")
```
Parameter überprüfen: Stelle sicher, dass alle Parameter der Funktion korrekt sind. Die Funktion ZÄHLENWENN benötigt einen Zellbereich und ein Kriterium.
Verwendung von INDIREKT: Wenn du mit Adressreferenzen arbeitest, nutze die Funktion INDIREKT, um den Zellbereich dynamisch zu bestimmen. Beachte jedoch, dass dies nur funktioniert, wenn die Datei geöffnet ist.

Häufige Fehler und Lösungen

Fehler: Zellbereich als Text: Wenn der Zellbereich als Text interpretiert wird, wird die Formel nicht korrekt funktionieren. Überprüfe, ob du die Funktion INDIREKT korrekt verwendest.
Lösung: Stelle sicher, dass die externe Datei geöffnet ist, während du die ZÄHLENWENN-Funktion verwendest.
Problem mit ZÄHLENWENNS: Wenn du ZÄHLENWENNS mit externen Dateien verwendest, kann es bei geschlossenen Dateien zu Fehlern kommen.
Lösung: Ziehe die Verwendung von SUMMENPRODUKT in Betracht, um die Berechnungen durchzuführen, auch wenn dies länger dauern kann.

Alternative Methoden

SUMMENPRODUKT: Diese Funktion ermöglicht es dir, mehrere Kriterien zu kombinieren. Besonders nützlich, wenn du komplexe Bedingungen hast.

Beispiel:

=SUMMENPRODUKT(('[Spachtelliste 2019.xlsm]Spachtler'!$C$1:$C$5000 >= J4 + K4) * ('[Spachtelliste 2019.xlsm]Spachtler'!$C$1:$C$5000 < R4 + S4) * ('[Spachtelliste 2019.xlsm]Spachtler'!D$1:D$5000 = "X"))

INDEX-Funktion: Eine Kombination aus INDEX und VERGLEICH kann ebenfalls hilfreich sein, um dynamische Bereiche zu definieren.

Praktische Beispiele

ZÄHLENWENN mit ODER: Um mehrere Kriterien gleichzeitig zu prüfen, kannst du die ZÄHLENWENN-Funktion mit ODER kombinieren.

Beispiel:
```
=ZÄHLENWENN(A1:A10; "Kriterium1") + ZÄHLENWENN(A1:A10; "Kriterium2")
```
ZÄHLENWENNS für mehrere Bedingungen: Wenn du mehrere Bedingungen in einem Bereich zählen möchtest, verwende ZÄHLENWENNS.

Beispiel:
```
=ZÄHLENWENNS(A1:A10; ">10"; B1:B10; "<5")
```

Tipps für Profis

Verwende Named Ranges: Statt Zellreferenzen kannst du benannte Bereiche verwenden, um die Lesbarkeit der Formeln zu verbessern.
Fehlerbehebung: Nutze die Funktion Fehlerüberprüfung in Excel, um potentielle Probleme in deinen Formeln zu identifizieren.
Optimierung: Um die Performance zu verbessern, beschränke die Anzahl der Zellen, die du in deinen Formeln überprüfst.

FAQ: Häufige Fragen

1. Was ist der Unterschied zwischen ZÄHLENWENN und ZÄHLENWENNS? ZÄHLENWENN zählt die Zellen, die ein einzelnes Kriterium erfüllen. ZÄHLENWENNS hingegen ermöglicht die Prüfung mehrerer Kriterien.

2. Wie kann ich ZÄHLENWENN mit ODER nutzen? Du kannst mehrere ZÄHLENWENN-Formeln addieren, um das ODER-Kriterium zu implementieren.

3. Funktioniert ZÄHLENWENN mit geschlossenen Dateien? Nein, bei externen Dateien funktioniert ZÄHLENWENN nur, wenn die Datei geöffnet ist. Alternativen wie SUMMENPRODUKT können in solchen Fällen verwendet werden.

Beliebteste Forumthreads (12 Monate)

Zählenwenn mit Adresse und Vergleich

Forumthread: Zählenwenn mit Adresse und Vergleich

2 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Infobox / Tutorial

Zählenwenn-Funktionen in Excel effektiv nutzen

Schritt-für-Schritt-Anleitung

Häufige Fehler und Lösungen

Alternative Methoden

Praktische Beispiele

Tipps für Profis

FAQ: Häufige Fragen

Beliebteste Forumthreads (12 Monate)

2
Beiträge zum Forumthread

Beiträge zu diesem Forumthread