Höchste Zahlenwerte ermitteln

Forumthread: Höchste Zahlenwerte ermitteln

28.06.2007 14:44:00

Frank

Hallo zusammen,
ich bräuchte mal Hilfe bei folgendem Problem:
Ich möchte aus einer Spalte, in der 6 Werte (in 6 Zellen) stehen, die vier höchsten Zahlen zu einer Summe zusammenfassen.
Supi wäre, wenn man dann die beiden verbleibenden Zahlen farblich markieren oder durchstreichen könnte.
Obwohl ich glaube, das wäre von Excel zuviel verlangt.
Bin für jede Hilfe dankbar!
Viele Grüße aus Schleswig-Holstein
Frank

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

AW: Höchste Zahlenwerte ermitteln

28.06.2007 14:51:00

Christian

Hallo Frank,
Tabelle1

	A	B
1	1	18
2	2
3	3
4	4
5	5
6	6

Formeln der Tabelle

Zelle	Formel
B1	{=SUMME(KGRÖSSTE(A1:A6;ZEILE(1:4)))}

Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Matrix verstehen

Bedingte Formatierungen der Tabelle

Zelle	Nr.: / Bedingung	Format
A1	1. / Formel ist =ODER(A1=KKLEINSTE($A$1:$A$6;1);A1=KKLEINSTE($A$1:$A$6;2))	Abc

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
MfG Christian

AW: Höchste Zahlenwerte ermitteln

28.06.2007 15:01:25

Frank

Erstmal Danke für die schnellen Antworten!
Leider habe ich mich falsch ausgedrückt!!!
Die zu ermittelnden Werte stehen nicht in einer Spalte, sondern in einer Zeile, und zwar in den Feldern:
C5 E5 G5 I5 K5 und M5.
Somit funktioniert Eure Formel leider nicht.
Viele Grüße
Frank

AW: Höchste Zahlenwerte ermitteln

28.06.2007 15:09:25

Christian

Hallo Frank,
dann so:
Tabelle1

	A	B	C	D	E	F	G	H	I	J	K	L	M
1		83
2
3
4
5			12		25		30		1				14
6

Formeln der Tabelle

Zelle	Formel
B1	{=SUMME(KGRÖSSTE(test_1;ZEILE(1:4)))}

Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Matrix verstehen

Namen in Formeln

Zelle	Name	Bezieht sich auf
B1	test_1	=Tabelle1!$M$5;Tabelle1!$M$5;Tabelle1!$I$5;Tabelle1!$G$5;Tabelle1!$E$5;Tabelle1!$C$5

Namen verstehen

Bedingte Formatierungen der Tabelle

Zelle	Nr.: / Bedingung	Format
C5	1. / Formel ist =ODER(C5=KKLEINSTE(test_1;1);C5=KKLEINSTE(test_1;2))	Abc

Namen in Formeln

Zelle	Name	Bezieht sich auf
C5	test_1	=Tabelle1!$M$5;Tabelle1!$M$5;Tabelle1!$I$5;Tabelle1!$G$5;Tabelle1!$E$5;Tabelle1!$C$5

Namen verstehen

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
MfG Christian

Korrektur: Höchste Zahlenwerte ermitteln

28.06.2007 15:12:00

Christian

Hallo Frank,
kleine Korrektur bei dem Namensbezug:
Tabelle1

	A	B	C	D	E	F	G	H	I	J	K	L	M
1		189
2
3
4
5			12		25		30		1		120		14
6

Formeln der Tabelle

Zelle	Formel
B1	{=SUMME(KGRÖSSTE(test_1;ZEILE(1:4)))}

Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Matrix verstehen

Namen in Formeln

Zelle	Name	Bezieht sich auf
B1	test_1	=Tabelle1!$M$5;Tabelle1!$K$5;Tabelle1!$I$5;Tabelle1!$G$5;Tabelle1!$E$5;Tabelle1!$C$5

Namen verstehen

Bedingte Formatierungen der Tabelle

Zelle	Nr.: / Bedingung	Format
C5	1. / Formel ist =ODER(C5=KKLEINSTE(test_1;1);C5=KKLEINSTE(test_1;2))	Abc

Namen in Formeln

Zelle	Name	Bezieht sich auf
C5	test_1	=Tabelle1!$M$5;Tabelle1!$K$5;Tabelle1!$I$5;Tabelle1!$G$5;Tabelle1!$E$5;Tabelle1!$C$5

Namen verstehen

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
MfG Christian

@ Christian

28.06.2007 17:34:11

Frank

Hallo Christian,
erstmal danke!
Aber das mit der Formatierung der Zellen, also dem Durchstreichen der kleinsten Werte.
Wenn ich in die Zelle z.B. C5 die Formel eingebe, kann ich doch dann keine Zahl mehr eingeben, denn dann überschreibe ich die Formel doch, oder?
Wäre nett, wenn Du mir das irgendwie erklären könntest!
MfG
Frank

@ Frank

28.06.2007 18:12:00

jockel

hi, auch wenn ich nicht Christian bin... in den zu berechnenden zellen stehen keine formeln (die kannst du dann auch nicht überschreiben...) das durchstreichen wird mittels bedingter formatierung vorgenommen. du kannst ja mal die die zahlen ändern. Christian hatte die betroffenden zellen markiert, ist dann auf bedingte formatierung (im menü format) gegangen und hat dort bei formel ist =ODER(C5=KKLEINSTE(test_1;1);C5=KKLEINSTE(test_1;2)) eingegeben - das heisst die zwei kleinsten werte werden durch das dann einzustellende format (hier durchgestrichen und muster eine farbe) formatiert... test_1 ist ein name - siehe einfügen - namen - definieren...
cu jörg
ein feedback wär ganz reizend

AW: @ jockel

29.06.2007 10:17:44

Frank

Hallo Jörg,
hatte gestern Abend leider keine Zeit mehr, mich weiter vmit dem Problem zu beschäftigen, Familie...
Habe das aber eben mal mit der bedingten Formatierung ausprobiert.
Funktioniert soweit auch echt Klasse, aber....
Wenn unter meinen 6 Zahlenwerten zB zwei gleiche sind (2, 3, 3, 4, 5, 9), streicht mir die Formel nicht nur die beiden kleinsten Zahlen durch, sondern die 2 und die beiden 3en.
Gibts dafür vielllllllleicht ein Lösung ?
Ach ja, wofür braucht er´s eigentlich?
Ich versuche für unseren Kart-Verein (www.msc-bennebek.de) eine Auswertung für unsere Vereinsmeisterschaft zu erstellen. (Was tut man nicht alles für die Kinder!)
Viele Grüße
Frank

AW: Höchste Zahlenwerte ermitteln

28.06.2007 15:10:00

HermannZ

Hallo Frank;
dann nimm folgende Formel;
=SUMMENPRODUKT(KGRÖSSTE(INDIREKT({"C5"."E5"."G5"."I5"."K5"."M5"});ZEILE(1:4)))
Gruss HermannZ

AW: Höchste Zahlenwerte ermitteln

28.06.2007 15:12:52

jockel

hi Frank, markiere die einzelnen zellen und defieniere einen namen (hier test), dann geht:

Tabelle3

	C	D	E	F	G	H	I	J	K	L	M
5	3		5				1		9		4
6											21

Formeln der Tabelle

M6 : {=SUMME(KGRÖSSTE(test;ZEILE(1:4)))}
Enthält Matrixformel:
Umrandende { } nicht miteingeben,
sondern Formel mit STRG+SHIFT+RETURN abschließen!

Bedingte Formatierungen der Tabelle

Zelle	Nr.: / Bedingung	Format
C5	1. / Formel ist =ODER(C5=KKLEINSTE(test;1);C5=KKLEINSTE(test;2))	Abc
D5	1. / Formel ist =ODER(D5=KKLEINSTE(test;1);D5=KKLEINSTE(test;2))	Abc
E5	1. / Formel ist =ODER(E5=KKLEINSTE(test;1);E5=KKLEINSTE(test;2))	Abc
F5	1. / Formel ist =ODER(F5=KKLEINSTE(test;1);F5=KKLEINSTE(test;2))	Abc
G5	1. / Formel ist =ODER(G5=KKLEINSTE(test;1);G5=KKLEINSTE(test;2))	Abc
H5	1. / Formel ist =ODER(H5=KKLEINSTE(test;1);H5=KKLEINSTE(test;2))	Abc
I5	1. / Formel ist =ODER(I5=KKLEINSTE(test;1);I5=KKLEINSTE(test;2))	Abc
J5	1. / Formel ist =ODER(J5=KKLEINSTE(test;1);J5=KKLEINSTE(test;2))	Abc
K5	1. / Formel ist =ODER(K5=KKLEINSTE(test;1);K5=KKLEINSTE(test;2))	Abc
L5	1. / Formel ist =ODER(L5=KKLEINSTE(test;1);L5=KKLEINSTE(test;2))	Abc
M5	1. / Formel ist =ODER(M5=KKLEINSTE(test;1);M5=KKLEINSTE(test;2))	Abc

Diagramm - Grafik - Excel Tabellen einfach im Web darstellen Excel Jeanie HTML 3.0 Download
cu jörg
ein feedback wär ganz reizend

AW: Höchste Zahlenwerte ermitteln

28.06.2007 16:00:58

Frank

Vielen, vielen Dank an alle !!!
Damit ist mir echt geholfen!
Ich muss die verschiedenen Versionen dann mal in Ruhe durchprobieren, um sie zu verstehen.
Viele Grüße aus Schleswig-Holstein
Frank

AW: Höchste Zahlenwerte ermitteln

28.06.2007 14:53:08

ransi

HAllo Frank
Schau mal ob du hiermit weiterkommst :
Tabelle3

	C	D
1	27	197
2	1
3	56
4	2
5	34
6	80

Formeln der Tabelle

Zelle	Formel
D1	=SUMME(KGRÖSSTE(C1:C6;{1.2.3.4}))

Bedingte Formatierungen der Tabelle

Zelle	Nr.: / Bedingung	Format
C1	1. / Zellwert ist kleiner als =KGRÖSSTE($C$1:$C$6;4)	Abc

Excel Tabellen im Web darstellen >> Excel Jeanie HTML 4
ransi

Beliebteste Forumthreads (12 Monate)

Forumthread: Höchste Zahlenwerte ermitteln

11
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

Beliebteste Forumthreads (12 Monate)

Höchste Zahlenwerte ermitteln

Forumthread: Höchste Zahlenwerte ermitteln

11 Beiträge zum Forumthread Beiträge zu diesem Forumthread

Forumthreads zu verwandten Themen

VBA Beispiele zu diesem und ähnlichen Themen

Beliebteste Forumthreads (12 Monate)

11
Beiträge zum Forumthread

Beiträge zu diesem Forumthread