0% entfernen in Pivot Chart / gestapelte Säulen

Informationen und Beispiele zu den hier genannten Dialog-Elementen:
Label
Bild

Betrifft: 0% entfernen in Pivot Chart / gestapelte Säulen
von: MaWe
Geschrieben am: 12.08.2015 11:00:06

Hallo, kann mir einer sagen wie ich die 0% in Pivot Charts entfernen kann?
Manuell ist mir das schon klar, aber immer wenn ich die Mappe aktualisiere, sind sie wieder da!
Um es besser zu formulieren. Ich habe gestapelte Säulen mit mehreren Unterteilungen. Zusammen ergibt es "logischerweise" immer 100%
Ich möchte gerne das es wie folgt aussieht (hier als Beispiel mit 4 Unterteilungen):
30%
20%
10%
40%
Er zeigt es mir aber zum Teil so an:
30%
0%
20%
10%
0%
40%
0%
Wäre top wenn einer eine Idee für mich hat, wie ich diese 0% entfernen kann :)

Bild

Betrifft: AW: 0% entfernen in Pivot Chart / gestapelte Säulen
von: fcs
Geschrieben am: 16.08.2015 20:51:11
Hallo MaWe,
das automatische Ausblenden der "0,00%" ist möglich per Makro.
Nachfolgend ein entsprechendes Makro. Dieses muss im VBA-Editor unter dem Tabellenblatt mit der Pivot-Tabelle eingefügt werden. Es wird automatisch bei jedem Update des Pivotberichtes gestartet,wenn die Makros für die Datei beim Öffnen der Datei aktiviert werden.
Gruß
Franz

'Makro unter dem Tabellenblatt mit der Pivot-Tabelle zum Chart
Private Sub Worksheet_PivotTableUpdate(ByVal Target As PivotTable)
    Dim objChart As Chart
    Dim objReihe As Series
    Dim objPoint As Point
    Dim strLabel As String
    
    Set objChart = Me.ChartObjects(1).Chart 'Chart ist auf dem gleichen Blatt wie die  _
Pivottabelle
'    Set objChart = Charts("DiagrammXXX") 'Chart in separatem Blatt - Blattname ggf. anpassen!!! _
    
    With objChart
        'Daten-Punkt-Labels mit 0% - Werten ausblenden
        For Each objReihe In .SeriesCollection
            With objReihe
                .HasDataLabels = True
                For Each objPoint In .Points
                    strLabel = objPoint.DataLabel.Text
                    strLabel = Replace(strLabel, "%", "")
                    If IsNumeric(strLabel) Then
                        If CDbl(strLabel) = 0 Then
                             objPoint.HasDataLabel = False
                        Else
                             objPoint.HasDataLabel = True
                        End If
                    End If
                Next
            End With
        Next
    End With
End Sub


 Bild

Beiträge aus den Excel-Beispielen zum Thema "0% entfernen in Pivot Chart / gestapelte Säulen"