Serienbrief
20.03.2018 17:16:00
KlausF
Hi,
das könnte man in etwa so lösen:
Sub Serienbrief()
Dim wksDruck As Worksheet
Dim wksDaten As Worksheet
Dim i As Long
Const firstRow As Long = 6 '1. Datenzeile im Auswahlblatt
Set wksDruck = Worksheets("Druck") 'Blatt für Seriendruck
Set wksDaten = Worksheets("Test2") 'Blatt mit Grunddaten
With wksDaten
'Von erster bis letzter Zeile
For i = firstRow To .Cells(.Rows.Count, "A").End(xlUp).Row
'Daten aus Zeile ins Druckblatt übertragen
wksDruck.Range("B2").Value = .Range("A" & i).Value 'Wert aus Spalte A
wksDruck.Range("D2").Value = .Range("B" & i).Value 'Wert aus Spalte B
'usw.
'Blatt drucken
wksDruck.PrintOut Preview:=True 'oder ohne Preview: wksDruck.PrintOut
Call DatenLoeschen
Next
End With
Set wksDruck = Nothing
Set wksDaten = Nothing
End Sub
Sub DatenLoeschen()
'Inhalte in Eingabezellen im Druckblatt löschen
Dim wksDruck As Worksheet
Set wksDruck = Worksheets("Druck") 'Blatt für Seriendruck
With wksDruck
'Eintragsfelder im Druckblatt leeren
.Range("B2").ClearContents
.Range("D2").ClearContents
'usw.
End With
Set wksDruck = Nothing
End Sub
Im Datenblatt Druck musst Du den Grundbrief anlegen.
Der Code muss dann so ergänzt werden, dass alle Datenzellen einzeln in das Druckblatt übertragen werden.
Danach startet der Druck automatisch und die Schleife arbeitet die nächste Zeilen bis zum Ende ab.
Mit dem DatenLoeschen-Code werden dann die Zellen wieder einzeln geleert
(ist aber nicht zwingend notwendig).
Gruß
Klaus