Überschneidungen beim Datum anzeigen

Bild

Betrifft: Überschneidungen beim Datum anzeigen von: JensW
Geschrieben am: 12.02.2005 20:37:38

Hallo

ich habe folgendes Problem das vielleicht schon jamand bereits gelöst hat:

Ich arbeite mit einer Tabelle die wie folgt aufgebaut ist

_____A_________B_______C_______D__ E F G H
1 Aufenthalt von | Aufenthalt bis | Zimmer Nr. | Name |
2 21.02.2003 | 26.03.2003 | 16 | Fr.Schmidt| txt .. .. ..
3 14.05.2003 | 17.05.2003 | 15 | Hr.Bauer | txt .. ....
4 15.05.2003 | 28.05.2003 | 16 | Fr.Müller | txt .. ....
5 15.06.2003 | 16.06.2003 | 11 | Hr.Nordman| txt .. ...


Es geht mir nun darum, Überschneidungen der einzelnen Aufenthaltszeiten zu markieren. In diesem Fall sollte die Zeile 3 und 4 kenntlich gemacht werden da eine Überschneidung vorliegt. In einem weiteren Schritt soll die Überschneidung nur dann angezeigt werden, wenn sich die Personen im gleichen Zimmer aufgehalten haben.

Bis jetzt habe ich die Auswertung immer von "Hand" gemacht, da ich keine Ahnung habe wie ich mit Monaten rechnen soll.Nun ist die Tabelle aber zu groß geworden. Die gesamte Tabelle umfasst 100 Personen mit 20 weiteren Punkten oben angedeutet mit E F G H I ...



Wie die überschneidungen kenntlich gemacht werden ( ob mit einem X wie ich es bisher versucht habe oder farbig unterlegt) ist total egal.

Über Hilfe freut sich

Jens ausm Schwabenland und zwar riesig

Bild


Betrifft: AW: Überschneidungen beim Datum anzeigen von: Josef Ehrensberger
Geschrieben am: 12.02.2005 20:52:48

Hallo Jens!

Vielleicht so.
Tabelle2
 ABCDEF
1Aufenthalt vonAufenthalt bisZimmer   
221.02.200326.03.200315Fr.Schmidt  
314.05.200317.05.200316Hr.Bauer Doppelbelegung!
415.05.200328.05.200316Fr.Müller Doppelbelegung!
515.06.200316.06.200311Hr.Nordman  
620.03.200326.03.200314Fr. Weis  
Formeln der Tabelle
F2 : =WENN(SUMMENPRODUKT(($A$2:$A$5<=B2)*($B$2:$B$5>=A2)*($C$2:$C$5=C2))>1;"Doppelbelegung!";"")
F3 : =WENN(SUMMENPRODUKT(($A$2:$A$5<=B3)*($B$2:$B$5>=A3)*($C$2:$C$5=C3))>1;"Doppelbelegung!";"")
F4 : =WENN(SUMMENPRODUKT(($A$2:$A$5<=B4)*($B$2:$B$5>=A4)*($C$2:$C$5=C4))>1;"Doppelbelegung!";"")
F5 : =WENN(SUMMENPRODUKT(($A$2:$A$5<=B5)*($B$2:$B$5>=A5)*($C$2:$C$5=C5))>1;"Doppelbelegung!";"")
F6 : =WENN(SUMMENPRODUKT(($A$2:$A$5<=B6)*($B$2:$B$5>=A6)*($C$2:$C$5=C6))>1;"Doppelbelegung!";"")
Bedingte Formatierungen der Tabelle
ZelleNr.: / BedingungFormat
A21. / Formel ist =SUMMENPRODUKT(($A$2:$A$6<=$B2)*($B$2:$B$6>=$A2)*($C$2:$C$6=$C2))>1Abc
B21. / Formel ist =SUMMENPRODUKT(($A$2:$A$6<=$B2)*($B$2:$B$6>=$A2)*($C$2:$C$6=$C2))>1Abc
A31. / Formel ist =SUMMENPRODUKT(($A$2:$A$6<=$B3)*($B$2:$B$6>=$A3)*($C$2:$C$6=$C3))>1Abc
B31. / Formel ist =SUMMENPRODUKT(($A$2:$A$6<=$B3)*($B$2:$B$6>=$A3)*($C$2:$C$6=$C3))>1Abc
A41. / Formel ist =SUMMENPRODUKT(($A$2:$A$6<=$B4)*($B$2:$B$6>=$A4)*($C$2:$C$6=$C4))>1Abc
B41. / Formel ist =SUMMENPRODUKT(($A$2:$A$6<=$B4)*($B$2:$B$6>=$A4)*($C$2:$C$6=$C4))>1Abc
A51. / Formel ist =SUMMENPRODUKT(($A$2:$A$6<=$B5)*($B$2:$B$6>=$A5)*($C$2:$C$6=$C5))>1Abc
B51. / Formel ist =SUMMENPRODUKT(($A$2:$A$6<=$B5)*($B$2:$B$6>=$A5)*($C$2:$C$6=$C5))>1Abc
A61. / Formel ist =SUMMENPRODUKT(($A$2:$A$6<=$B6)*($B$2:$B$6>=$A6)*($C$2:$C$6=$C6))>1Abc
B61. / Formel ist =SUMMENPRODUKT(($A$2:$A$6<=$B6)*($B$2:$B$6>=$A6)*($C$2:$C$6=$C6))>1Abc
 
Diagramm - Grafik - Excel Tabellen einfach im Web darstellen    Excel Jeanie HTML  3.0    Download  




Gruß Sepp

P.S.: Rückmeldung nicht vergessen!


Bild


Betrifft: AW: Überschneidungen beim Datum anzeigen von: Josef Ehrensberger
Geschrieben am: 12.02.2005 20:58:16

Hallo nochmal!

Kleiner Fehler in der Zellformel.
Tabelle2
 ABCDEF
1Aufenthalt vonAufenthalt bisZimmer   
221.02.200326.03.200314Fr.Schmidt Doppelbelegung!
314.05.200317.05.200315Hr.Bauer  
415.05.200328.05.200312Fr.Müller  
515.06.200316.06.200311Hr.Nordman  
620.03.200326.03.200314Fr. Weis Doppelbelegung!
Formeln der Tabelle
F2 : =WENN(SUMMENPRODUKT(($A$2:$A$6<=B2)*($B$2:$B$6>=A2)*($C$2:$C$6=C2))>1;"Doppelbelegung!";"")
F3 : =WENN(SUMMENPRODUKT(($A$2:$A$6<=B3)*($B$2:$B$6>=A3)*($C$2:$C$6=C3))>1;"Doppelbelegung!";"")
F4 : =WENN(SUMMENPRODUKT(($A$2:$A$6<=B4)*($B$2:$B$6>=A4)*($C$2:$C$6=C4))>1;"Doppelbelegung!";"")
F5 : =WENN(SUMMENPRODUKT(($A$2:$A$6<=B5)*($B$2:$B$6>=A5)*($C$2:$C$6=C5))>1;"Doppelbelegung!";"")
F6 : =WENN(SUMMENPRODUKT(($A$2:$A$6<=B6)*($B$2:$B$6>=A6)*($C$2:$C$6=C6))>1;"Doppelbelegung!";"")
 
Diagramm - Grafik - Excel Tabellen einfach im Web darstellen    Excel Jeanie HTML  3.0    Download  




Gruß Sepp

P.S.: Rückmeldung nicht vergessen!


Bild


Betrifft: AW: Überschneidungen beim Datum anzeigen von: Ulf
Geschrieben am: 12.02.2005 20:57:24

Können auch mehrere Zeilen zwischen Überschneidungen liegen, oder ist es immer
die nächste Zeile?

Ulf


Bild


Betrifft: AW: Überschneidungen beim Datum anzeigen von: JensW
Geschrieben am: 12.02.2005 21:34:30

Man seid ihr schnell!
Vielen Dank ich versuche es gerade auf meine Tabelle zuzuschneiden.

@Ulff: Es können auch mehrere Zeilen dazwischen liegen. Im Normalfall liegen auch so 5 bis 8 dazwischen.

@Josef Ehrensberger: vielen Dank! probiere es gerade aus. Als Anfänger dauert das leider ein wenig.


Bild


Betrifft: @Ulff von: JensW
Geschrieben am: 12.02.2005 21:40:26

Es können auch mehrere Zeilen dazwischen liegen. Normalerweise so 5-8

Gruß Jens
Und Danke


Bild


Betrifft: AW: @Ulff von: Ulf
Geschrieben am: 12.02.2005 21:42:25

Die Lösung von Sepp ist doch ok.

Ulf


Bild


Betrifft: Die Lösung ist sehr gut. von: JensW
Geschrieben am: 12.02.2005 21:47:53

Die Lösung von Josef Ehrensberger ist wirklich gut ich wollte nur höflich sein und alle Fragen beantworten wenn man mir schon so nett weiter hilft.

Also nochmals meinen Dank an euch

Ciao Jens


 Bild

Beiträge aus den Excel-Beispielen zum Thema "Überschneidungen beim Datum anzeigen "