Neues Blatt einfügen

Bild

Betrifft: Neues Blatt einfügen
von: Bernd
Geschrieben am: 29.07.2015 12:45:01

Hallo,
ich möchte per Buttonklick ein neues Blatt einfügen.
Und zwar eine genaue Kopie vom Musterblatt
Der Name des Neuen Blattes soll dann AE_001 sein.
Bei weiteren Blättern soll sich der Name hochaddieren.
AE_002, AE_003 u.s.w.
mit dem Code:

Sub Neues_Blatt_AE()
    Dim wsNew As Worksheet
    Set wsNew = Worksheets.Add
    With wsNew
        .Name = "AE_" & Format(Now, "dd.mm.yyyy")
        .Move after:=Sheets(Sheets.Count)
    End With
    Set wsNew = Nothing
End Sub
füge ich ein neues Blatt ein mit Datum hinter AE_
Das möchte ich aber nicht mehr.
Kann mir bitte einer bei der Erweiterung des Codes behilflich sein.
Vielen Dank und allen noch einen schönen Tag
Gruß Bernd

Bild

Betrifft: AW: Neues Blatt einfügen
von: Sepp
Geschrieben am: 29.07.2015 12:53:23
Hallo Bernd,

Sub Neues_Blatt_AE()
Dim wsNew As Worksheet, lngI As Long

Sheets("Musterblatt").Copy After:=Sheets(Sheets.Count) 'Name des Musterblattes anpassen!

Set wsNew = Sheets(Sheets.Count)

Do
  lngI = lngI + 1
  If Not SheetExist("AE_" & Format(lngI, "000")) Then
    wsNew.Name = "AE_" & Format(lngI, "000")
    Exit Do
  End If
Loop

Set wsNew = Nothing
End Sub


Private Function SheetExist(ByVal sheetName As String, Optional Wb As Workbook) As Boolean
Dim wks As Object
On Error GoTo ERRORHANDLER
If Wb Is Nothing Then Set Wb = ThisWorkbook
For Each wks In Wb.Sheets
  If LCase(wks.Name) = LCase(sheetName) Then SheetExist = True: Exit Function
Next
ERRORHANDLER:
SheetExist = False
End Function


Gruß Sepp


Bild

Betrifft: Danke Sepp o.w.t.
von: Bernd
Geschrieben am: 30.07.2015 08:40:36
.

 Bild

Beiträge aus den Excel-Beispielen zum Thema "Neues Blatt einfügen"