ListBox-Header nicht zusammenhändender Spaltenwahl

Hallo Forumsgemeinde,
besteht die Möglichkeit, die Kopfleisteneinträge einer mehrspaltigen Listbox, bei der zudem die Spalten in ungeordneter Folge zusammengestzt sind, frei zu definieren?
Beispielmappe dazu: ListBoxHeader.xls
Die Übernahme von Zeileneinsträgen als Listboxeinträge erfogt nur, wenn ein Eintrag in der Spalte F gesetzt ist. Die ColumnHeader-Eigenschaft nutzt jedoch wohl nur die Zeile über einem geschlossen Bereich als Kopfeinträge, wenn sie auf True gesetzt ist.
Eine Umordnung der Spalten soll vermieden werden, da die Tabelle selbst von anderen Quellen in dieser Ordnung aktualisiert wird. Die Möglichkeit, ein "Label-Band" über die Listbox zulegen würde ich auch nur als die letzte Möglichkeit nutzen.
Gruß,
Uwe

Beiträge zum Forumthread

Beiträge zu diesem Forumthread

Betreff

Datum

Anwender

Hallo, @Luschi,
Dein Tipp war genau das Richtige, um sich den Teil herauszupicken, der meinen Anforderungen genügt.
Der "Schlüsselhinweis" war einfach der auf die zweite Listbox, die es mir ohne lange Ausrichtungsarbeiten ermöglicht, die Spaltenüberschriften genauso zu plazieren, wie die Listboxspalten selbst.
Nach einfügen der zweiten Listbox, nun lbxHeader genannt, konnte ich den Programmcode wie folgt verändern und erweitern:


Option Explicit
Private Sub UserForm_Initialize()
Dim wsSymb As Worksheet, rng As Range
Dim strWidth As String
strWidth = "1cm;1,2cm;2cm;0,5cm;0,5cm;3cm"
Set wsSymb = Worksheets("Tabelle1")
With lbxHeader
.ColumnHeads = False
.ColumnCount = 6
.ColumnWidths = strWidth
.ListStyle = fmListStylePlain
.Left = ListBox1.Left
.Top = ListBox1.Top - .Height
.Width = ListBox1.Width
.AddItem
.List(.ListCount - 1, 0) = "#"
.List(.ListCount - 1, 1) = "Segm"
.List(.ListCount - 1, 2) = "Symbol"
.List(.ListCount - 1, 3) = "V1"
.List(.ListCount - 1, 4) = "V2"
.List(.ListCount - 1, 5) = "Name"
.Enabled = False
End With
With ListBox1
.ColumnHeads = False
.ColumnCount = 6
.ColumnWidths = strWidth
.ListStyle = fmListStylePlain
For Each rng In wsSymb.Range("F3:F" & wsSymb.Cells(wsSymb.Rows.Count, "F").End(xlUp).Row)
If Len(rng.Value2) > 0 Then
.AddItem
.List(.ListCount - 1, 0) = rng.Row
.List(.ListCount - 1, 1) = rng.Offset(0, -5)
.List(.ListCount - 1, 2) = rng.Offset(0, -3)
If rng.Offset(0, 4) > 0 Then .List(.ListCount - 1, 3) = rng.Offset(0, 4)
If rng.Offset(0, 5) > 0 Then .List(.ListCount - 1, 4) = rng.Offset(0, 5)
.List(.ListCount - 1, 5) = rng.Offset(0, 3)
End If
Next
End With
End Sub

Für Deine Ergänzungsarbeit sei Dir auf jeden fall gedankt, @Luschi.
Gruß,
Uwe

Beliebteste Forumthreads (12 Monate)

ListBox-Header nicht zusammenhändender Spaltenwahl

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread

303 Forumthreads zu ähnlichen Themen

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

ListBox-Header nicht zusammenhändender Spaltenwahl

8 Beiträge zum Forumthread Beiträge zu diesem Forumthread

303 Forumthreads zu ähnlichen Themen

Links zu Excel-Dialogen

Beliebteste Forumthreads (12 Monate)

Beliebteste Forumthreads (12 Monate)

8
Beiträge zum Forumthread

Beiträge zu diesem Forumthread