daten von kenwort geschützter accessdb importieren

Bild

Betrifft: daten von kenwort geschützter accessdb importieren von: derb
Geschrieben am: 05.04.2005 16:46:30

hallo
geht das, dass ich die daten einer access datenbank, welche mit dem kennwort test geschützt ist importieren kann, ohne das ich das kennwort eingeben muss?

momentan muss ich immernoch das passwort eingeben und
momentan sieht mein sub so aus:
Private Sub Workbook_Open()
'stopp uhr start

Dim s As Long, e As Long
Dim i As Long

s = GetTickCount
'-----------

Application.ScreenUpdating = False

Cells.Select
Selection.ClearContents
Range("A1").Select

With ActiveSheet.QueryTables.Add(Connection:=Array(Array( _
"ODBC;DSN=Microsoft Access-Datenbank;DBQ=H:\Personal\Job\Kursdatenbank\ACHTUNG!Datenbank Backend\DB_V1.1_be.mdb;DefaultDir=H:\Persona" _
), Array( _
"l\Job\Kursdatenbank\ACHTUNG!Datenbank Backend;DriverId=25;Exclusive=1;FIL=MS Access;MaxBufferSize=2048;PageTimeout=5;;ReadOnly=" _
), Array("0;UID=admin;")), Destination:=Range("A1"))
.CommandText = Array( _
"SELECT *" & Chr(13) & "" & Chr(10) & "FROM Kursbesuche_Kreuztabelle Kursbesuche_Kreuztabelle" & Chr(13) & "" & Chr(10) & "ORDER BY Kursbesuche_Kreuztabelle.Kostenstelle" _
)

.Name = "Abfrage von Microsoft Access-Datenbank_75"
.FieldNames = True
.RowNumbers = False
.FillAdjacentFormulas = False
.PreserveFormatting = True
.RefreshOnFileOpen = False
.BackgroundQuery = True
.RefreshStyle = xlInsertDeleteCells
.SavePassword = False
.SaveData = True
.AdjustColumnWidth = True
.RefreshPeriod = 0
.PreserveColumnInfo = True
.Refresh BackgroundQuery:=False
End With

Columns("E:E").Select
Selection.Delete Shift:=xlToLeft

Bild


Betrifft: AW: daten von kenwort geschützter accessdb importieren von: Werner
Geschrieben am: 07.04.2005 00:02:07

Hallo,

versuch es mal so (musst Du noch ein bischen anpassen. DB_Name, SELECT... ).
Private Sub Workbook_Open()
    Dim appAccess   As Object
    Dim accDB       As Object
    Dim accRst      As Object
           
    Dim strConnect  As String
    
    Const DB_NAME As String = "C:\TEST.mdb" 'Datenbank
    Const PASSWORT As String = "test"       'Passwort
    
    'Connect String
    strConnect = "ms access;pwd=" & PASSWORT & ";database=" & DB_NAME
    
    'neues Access Object
    Set appAccess = CreateObject("Access.Application")
        
    'Datenbank öffnen
    Set accDB = appAccess.DBEngine(0).OpenDatabase( _
                DB_NAME, _
                    Options:=False, _
                    ReadOnly:=True, _
                    Connect:=strConnect)
    
    'neues Recordset
    Set accRst = accDB.Openrecordset("SELECT * FROM Kursbesuche_Kreuztabelle ORDER BY Kursbesuche_Kreuztabelle.Kostenstelle;")
    
    'Daten ausgeben
    Range("A1").CopyFromRecordset accRst
    
    
    accRst.Close
    accDB.Close
    
    Set accDB = Nothing
    Set accRst = Nothing
End Sub



 Bild

Beiträge aus den Excel-Beispielen zum Thema "daten von kenwort geschützter accessdb importieren"